[文本处理] 【已解决】BAT脚本如何批量去掉文件名某个字符前后的内容

草旺角

我在网上找到一个可以批量去掉文件名某个字符前内容的批处理
如下：

@echo off
setlocal enabledelayedexpansion
set /p str=请输入要删除哪个字符串前的内容:
for %%i in ("*%str%*") do (
set "FileName=%%i"
set "FileName=!FileName:*%str%=!"
echo !FileName!
ren "%%i" "!FileName!"
)
pause
复制代码

但有个缺点，这个批处理在删除时会把我指定的字符一起删除。比如我重命名001abc011.mp4、002abc012.mp4文件时，指定abc字符，但批处理会把abc一起删除，变成011.mp4、012.mp4。而我想保留abc字符只删除前面的，变成abc011.mp4、abc012.mp4，不知怎么改进这个批处理呢？
另外想求教下如何改进这个批处理使其能批量去掉文件名某个字符后的内容呢？

qixiaobin0715

回复 1# 草旺角

命名时再加上就行。
ren "%%i" "!FileName!"
改为
ren "%%i" "%str%!FileName!"

ivor

#&cls&@powershell "Invoke-Expression ([Io.File]::ReadAllText('%~0',[Text.Encoding]::UTF8))" &pause&exit
$deltext="abc"
dir *.* | %{Rename-Item $_ -NewName ($_.name -replace "$deltext","") -verbose}
复制代码

qixiaobin0715

回复 1# 草旺角
删除指定字符后面的字符

@echo off
setlocal enabledelayedexpansion
set /p str=请输入特定字符串:
for %%i in ("*%str%*") do (
    set "FileName=%%i"
    set "FileName1=!FileName:*%str%=!"
    for %%a in ("!FileName1!") do set "FileName=!FileName:%%~na=!"
    ren "%%i" "!FileName!"
)
pause
复制代码

yhcfsr

回复 1# 草旺角


    第6行改为

set "FileName=!FileName:*%str%=%str%!"
复制代码

qixiaobin0715

回复 5# yhcfsr

这样修改好，非常直观。

草旺角

回复 2# qixiaobin0715


非常感谢

草旺角

回复 4# qixiaobin0715


  非常感谢

草旺角

回复 5# yhcfsr


  非常感谢

草旺角

回复 5# yhcfsr

草旺角

回复 3# ivor


    非常感谢