bamboo

程序1

@echo off
setlocal enabledelayedexpansion
set "number=1 2 3 4"
for %%a  in (%number%) do (
  set num1=!number:%%a=!
  for %%b in (!num1!) do (
    set num2=!num1:%%b=!
    for %%c in (!num2!) do (
      echo %%a%%b%%c
    )
  )
)
echo    按任意键退出！
pause>nul
复制代码

bamboo

程序4

@echo off
setlocal enabledelayedexpansion

echo 输入日期（格式：2009-11-24），判断这一天是这一年的第几天？
set /p input=请输入日期：
for /f "tokens=1-3 delims=-" %%a in ("%input%") do (
  call :calcdays %%a %%b %%c
)
echo 这一天是这一年的第%days%天
echo    按任意键退出！
pause>nul
exit

:calcdays
set "month1=31 28 31 30 31 30 31 31 30 31 30 31"
set "month2=31 29 31 30 31 30 31 31 30 31 30 31"
set isleapyearflag=1
call :isleapyear %1
set /a months=%2-1
for %%A in (!month%isleapyearflag%!) do (
  if !months! gtr 0 (
    set /a months-=1
    set /a days+=%%A
  )
)
set /a days+=%3
goto :eof

:isleapyear
set /a flag1= %1%%4
if !flag1! equ 0 (
  set /a flag2=%1%%100
  if !flag2! equ 0 (
    set /a flag3=%1%%400
    if !flag3! equ 0 (
      set isleapyearflag=2
    ) else (set isleapyearflag=1)
  ) else (set isleapyearflag=2)
) else (set isleapyearflag=1)
goto :eof
复制代码

bamboo

程序8(正三角)

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,9) do (
  for /l %%b in (1,1,9) do (
    if %%b leq %%a (
      set /a ans=%%a*%%b
      set /p=%%a*%%b=!ans!  <nul
    )
  )
  echo.
)
echo    按任意键退出！
pause>nul
复制代码

gbw911

程序8：

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 9) do (
for /l %%j in (%%i 1 9) do (echo %%i*%%j))
pause
复制代码

只会这么多还望指教

shuai24

程序1

@echo off
for /l %%i in (1 1 4) do (
   for /l %%j in (1 1 4) do (
      if not %%j==%%i for /l %%k in (1 1 4) do (
         if not %%k==%%i (if not %%k==%%j echo %%i%%j%%k)
         )
      )
   )
pause>nul
复制代码

shuai24

程序4

@echo off
setlocal enabledelayedexpansion
set n=0
set /p year=年：
set /p moon=月：
set /p day=日：
set /a days=0
set /a aa=%year% %% 4
set /a bb=%year% %% 100
if %aa% equ 0 ( 
   if not %bb% equ 0 (
      if %moon% gtr 2 set days=1
   )
)
set /a days=%days%+%day%
for %%i in (0 31 28 31 30 31 30 31 31 30 31 30) do (
   set /a days=!days!+%%i
   set /a n=!n!+1
   if !n! equ %moon% echo !days! & pause>nul &exit
)
复制代码

rik761985

答案为24个

@echo off
title 1-无重复三位数
echo.
setlocal enabledelayedexpansion
echo 题目：
echo 有1、2、3、4个数字，能组成多少个互不相同且无重复数字的三位数？都是多少？
set /a n=0
set /a s=0
for /l %%i in (1,1,4) do (
 set /a s=100*%%i
   for /l %%j in (1,1,4) do (
      if %%i neq %%j (
           set /a s=!s!+10*%%j
         for /l %%k in (1,1,4) do (
          if %%i neq %%k (
             if %%j neq %%k (
               set /a n=!n! + 1
               set /a s=!s!+%%k
               echo !s! 
               set /a s=!s!-%%k 
)          
)
       )
set /a s=!s!-10*%%j
)
)
set /a s=0
)
echo 总共有%n%个无重复数字的三位数！
pause > nul
复制代码

Silversky

【程序82】
题目：八进制转换为十进制
方法一

@echo off
:begin
set /p input=请输入一个八进制数:
set num=0
set count=1
:start
set /a Remainder=%input%%%10
if %Remainder% gtr 7 goto error
set /a num+=%Remainder%*count
set /a count*=8
set /a bug=%input%
set /a input/=10
if %bug% gtr 0 goto start
echo 转换后的十进制数为:%num%
pause>nul & exit
:error
echo 该数不是八进制数,请重新输入!
pause>nul & cls
goto begin
复制代码

方法二

@echo off
set /p input=请输入一个八进制数:
set /a output=0%input%
echo 转换后的十进制数为:%output%
pause>nul
复制代码

[ 本帖最后由 Silversky 于 2010-7-27 13:17 编辑 ]

Silversky

【程序30】
题目：一个5位数，判断它是不是回文数。即12321是回文数，个位与万位相同，十位与千位相同。

@echo off
set /p input=请输入一个数:
set put=1%input%1
:loop
set put=%put:~1,-1%
if "%input%"=="" goto no
if "%put%"==""  goto yes
if "%put:~0,1%"=="%put:~-1%" goto loop
:no
echo %input%不是回文数
pause>nul & exit
:yes
echo %input%是回文数
pause>nul
复制代码

[ 本帖最后由 Silversky 于 2010-7-26 20:01 编辑 ]

Silversky

【程序21】
题目：猴子吃桃问题：猴子第一天摘下若干个桃子，当即吃了一半，还不瘾，又多吃了一个第二天早上又将剩下的桃子吃掉一半，又多吃了一个。以后每天早上都吃了前一天剩下的一半零一个。到第10天早上想再吃时，见只剩下一个桃子了。求第一天共摘了多少。

@echo off
set a=1
echo 倒数第1天时有%a%个桃子
for /l %%i in (2,1,10) do (
set /a a=a*2+2
call echo 倒数第%%i天时有%%a%%个桃子
)
pause>nul
复制代码

[ 本帖最后由 Silversky 于 2010-7-27 12:00 编辑 ]

Silversky

【程序11】
题目：古典问题：有一对兔子，从出生后第3个月起每个月都生一对兔子，小兔子长到第三个月后每个月又生一对兔子，假如兔子都不死，问每个月的兔子总数为多少？

@echo off & setlocal enabledelayedexpansion
set/p n=请输入月份:
set a1=1
set a3=0
for /l %%i in (1,1,%n%) do (
set a2=!a3!
set /a a3+=a1
set a1=!a2!
echo !a3!
)
pause>nul
复制代码

[ 本帖最后由 Silversky 于 2010-7-27 13:13 编辑 ]

Silversky

【程序13】
题目：打印出所有的“水仙花数”，所谓“水仙花数”是指一个三位数，其各位数字立方和等于该数本身。例如：153是一个“水仙花数”，因为153=1的三次方＋5的三次方＋3的三次方。

@echo off & setlocal enabledelayedexpansion
for /l %%i in (100 1 999) do (
set x=%%i && set /a a=b=c=1
for /l %%z in (1,1,3) do set /a a*=!x:~0,1! & set /a b*=!x:~1,1! & set /a c*=!x:~2,1!
set /a n=a+b+c
if "!n!" == "%%i" echo %%i
)
pause>nul
复制代码

Silversky

【程序14】
题目：将一个正整数分解质因数。例如：输入90,打印出90=2*3*3*5。

@echo off
set /p n=请输入要分解的数:
set/p=%n%分解为1<nul
set count=1
:s
set /a count+=1
:s1
set /a remainder=%n%%%%count%
if not %remainder% equ 0 goto s
set /a divisor=%n%/%count%
set/p=*%count%<nul
set n=%divisor%
if "%n%"=="1" (pause>nul & exit)
goto s1
复制代码

Silversky

【程序16】
题目：输入两个正整数m和n，求其最大公约数和最小公倍数。

@echo off
set /p n1=请输入第一个数:&& set /p n2=请输入第二个数:
set/a result=%n1%*%n2%
:ss
set /a temp=%n1%%%%n2%
if %temp% neq 0 (set /a n1=%n2% & set /a n2=%temp% & goto :ss)
set /a result=%result%/%n2%
echo 最大公约数为:%n2%
echo 最小公倍数为:%result%
pause>nul
复制代码

Silversky

【程序25】
题目：求1+2!+3!+...+20!的和

@echo off
set a=1
set b=0
for /l %%i in (1,1,20) do (set /a a*=%%i && set /a b+=a)
echo 1+2!+3!...+20!=%b%
pause>nul
复制代码