[文本处理] 文本批量替换字符的批处理求助

haichuan5121

各位大神好：
有一批文本内容格式如下；RCP格式可以记事本打开；判断文件名是否包含04T字符，不包含04T的文件将C0_E0后面的1,0,0或2,0,0替换为3,0,1
SMD-Product,C:\AV03-2322-1\Data\RecipeFile\ChmRcpData\R0001\AD IMPROVE-AB,1:C+W+M+C,1,1,0.7t,2023/07/24 18:02:37,C2,NotUse,C2,NotUse,LotClean,NotUse,Clean Cycle,NotUse,,C:\AV03-2322-1\Data\RecipeFile\PtnRcpData\S12100_P10_C0_E0,1,0,0,C:\AV03-2322-1\Data\RecipeFile\PtnRcpData\S12100_P02_C0_E0,2,0,0,S3 or S4,,
,,,,,,,,,,,,

Batcher

回复 1# haichuan5121


    找个真实的文件，把操作之前、操作之后的两份文件打包上传到网盘，我试试。

haichuan5121

回复 2# Batcher

内部局域网限制上传附件；文本全部内容就是下面字符RCP格式可以记事本打开，其中2,0,0也可能是1,0,0

SMD-Product,C:\A-B-1\Data\RecipeFile\ChmRcpData\R0001\AD IMPROVE-AB,1:C+W+M+C,1,1,0.7t,2023/07/24 18:02:37,C2,NotUse,C2,NotUse,LotClean,NotUse,Clean Cycle,NotUse,,C:\A-B-1\Data\RecipeFile\PtnRcpData\S12100_P10_C0_E0,2,0,0,C:\A-B-1\Data\RecipeFile\PtnRcpData\S12100_P02_C0_E0,2,0,0,S3 or S4,,
,,,,,,,,,,,,
变更后是
SMD-Product,C:\A-B-1\Data\RecipeFile\ChmRcpData\R0001\AD IMPROVE-AB,1:C+W+M+C,1,1,0.7t,2023/07/24 18:02:37,C2,NotUse,C2,NotUse,LotClean,NotUse,Clean Cycle,NotUse,,C:\A-B-1\Data\RecipeFile\PtnRcpData\S12100_P10_C0_E0,3,0,1,C:\A-B-1\Data\RecipeFile\PtnRcpData\S12100_P02_C0_E0,3,0,1,S3 or S4,,
,,,,,,,,,,,,

qixiaobin0715

没有测试文件，只能这样试试：

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.RCP^|findstr /v "04T"') do (
    (for /f "delims=" %%j in ('type "%%i"') do (
        set "str=%%j"
        set "str=!str:C0_E0,1,0,0=C0_E0,3,0,1!"
        set "str=!str:C0_E0,2,0,0=C0_E0,3,0,1!"
        echo,!str!
    ))>New-%%i
)
pause
复制代码

haichuan5121

回复 4# qixiaobin0715

执行结果是这个  ；批处理过程覆盖源文件了

   
C:\Users\admin\Desktop\PI\SP01>(
set "str=SMD-Product,C:\SH03-9322-1\Data\RecipeFile\ChmRcpData\R0001\AD IMPROVE-AB,1:C+W+M+C,1,1,0.7t,2023/07/24 18:02:37,C2,NotUse,C2,NotUse,LotClean,NotUse,Clean Cycle,NotUse,,C:\SH03-9322-1\Data\RecipeFile\PtnRcpData\S12100_P10_C0_E0,1,0,0,C:\SH03-9322-1\Data\RecipeFile\PtnRcpData\S12100_P02_C0_E0,2,0,0,S3 or S4,,"  
set "str=!str:C0_E0,1,0,0=C0_E0,3,0,1!"  
set "str=!str:C0_E0,2,0,0=C0_E0,3,0,1!"  
echo,!str!
)
SMD-Product,C:\SH03-9322-1\Data\RecipeFile\ChmRcpData\R0001\AD IMPROVE-AB,1:C+W+M+C,1,1,0.7t,2023/07/24 18:02:37,C2,NotUse,C2,NotUse,LotClean,NotUse,Clean Cycle,NotUse,,C:\SH03-9322-1\Data\RecipeFile\PtnRcpData\S12100_P10_C0_E0,3,0,1,C:\SH03-9322-1\Data\RecipeFile\PtnRcpData\S12100_P02_C0_E0,3,0,1,S3 or S4,,

C:\Users\admin\Desktop\PI\SP01>(
set "str=,,,,,,,,,,,,"  
set "str=!str:C0_E0,1,0,0=C0_E0,3,0,1!"  
set "str=!str:C0_E0,2,0,0=C0_E0,3,0,1!"  
echo,!str!
)
,,,,,,,,,,,,

qixiaobin0715

1.复制代码内容时，请点击代码下面的“复制代码”，不要选中复制；
2.最好发一个测试文件上来。
如果还不行，我就放弃吧。

aloha20200628

回复 3# haichuan5121

以下批处代码仅处理当前目录下文件名未含 04T 的文本文件，假设其扩展名为 .rcp
其中包含 C0_E0,1,0,0 或者 C0_E0,2,0,0 的字段均被置换为  C0_E0,3,0,1
新文件名=源文件名.new.rcp

@echo off &for /f "delims=" %%F in ('dir /b/a-d *rcp^|findstr /irvc:"04t" ') do (
      powershell "(gc '%%F') -replace 'C0_E0,\d,0,0', 'C0_E0,3,0,1' ">"%%~nF.new%%~xF"
)
pause&exit/b
复制代码

再让ps代劳一步...

@echo off & powershell "dir *.rcp -exclude '*04T*'|%%{((gc $_.name) -replace 'C0_E0,\d,0,0', 'C0_E0,3,0,1')|sc ($_.basename+'.new.rcp')}"
pause&exit/b
复制代码

77七

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.rcp ^|find /v "04T"') do (
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		if "%%b" equ "" (
			echo=
		) else (
			set str=%%b
			setlocal enabledelayedexpansion
			set str=!str:C0_E0,1,0,0=C0_E0,3,0,1!
			echo=!str:C0_E0,2,0,0=C0_E0,3,0,1!
			endlocal
		)
	))>"%%~ni_2%%~xi"
)
pause
复制代码

haichuan5121

回复 4# qixiaobin0715


    可以用了感谢感谢大神

qixiaobin0715

回复 9# haichuan5121
是漏掉了首行？@echo off

haichuan5121

回复 8# 77七


    可以可以 感谢！要把3,0,1变回1.0.0或2.0.0怎么写，能不能根据提示输入后执行；文档两个C0_E0后参数根据需求修改；
比如提示输入12 则内容  第一个3.0.1变更为1.0.0，第二个3.0.1变更为2.0.0
比如提示输入11 则内容  第一个3.0.1变更为1.0.0，第二个3.0.1变更为1.0.0
比如提示输入13 则内容  第一个3.0.1变更为1.0.0，第二个3.0.1变更为3.0.1

haichuan5121

回复 10# qixiaobin0715


       对的我看执行过程把OFF 改成ON了  
感谢！要把3,0,1变回1.0.0或2.0.0怎么写，C0_E0后面只有这三个组合
能不能根据提示输入后执行；文档两个C0_E0后参数根据需求修改；
比如提示输入12 则内容  第一个3.0.1变更为1.0.0，第二个3.0.1变更为2.0.0
比如提示输入11 则内容  第一个3.0.1变更为1.0.0，第二个3.0.1变更为1.0.0
比如提示输入13 则内容  第一个3.0.1变更为1.0.0，第二个3.0.1变更为3.0.1
比如提示输入21 则内容  第一个3.0.1变更为2.0.0，第二个3.0.1变更为1.0.0
比如提示输入22 则内容  第一个3.0.1变更为2.0.0，第二个3.0.1变更为2.0.0
比如提示输入23 则内容  第一个3.0.1变更为1.0.0，第二个3.0.1变更为3.0.1

qixiaobin0715

回复 12# haichuan5121
替换需要一个字符作为锚点，此字符不能在文本的任何地方出现，这里选为“`”，如果文本中含有此字符，请自行更换：

@echo off
set /p n=Please Input No. :
setlocal enabledelayedexpansion
set x1=C0_E0,1.0.0
set x2=C0_E0,2.0.0
set x3=C0_E0,3.0.1
for /l %%i in (1,1,3) do (
    for /l %%j in (1,1,3) do (
        set m=%%i%%j
        if !n! equ !m! (
            set a1=!x%%i!
            set a2=!x%%j!
        )
    )
)
for /f "delims=" %%i in ('dir /b /a-d *.RCP^|findstr /v "04T"') do (
    (for /f "delims=" %%j in ('type "%%i"') do (
        set "str=%%j"
        set "str=!str:C0_E0,3,0,1=`!"
        if "!str!"=="%%j" (
            echo,%%j
        ) else (
            for /f "tokens=1,2* delims=`" %%a in ("!str!") do (
                echo,%%a!a1!%%b!a2!%%c
            )
        )
    ))>New-%%i
)
pause
复制代码

这里也是针对顶楼所说的“文件名中不包含04T文件”。
代码未经测试，请注意备份好源文件，以免出现意外。

qixiaobin0715

回复 12# haichuan5121
刚刚注意到，你前面的数字之间是逗号，后面是点号，写代码时我也没注意，前后不统一，请根据文本具体情况自行修改。3.0.1————3,0,1

77七

回复 11# haichuan5121


   这个和1楼的替换应该是一回事，就是替换 两段C0_E0后数字，可以写个通用脚本，用批处理有点麻烦，用其它脚本或第三方文本工具的正则应该好点。