[文件操作] 求助先判断后循环：将文件名以指定格式写入指定文件

ganjie

已知某文件夹内有若干文件,文件名为X1、X2、X3、…………，如果文件数小于等于3，那么输出
<tr>
<td>X1</td>
<td>X2</td>
<td>X3</td>
</tr>
若文件数大于3时，输出
<tr>
<td>X1</td>
<td>X2</td>
<td>X3</td>
</tr>
<tr>
<td>X4</td>
<td>X5</td>
<td>X6</td>
</tr>
………………

保存到文本中，文件名为文件夹名,每读取三个文件名后就需要一对<tr> </tr>，如果文件个数超过30个,则输出到另一个文本中,如
<tr>
<td>X31</td>
<td>X32</td>
<td>X33</td>
</tr>
<tr>
<td>X34</td>
<td>X35</td>
<td>X36</td>
</tr>
………………



文件名则为文件夹名加02,每个文件里只能保存30个文件名,如果超过就另存为一个文本,文件名顺序加1就行了,如何才能实现这个判断循环语句呀，求大侠们教一下小弟，谢谢！

[ 本帖最后由 ganjie 于 2008-12-30 14:20 编辑 ]

lhjoanna

看看这个行不？

@echo off
setlocal enabledelayedexpansion
set "cd_=%cd%"
:loop
set "cd_=%cd_:*\=%"
set "cd_tmp=%cd_:\=%"
if not "%cd_tmp%"=="%cd_%" goto loop
set "folder_name=%cd_%"
set n=0
set sign1=1
for /r "%cd%\" %%i in (*.*) do (
  if not "%%~nxi" equ "%~nx0" (
    set /a n+=1
    set /a sign2=n%%30
    if !sign2! equ 1 ( 
       cd.>"!folder_name!_!sign1!.txt"
       echo ^<tr^>>>"!folder_name!_!sign1!.txt"
    )
    echo ^<td^>%%~ni^</td^>>>"!folder_name!_!sign1!.txt"
    set /a sign3=n%%3
    if !sign3! equ 0 (
       echo ^</tr^>>>"!folder_name!_!sign1!.txt"
       if not !sign2! equ 0 echo ^<tr^>>>"!folder_name!_!sign1!.txt"
    )
    set /a sign1=n/30+1
)
)
if not !sign3! equ 0 echo ^</tr^>>>"!folder_name!_!sign1!.txt"
echo 执行完毕！&pause>nul
复制代码

[ 本帖最后由 lhjoanna 于 2008-12-30 18:14 编辑 ]

ganjie

测试了一下，总体是可以了，但有几个小问题，比如有60个文件，他应生成2个文本，但却生成了3个文本，因为它把生成的文本文件名都加进去了，还有生成的文本里，在结尾里总是多出一个<tr>

[ 本帖最后由 ganjie 于 2008-12-30 16:43 编辑 ]

lhjoanna

哦？刚开始是还没生成文本文件啊，楼主是要反复使用吗？如果是可以修改为建立文本文件到一个其他地址。第二个问题一开始没注意到，已经修改，在楼上更新。

ganjie

测试成功了，生成的文本里，再没有多出一个<tr>，很完美了，我把存放的文本路径改了，它就不需要读取生成的文本文件名了，谢谢了！

ganjie

set /a n+=1  set /a sign2=n%%30  在程序中起什么作用呀，不明白，还有 set /a sign3=n%%3    set /a sign1=n/30+1  编程的思路是什么我还是看不太明白。

lhjoanna

n是用来计数的啊，每处理一个文件就加一个。
         set /a sign1=n/30+1是标记文件名，文件名为 !folder_name!_!sign1!.txt，每达到30个新创建一个文本，那么文本名顺序加一，这就是此句的作用。
         sign2是用来标记当前文件是否满了30，下面一句 if  !sign2! equ 1......就是当文件数达到1、31、61、91等等时，就新建一个文本文件，往新的文本文件里写入内容。   
         set /a sign3=n%%3和此句 if !sign3! equ 0 (...)一起理解。是每三个就加一对<tr></tr>。

[ 本帖最后由 lhjoanna 于 2008-12-31 20:37 编辑 ]

ganjie

%%~nxi这是指读取的文件名了，那%~nx0 这是什么意思？

lhjoanna

if not "%%~nxi" equ "%~nx0" (...)
此句是忽略批处理文件自身，防止自己也被写入到文本文件中，楼主可推测一下 %0 是什么意思。多实践下看。

ganjie

大大，您上面的代码是读取当前文件夹下的文件名，今小弟想求%cd% 下所有目录里的thumb这个文件夹下的所有文件名，以下是的我代码，可老是测试不成功，请大大帮检查一下，谢谢！

 
@echo off
setlocal enabledelayedexpansion
set "route=%cd%"
set n=0
set sign1=1
for /f "delims=" %%k in ('dir /ad /b "%route%"') do (
set "as=%%k"
for /r "!as!\thumb\" %%i in (*.*) do (
  if not "%%~nxi" equ "%~nx0" (
    set /a n+=1
    set /a sign2=n%%30
    if !sign2! equ 1 ( 
       cd.>"%%k_!sign1!.txt"
       echo ^<tr^>>>"!as!_!sign1!.txt"
    )
    echo ^<td^>%%~nxi^</td^>>>"!as!_!sign1!.txt"
    set /a sign3=n%%3
    if !sign3! equ 0 (
       echo ^</tr^>>>"!as!_!sign1!.txt"
       if not !sign2! equ 0 echo ^<tr^>>>"!as!_!sign1!.txt"
    )
    set /a sign1=n/30+1
)
)
)
if not !sign3! equ 0 echo ^</tr^>>>"%%k_!sign1!.txt"
echo 执行完毕！&pause>nul
复制代码

lhjoanna

把此句for /f "delims=" %%k in ('dir /ad /b "%route%"') do (...)改为for /f "delims=" %%k in ('dir /ad /b') do (...)看看。

ganjie

测试了，连个文本也看不见，没有什么输出的。

lhjoanna

改动了几个地方，上面题的句子改成了for /f，for /r原因我还在测试中。还有其他几个地方，你对比下即可。

@echo off
setlocal enabledelayedexpansion
set "route=%cd%"
set n=0
set sign1=1
for /f "delims=" %%k in ('dir /ad /b') do (
  set "as=%%k"
  for /f "delims=" %%i in ('dir /a /b !as!\thumb') do (
      set /a n+=1
      set /a sign2=n%%30
      if !sign2! equ 1 ( 
         cd.>"%%k_!sign1!.txt"
         echo ^<tr^>>>"!as!_!sign1!.txt"
      )
      echo ^<td^>%%~nxi^</td^>>>"!as!_!sign1!.txt"
      set /a sign3=n%%3
      if !sign3! equ 0 (
         echo ^</tr^>>>"!as!_!sign1!.txt"
         if not !sign2! equ 0 echo ^<tr^>>>"!as!_!sign1!.txt"
      )
      set /a sign1=n/30+1
  )
 if not !sign3! equ 0 echo ^</tr^>>>"%%k_!sign1!.txt"
)
echo 执行完毕！&pause>nul
复制代码

ganjie

不行呀，请看运行结果，因为要测试，我把30个限制改成了12个，如当前目录下有psp、nds两个文件夹，它们都有一个thumb文件夹，运行后得nds_1.txt、 nds_2.txt、psp_2.txt、psp_3.txt 四个文本，psp这个错误了，内容如下：
nds_1.txt
<tr>
<td>thum-21.jpg</td>
<td>thum-22.jpg</td>
<td>thum-23.jpg</td>
</tr>
<tr>
<td>thum-24.jpg</td>
<td>thum-25.jpg</td>
<td>thum-26.jpg</td>
</tr>
<tr>
<td>thum-27.jpg</td>
<td>thum-28.jpg</td>
<td>thum-29.jpg</td>
</tr>
<tr>
<td>thum-30.jpg</td>
<td>thum-31.jpg</td>
<td>thum-32.jpg</td>
</tr>

nds_2.txt
<tr>
<td>thum-33.jpg</td>
<td>thum-34.jpg</td>
<td>thum-35.jpg</td>
</tr>
<tr>

psp_2.txt
<td>thum-01.jpg</td>
<td>thum-02.jpg</td>
<td>thum-03.jpg</td>
</tr>
<tr>
<td>thum-04.jpg</td>
<td>thum-05.jpg</td>
<td>thum-06.jpg</td>
</tr>
<tr>
<td>thum-07.jpg</td>
<td>thum-08.png</td>
<td>thum-09.jpg</td>
</tr>

psp_3.txt
<tr>
<td>thum-10.jpg</td>
<td>thum-11.jpg</td>
<td>thum-12.jpg</td>
</tr>
<tr>
<td>thum-13.jpg</td>
<td>thum-14.jpg</td>
<td>thum-15.jpg</td>
</tr>
<tr>


[ 本帖最后由 ganjie 于 2009-1-4 03:59 编辑 ]

lhjoanna

你是说psp后的数字与里面的文件个数有问题吧，把set n=0和set sign1=1放进第一个for循环中看下。