[文件操作] 请教批处理命令IF使用

临江仙2019

有个实际需求，每天要下载相关文件，但在命名时规则要调整为XX+YYMMDD.xlsx（这里的YYMMDD指的是上一个工作日）。
百度了部分资料，脚本如下：

rem 计算指定天数之前的日期
rem 假设系统日期的格式为yyyy-mm-dd
if defined %date:~-3%==周一 (
echo num=3
)else echo num=1
set DaysAgo=num
call ateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
echo %DaysAgo%天的日期是%DstMonth%月%DstDay%日
ren XX.xlsx XX%date:~0,4%%DstMonth%%DstDay%.xlsx
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF


这里有个问题，给 DaysAgo赋值的时候，总是num，而不是if函数中判断的num，请教如何将if函数判断的num赋值给 DaysAgo
盼大神解答，谢谢

smss

if %date:~-3%==周一 (set DaysAgo=3)else set DaysAgo=1
复制代码

set DaysAgo=num删除

Batcher

if "%date:~-2%" equ "周一" (
    set num=3 
) else (
    set num=1
)
set DaysAgo=%num%
复制代码

1. defined 是用来判断某个变量是否存在，而不是判断两个字符串是否相等。
2. 赋值需要使用 set 命令而不是 echo 命令
3. 赋值操作的时候等号右边的变量加上百分号