[文本处理] 【已解决】求问批处理for如何把数据枚举成一行一行的？

hztccy

这是我的写的代码

@echo off
Setlocal enabledelayedexpansion

for /f "skip=1 delims=" %%i in ('wmic printer list brief') do (echo %%i)

pause
复制代码

我想通过for把命令wmic printer list brief获取到的打印机信息按一行一行输入

然后我可以通过set /p的选择方式给出道其他其他代码使用

类似一个这样的代码操作

setlocal enabledelayedexpansion
set 序号=1
for /f "delims=" %%i in ('dir /b "路径"') do ( 
set 文件[!序号!]=%%~nxi
echo -----------------------------
echo  ^>^>^>（!序号!）%%i 
set /a 序号+=1)
echo -----------------------------
echo.
set /p 选择=-输入序号：
if not "%选择%"=="" (操作) else (goto :返回)
cls
set 序号=1
for /f "delims=" %%i in ('dir /b "C:\123"') do ( 
set 文件[!序号!]=%%~nxi
echo -----------------------------
echo  ^>^>^>（!序号!）%%i 
set /a 序号+=1)
echo -----------------------------
echo.
复制代码

Batcher

回复 1# hztccy


请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
setlocal enabledelayedexpansion
set "n=0"
for /f "tokens=1* delims==" %%a in ('wmic printer get name /value ^| find "Name="') do (
    set "Printer_!n!=%%b"
    set /a n+=1
)
set Printer_
set /p InuputNum=Choose your printer number:
echo,!Printer_%InuputNum%!
pause
复制代码

hztccy

回复  hztccy


请参考Q-04把bat文件保存为ANSI编码：
Batcher 发表于 2022-7-1 09:28

    非常感谢版主大大，主要我个人对for里面的set /a 和 ！这类搞不明白，非常感谢

hztccy

回复  hztccy


请参考Q-04把bat文件保存为ANSI编码：
Batcher 发表于 2022-7-1 09:28

    我把结果输出给rundll32 printui.dll,PrintUIEntry出现无法调用



下图输出的名称给不到使用

hztccy

回复 2# Batcher


    版主大大，有空吗？帮我看看怎么处理

Batcher

回复 4# hztccy

@echo off
setlocal enabledelayedexpansion
set "n=0"
for /f "tokens=1* delims==" %%a in ('wmic printer get name /value ^| find "Name="') do (
    for /f "delims=" %%c in ("%%b") do (
        set "Printer_!n!=%%c"
    )
    set /a n+=1
)
set Printer_
set /p InuputNum=Choose your printer number:
echo,!Printer_%InuputNum%!
pause
复制代码

hztccy

回复 6# Batcher


    哥，能我帮我解释一下原理吗？后面的第二次循环没看懂

Batcher

回复 7# hztccy


批处理调用WMIC时如何处理结果中的特殊字符？
http://bbs.bathome.net/thread-2862-1-1.html
http://bbs.bathome.net/thread-28534-1-1.html
http://bbs.bathome.net/thread-28535-1-1.html
http://bbs.bathome.net/thread-12033-1-1.html