lujice

呵呵，我这个菜鸟好笨啊！！看不懂带for的语句，看不懂如何插入、与删除字符......

算了，给我一个成品吧！



挑战——批量修改后缀名、并同时颠倒文件名
   
      批处理的用途是——
      1、把目标文件夹（包含它的所有子目录）里，某类指定后缀名的文件，批量的修改为其它指定的后缀名。
      2、同时，把目标文件夹（包含它的所有子目录）里，某类指定后缀名的文件，批量的颠倒文件名。
      

      补充说明——
      1、批处理必须要支持：由用户在批处理的运行窗口，自行输入目标文件夹（或拖放获取路径）、原后缀名和新后缀名。
      2、目标文件夹的路径，有可能含有空格。
           比如“C:\Documents and Settings\Administrator”目录。
      3、目标文件夹的路径，有可能含有汉字。
            比如“C:\Documents and Settings\Administrator\桌面”目录。
      4、目标文件夹的路径，有可能含有特殊字符。
           比如"^"和“&”字符。
      5、具体改名的例子是：
           比如"1234.原后缀名"，改名后就变为“4321.新后缀名”
      6、双后缀名的情况是：
           比如"1234.jpg.原后缀名"，改名后就变为“gpj.4321.新后缀名”。
           总之，只认最后一个后缀名为真实后缀名。前面的，全部按文件名处理，整体颠倒！
      7、批处理必须要支持，对系统或隐藏属性文件的改名。但是，改名后，又必须恢复原来的属性。

[ 本帖最后由 lujice 于 2011-1-22 19:16 编辑 ]

tmplinshi

@echo off

:Input_Folder
    echo 请输入文件夹路径（或拖放文件夹到本窗口）：
    set Folder=
    set /p Folder=    
    
    if not defined Folder goto Input_Folder
    if not exist "%Folder:"=%" (
        echo * 错误：不存在该文件夹
        goto Input_Folder
    )

:Input_OldExt
    set OldExt=
    set /p OldExt=请输入原后缀名：
    
    if not defined OldExt goto Input_OldExt

:Input_NewExt
    set NewExt=
    set /p NewExt=请输入新后缀名：
    
    if not defined NewExt goto Input_NewExt

rem 去除路径中的引号、后缀中的“.”及前面的字符
set "Folder=%Folder:"=%"
set "OldExt=%OldExt:*.=%"
set "NewExt=%NewExt:*.=%"

for /f "delims=" %%i in ('dir /a:-d /b /s "%Folder%\*.%OldExt%"') do (
    set fPath=%%~dpi
    set fName=%%~ni
    set fAttr=%%~ai
    SetLocal EnableDelayedExpansion
    
    rem 判断有没有“系统”和“隐藏”属性，有则去除
    set AttrList=
    if "!fAttr:s=!" neq "!fAttr!" set AttrList= s
    if "!fAttr:h=!" neq "!fAttr!" set AttrList=!AttrList! h
    if defined AttrList (
        attrib !AttrList: = -! "!fPath!!fName!.!OldExt!"
    )
    
    rem 计算文件名的字符个数
    set /a n = 8189, b = 0
    for /l %%a in (1 1 13) do (
        set /a "a = (n - b) / 2 + b"
        for %%b in (!a!) do (
            if "!fName:~%%b,1!"=="" (set n=!a!) else set b=!a!
        )
    )
    
    rem 颠倒文件名
    set /a n -= 1
    for /l %%n in (0 1 !n!) do (
        set NewName=!fName:~%%n,1!!NewName!
    )
    
    rem 重命名
    ren "!fPath!!fName!.!OldExt!" "!NewName!.!NewExt!"
    
    rem 如果之前修改了文件属性，则改回去
    if defined AttrList (
        attrib !AttrList: = +! "!fPath!!NewName!.!NewExt!"
    )
    
    EndLocal
)
复制代码

[ 本帖最后由 tmplinshi 于 2011-1-23 10:23 编辑 ]

lujice

试验了！目前还没有发现Bug！！

这个工具，用于禁止（恢复）计算机某些功能的执行。比如禁止（恢复）“我的电脑——右键——管理”、比如禁止（恢复）“文件夹选项”、比如禁止（恢复）控制面板的所有项目、比如禁止（恢复）组策略、比如禁止（恢复）注册表......

呵呵！这种禁止方法，别人还能轻易破解吗？？？

万分感谢tmplinshi 老大！！

马上回去，抱起论坛的教程，慢慢咀嚼tmplinshi 老大的代码......

再次感谢tmplinshi 老大！！

lujice

虽然我是一个不折不扣的菜鸟，只会最简单的命令。但是，我敢于尝试......

过两天，我会发一个U盘病毒免疫批处理。有一点原创的DIY，就是加一个把隐私文件藏进去的功能，再加强下防删除、防更名的能力。

高手就不看了，全是用简单命令写的语句。

回去抠脑壳吧！