普大喜奔

回复 14# 523066680
谢啦版主 看来细胞自动机最后都要稳定啊

523066680

回复 16# 普大喜奔

前面发的一个矩阵是无限循环的。
    再发一个典型的刷了很久的轰炸模型， 挺精彩的，运行好一段时间才进入稳定状态，当然，还要看你的空间设置为多大。

.........................**.....**
.........................**.....**
..................................
..................................
..................................
..................................
..................................
..................................
..................................
..................................
..................................
..................................
..................................
...........................**.**..
..........................*.....*.
..................................
.........................*.......*
.........................*..*.*..*
.........................***...***
..................................
..................................
..................................
..................................
.................*................
**...............**...............
**................**..............
.............**..**...............
..................................
..................................
..................................
.............**..**...............
**................**.......**.....
**...............**........**.....
.................*................
复制代码

普大喜奔

回复 17# 523066680
版主好人！
只是输入矩阵麻烦些 我试试吧

523066680

use strict;
use Term::ReadKey;
use Win32::Console;
use Time::HiRes 'sleep';
use IO::Handle;
STDOUT->autoflush(1);
system("mode con lines=40 cols=200");

our $OUT=Win32::Console->new(STD_OUTPUT_HANDLE);
$OUT->Cursor(20, 20, 99, 0);  #hide cursor

my ($i, $j);
our ($rows, $cols) = (40, 90);
our ($mxrow, $mxcol) = ($rows-1, $cols-1);

# init
our @coord;
my (@h, @n);
my $y = 0;

foreach (<DATA>) {
    s/\r?\n$//;
    tr/\*\./10/;
    @{$h[$y++]} = ( split("", $_) );
}

foreach $i (0 .. $mxrow) {
    foreach $j (0 .. $mxcol) {
        $coord[$i][$j]{'x'} = $j*2;
        $coord[$i][$j]{'y'} = $i;
        $h[$i][$j] = 0 unless (defined $h[$i][$j]);
        $n[$i][$j] = 0;
    }
}

&Draw(\@n, \@h);
while (1) {
    sleep 0.02;
    @n = ();
    &NextBuffer(\@h, \@n);
    &Draw(\@h, \@n);
    @h = (@n);

    &KeyFunc();
}

sub NextBuffer {
    my ($ra, $rb) = (shift, shift);
    my ($i, $j, $sum);
    my ($L, $R, $U, $D);
    foreach $i (0 .. $mxrow) {
        $U = ($i-1) < 0 ? $mxrow : ($i-1);
        $D = ($i+1) > $mxrow ? 0 : ($i+1);
        foreach $j (0 .. $mxcol) {
            $L = ($j-1) < 0 ? $mxcol : ($j-1);
            $R = ($j+1) > $mxcol ? 0 : ($j+1);
            $sum = $ra->[$U][$L] + $ra->[$U][$j] + $ra->[$U][$R] +
                   $ra->[$i][$L] +        0      + $ra->[$i][$R] +
                   $ra->[$D][$L] + $ra->[$D][$j] + $ra->[$D][$R];

            if ($sum == 3) {
                $rb->[$i][$j] = 1;
            } elsif ($sum == 2) {
                $rb->[$i][$j] = $ra->[$i][$j];
            } else {
                $rb->[$i][$j] = 0;
            }
        }
    }
}

sub Draw {
    my ($ra, $rb) = (shift, shift);
    foreach $i (0 .. $mxrow) {
        foreach $j (0 .. $mxcol) {
            if ($rb->[$i][$j] != $ra->[$i][$j]) {
                &Point( 
                    $coord[$i][$j]{'x'}, 
                    $coord[$i][$j]{'y'}, 
                    $rb->[$i][$j],
                );
            }
        }
    }
}

sub Point {
    my ($mx, $my, $light) = (shift, shift, shift);
    my $color;
    if ($light == 1) {
        $color = $FG_WHITE|$BG_GRAY;
    } else {
        $color = $FG_WHITE|$BG_BLACK;
    }
    $OUT->Cursor($mx, $my);
    $OUT->FillAttr($color, 2, $mx, $my);
}

sub KeyFunc {
    my $key;
    $key = ReadKey(-1);
    return if (not defined $key);
    if ( ord($key) == 27 ) {
        exit;
    }
}



__DATA__
.........................**.....**
.........................**.....**
..................................
..................................
..................................
..................................
..................................
..................................
..................................
..................................
..................................
..................................
..................................
...........................**.**..
..........................*.....*.
..................................
.........................*.......*
.........................*..*.*..*
.........................***...***
..................................
..................................
..................................
..................................
.................*................
**...............**...............
**................**..............
.............**..**...............
..................................
..................................
..................................
.............**..**...............
**................**.......**.....
**...............**........**.....
.................*................
复制代码

523066680

回复 18# 普大喜奔


    也搞一个读入矩阵的函数嘛，我在wiki挖了好多经典的模型。

CrLf

回复 8# 普大喜奔


    不一样啊，num 变量不包括 dict[cells[y][x]]，所以当周围的格子都是空的时候 elif num: 将不成立，cells[x][y] 的内容会维持上一轮循环的状态，所以会出现独立的细胞永垂不朽的现象

普大喜奔

回复 20# 523066680
读入应该不难 难的是cmd窗口太小了 cmd30列就到头了 行只有20左右 难不成再学下GUI!版主有没有好办法教教小弟

普大喜奔

回复 21# CrLf
高手就是高手 我的理解有问题 我以为num只要不为空就成立了 忘了0也是 C语言没学好

普大喜奔

回复 20# 523066680
才发现cmd原来可以设置的

CrLf

回复 22# 普大喜奔


高宽各 1000，这样够大了吧，超出屏幕部分得拉动滚动条查看...

mode con:cols=1000 lines=1000
复制代码

再将置字体为 3*5 大小，就能显示不少东西了

CrLf

回复 11# 523066680


浅拷贝/深拷贝，不过话说回来深拷贝的效率确实不如用俩数组将就了（泥们就是这么干的！魂淡！），反正脚本也不大

普大喜奔

回复 20# 523066680
版主这个模型叫什么来着

CrLf

回复 11# 523066680


想请教个问题，perl 可以用列表直接交换变量值：

$a=1;
$b=2;
($a,$b)=($b,$a);
print "\$a=$a;\$b=$b;"
复制代码

数组肯定不能直接用 (@a,@b)=(@b,@a)，但为什么改成引用就报错？是否是只有在调用函数时可以用 \@ 呢？一对数组、列表、hash 表是不是无法直接交换内容呢？

@a=1..3;
@b=4..5;
(\@a,\@b)=(\@b,\@a);
print "@a";
复制代码

523066680

回复 28# CrLf


      因为引用是一个地址，\@a = \@b 就是地址=地址，就那啥了……
只能是 变量名 = 引用地址

可以这么做，一开始就用引用对数组操作比如：
      ($ar, $br) = (\@a, \@b);
用 $ar->[下标] 的方式访问元素，用 @{$ar} 的方式访问整个数组
交换的时候也就和标量交换一样了。
      ($ar, $br) = ($br, $ar);


经过思考，发现可以这样（其实是在Perl高效编程里面看过这样的用法：片段赋值）

my @a=1..5;
my @b=6..10;

(@a[0..$#b], @b[0..$#a]) = (@b, @a);
复制代码

这样的话指定了长度，列表元素自然对号入座，嘿嘿。

523066680

回复 28# CrLf


      居然不理我

还有个"正确"方法，发到Perl区了。