[文件操作] 批处理怎样将文件夹内的文件用文件夹名来重命名？

pujizhongxue

我手上有几十个文件夹，每个文件夹内都只有一个文件，我想将这些文件夹内的文件都用其所在的文件夹名称来重命名，系统是win10家庭版，请大家帮忙。

hfxiang

@echo off
@rem 保存为ANSI格式
cd /d "%~dp0"
for /f %%a in ('dir /a-d/s/b') do (
	if "%%~fa" NEQ "%~f0" (
		for %%b in ("%%~dpa.") do (
			move /y "%%~fa" "%%~dpa%%~nxb%%~xa"
		)
	)
)
复制代码

pujizhongxue

回复 2# hfxiang
十分感谢，但是有个奇怪的问题，这个批处理为什么换一个文件夹就失效了呢？

hfxiang

回复 3# pujizhongxue


    能把问题描述得具体些吗？

77七

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
    pushd "%%i"
    for /f "delims=" %%a in ('dir /b /a-d') do (
        ren "%%a" "%%~ni%%~xa"
    )
    popd
)
pause
复制代码

pujizhongxue

回复 4# hfxiang
@echo off
@rem 保存为ANSI格式
cd /d "%~dp0"

for /f %%a in ('dir /a-d/s/b') do (
        if "%%~fa" NEQ "%~f0" (
                for %%b in ("%%~dpa.") do (
                        move /y "%%~fa" "%%~dpa%%~nxb%%~xa"
                pause)
        )
)
我加了一个pause，发现提示是这样写的：找不到系统指定文件

hfxiang

回复 6# pujizhongxue


    用你加pause后的代码测试，只是多了个暂停，其它一切正常。

77七

回复 7# hfxiang


   应该是文件夹名或者文件名含特殊符号了

Batcher

回复 6# pujizhongxue


加个echo命令观察一下，看看代码是试图进行什么操作的时候报错了。

for /f %%a in ('dir /a-d/s/b') do (
    if "%%~fa" NEQ "%~f0" (
        for %%b in ("%%~dpa.") do (
            echo move /y "%%~fa" "%%~dpa%%~nxb%%~xa"
            move /y "%%~fa" "%%~dpa%%~nxb%%~xa"
            pause
        )
    )
)