[代码合集] 自己修改的一个工具合集，请帮忙优化一下，多多指教

wom087

@Echo Off
Setlocal enabledelayedexpansion
title  CMD 工 具 箱
cls
setlocal
set user=
set pwd=
set times=4

:check
echo.
echo This is a secure system. Authorized Access Only!!!
echo.
echo User Access Verification
echo.
set /p user= Login: 
set /p pwd= Password: 
if "%user%"=="admin" (if "%pwd%"=="admin" goto :CMDTool)
REM                                       
if %times%==0 goto :Close
set /A times=%times%-1
set /a checkup=%times%+1
echo.
echo 帐号密码错误,还有%checkup%机会^^!
pause>nul & cls
goto :check

:Close
echo.
echo Logon Failed^^!
pause>nul
exit


:CMDTool
title  CMD 工 具 箱
color 2f
//mode con: cols=80 lines=27
cls
@Echo Off
echo                        ────────────────  
echo     ─────────┤        　CMD 工 具 箱　      ├─────────
echo    │                  ────────────────                   │
echo    │  [1] WIFI共享网络工具                    [2] 自动关机               │
echo    │                                                                     │
echo    │  [3] 停止自动关机                        [4] Ping网段所有IP         │
echo    │                                                                     │
echo    │  [5] 请算1到n的总和                      [6] 清理系统垃圾           │
echo    │                                                                     │
echo    │  [7] JAVA小工具                          [8] 重新启动打印服务       │
echo    │                                                                     │
echo    │  [9] 生成一键以管理员运行                [A] IP释放并更新           │
echo    │                                                                     │
echo    │  [B] BAT加密工具                         [C] IP显示主机名和MAC      │
echo    │                                                                     │
echo    │  [D] 显示系统信息                        [E] 跟踪指定IP或域名路由   │
echo    │                                                                     │
echo    │  [F] 添加右键获取管理员所有权            [G] 局域网共享工具         │
echo    │                                                                     │
echo    │  [H] 显示使用TCP^&UDP端口的进程           [I] 禁启用任务管理器       │
echo    │                                                                     │
echo    │  [0] 退出                                17年11月17日               │
echo     ───────────────────────────────────
Echo.
choice /C 123456789abcdefghi0  /d 0 /t 30  /M "请选择！！30秒自动退出
if errorlevel 19 exit
if errorlevel 18 Goto :CMDTool18
if errorlevel 17 Goto :CMDTool17
if errorlevel 16 Goto :CMDTool16
if errorlevel 15 Goto :CMDTool15
if errorlevel 14 Goto :CMDTool14
if errorlevel 13 Goto :CMDTool13
if errorlevel 12 Goto :CMDTool12
if errorlevel 11 Goto :CMDTool11
if errorlevel 10 Goto :CMDTool10
if errorlevel 9 Goto :CMDTool9
if errorlevel 8 Goto :CMDTool8
if errorlevel 7 Goto :CMDTool7
if errorlevel 6 Goto :CMDTool6
if errorlevel 5 Goto :CMDTool5
if errorlevel 4 Goto :CMDTool4
if errorlevel 3 Goto :CMDTool3
if errorlevel 2 Goto :CMDTool2
if errorlevel 1 Goto :CMDTool1


Rem =========================WIFI 共 享 网 络 工 具================================

:CMDTool1
color 5f
title  WIFI 共 享 网 络 工 具 
cls
echo                     ───────────────  
echo     ───────┤    WIFI 共 享 网 络 工 具   ├────────
echo    │               ───────────────                 │
echo    │                                                              │
echo    │[1] 开始配置共享网络（如SSID和WIFI密码） [2] 启用无线共享     │
echo    │                                                              │
echo    │[3] 停止无线共享                         [4] 删除共享网络配置 │
echo    │                                                              │
echo    │[5] 显示连接的客户端                     [6]返回主菜单        │
echo    │                                                              │
echo    │[0] 退出                                 17年10月28日         │
echo     ────────────────────────────────
choice /C 1234560 /M "请选择！！
if errorlevel 7 exit
if errorlevel 6 Goto :CMDTool
if errorlevel 5 Goto :wifiset4
if errorlevel 4 Goto :wifiset3
if errorlevel 3 Goto :wifiset2
if errorlevel 2 Goto :wifiset1
if errorlevel 1 goto :wifiset

Rem ====================开始配置共享网络（如SSID和WIFI密码）=======================

:wifiset
cls
set ssid=
set pass=
choice /C YN /M "是否设置共享网络，按Y设置，按N返回菜单
if errorlevel 2 Goto :CMDTool1
if errorlevel 1 echo Please wait....
cls
netsh wlan stop hostednetwork
netsh wlan set hostednetwork mode=disallow
cls
Echo		本程序是Windows7以上系统共享WIFI设置的工具。
Echo		注：计算机必须要两个以上可用的网卡，且要一个是无线网卡。
Echo.
Set /p ssid=请输入SSID名字，默认为360WIFI-AC:
Set /p pass=请输入WIFI密码，默认为1234567890:
if "!ssid!"=="" set ssid=360WIFI-AC
if "!pass!"=="" set pass=1234567890
netsh wlan set hostednetwork mode=allow ssid=%ssid% key=%pass%
netsh wlan start hostednetwork
netsh interface set interface name="本地连接 2" newname="虚拟WIFI"
cls
Echo	设置Internet连接共享
Echo	右键,宽带连接（不用宽带连接的就用本地连接）,选择“属性”
Echo	“共享”，勾上“允许其他······连接(N)”并选择“虚拟WiFi”。
Echo	===================================================================
Echo	WIFI共享配置成功，WIFI名字为%ssid%,密码为%pass%,请牢记！任意键返回……
pause>nul && goto :CMDTool1

Rem ================================启用无线共享================================

:wifiset1
cls
netsh wlan start hostednetwork
cls
Echo		网络共享已启动，任意键返回……
pause>nul && goto :CMDTool1

Rem ===================================停止无线共享===============================

:wifiset2
cls
netsh wlan stop hostednetwork
cls
Echo		网络共享已停用，任意键返回……
pause>nul && goto :CMDTool1

Rem ====================================删除共享网络配置================================

:wifiset3
cls
netsh wlan stop hostednetwork
netsh wlan set hostednetwork mode=disallow
cls
Echo		网络共享已删除，任意键返回……
pause>nul && goto :CMDTool1

Rem =====================================显示连接的客户端================================

:wifiset4
cls
netsh wlan show hostednetwork
Echo	=================任意键返回=================
pause>nul && goto :CMDTool1


Rem =====================================这是自动关机程序================================

:CMDTool2
@echo off
shutdown -a
set settime=
set sum=
set time_begin=%time:~0,-6%
for /f "tokens=1,2 delims=:" %%i in ("%time_begin%") do (
    set /a hour_b=%%i
    set /a munite_b=%%j
)

set date_begin=%date%
for /f "tokens=1,2,3 delims=-" %%i in ("%date_begin%") do (
    set /a yea_b=%%i
    set /a mon_b=%%j
    set /a dat_b=%%k
)
cls
echo 当前时间是%yea_b%年%mon_b%月%dat_b%日%time_begin%[Q=主菜单]
echo.
set /p settime=请输入分钟[n]或具体时间[如12:30]:
if /i "!settime!"=="Q" Goto :CMDTool
if "!settime!"=="" Goto :CMDTool2

echo %settime%|findstr ":">nul && Goto :shutdown2 || Goto :shutdown1


:shutdown1
if !settime! lss 1 goto :CMDTool2
if !settime! gtr 1440 goto :CMDTool2
set /a sum=%settime%
set /a hour_=%settime%/60
set /a munite_=%settime%%%60
Goto :Showtime

:shutdown2
set time_end=%settime%
for /f "tokens=1,2 delims=:" %%i in ("%time_end%") do (
    set /a hour_e=%%i:~2
    set /a munite_e=%%j:~2
)
if not defined hour_e Goto :CMDTool2
if not defined munite_e Goto :CMDTool2
if %hour_e% lss 0 Goto :CMDTool2
if %hour_e% gtr 23 Goto :CMDTool2
if %munite_e% lss 0 Goto :CMDTool2
if %munite_e% gtr 59 Goto :CMDTool2
echo %hour_e% : %munite_e%
call :time_lapse
@set /a sum=%hour_%*60+%munite_%

:Showtime
@set /a a=!sum!*60
cls
echo 剩余 %hour_% 小时 %munite_% 分，合计 %sum% 分钟。
echo.
choice /C YNC /M "计算机将在%sum%分钟后自动关闭,是请按 Y ，按 N 重输，按C返回主菜单
if errorlevel 3 Goto :CMDTool
if errorlevel 2 Goto :CMDTool2
if errorlevel 1 Goto :DW

:DW
::echo @ECHO OFF >>aaa.bat
::echo title 倒计时 >>aaa.bat
::echo SETLOCAL ENABLEDELAYEDEXPANSION >>aaa.bat
::echo mode con: cols=40 lines=3 >>aaa.bat
::echo for /F "usebackq delims=, tokens=2" %%%%a in (`"Tasklist /v /fo csv | findstr /i "倒计时""`) do (  >>aaa.bat
::echo set /a PID=%%%%~a  >>aaa.bat
::echo ) >>aaa.bat
::echo SET /a s=%%a%% >>aaa.bat
::echo :AAA >>aaa.bat
::echo FOR /l %%%%i in (1,1,%%s%%) do ( >>aaa.bat
::echo SET /a s-=1 >>aaa.bat
::echo choice /T 1 /C QY /D Y /N ^>nul >>aaa.bat
::echo if %%s%%==120 msg %%username%% /time:5 "系统即将在120秒后关闭，请注意保存资料" ^& goto :AAA >>aaa.bat
::echo if errorlevel 2 cls ^& echo 倒计时开始 %%s%% 按Q关闭自动关机并退出 ^& goto :AAA >>aaa.bat
::echo if errorlevel 1 del aaa.bat ^& shutdown -a ^& taskkill /F /PID %%PID%% /T >>aaa.bat
::echo ) >>aaa.bat
::echo mshta vbscript:msgbox("系统即将关闭",64,"自动关机提醒")(window.close) >>aaa.bat
::echo del aaa.bat >>aaa.bat
::echo :eof >>aaa.bat
::start aaa.bat %a%
shutdown -a & cls & shutdown -s -f -t %a%
echo 自动关机设置完成，请查看屏幕右下角信息，任意键返回主菜单
pause>nul & Goto :CMDTool

:time_lapse
if %munite_e% lss %munite_b% (
    set /a hour_e=%hour_e%-1
    set /a munite_e=%munite_e%+60
)
set /a munite_=%munite_e%-%munite_b%

if %hour_e% lss %hour_b% (
    set /a hour_e=%hour_e%+24
)
set /a hour_=%hour_e%-%hour_b%
Goto :eof

Rem =====================================这是取消自动关机程序================================

:CMDTool3
cls
Echo.
choice /C YN /M "是否取消自动关机,是请按 Y ，否按 N 返回主菜单
if errorlevel 2 Goto :CMDTool
if errorlevel 1 shutdown -a
cls
Echo 自动关机已取消，任意键返回……
pause>nul && goto :CMDTool

Rem =====================================Ping网段所有IP================================

:CMDTool4
if exist "D:\pingall.log" del D:\pingall.log
cls
Set Ping= & set /a a=-1 & set /a b=-1 & set /a c=-1
Set /p Ping=请输入要Ping的网段[Q=主菜单]：
if /i "!Ping!"=="Q" Goto :CMDTool
if "!Ping!"=="" Goto :CMDTool4
for /f "tokens=1,2,3 delims=." %%i in ("%Ping%") do set /a "a=%%i" & set /a "b=%%j" & set /a "c=%%k"
if not defined c Goto :CMDTool4
if %a% lss 1 Goto :CMDTool4
if %b% lss 0 Goto :CMDTool4
if %c% lss 0 Goto :CMDTool4
if %a% gtr 255 Goto :CMDTool4
if %b% gtr 255 Goto :CMDTool4
if %c% gtr 255 Goto :CMDTool4
:SetRange
set Range= & set /a d=0 & set /a e=0
cls
Set /p Range=请输入%a%.%b%.%c%的范围[1-255]：
for /f "tokens=1,2 delims=-" %%l in ("%Range%") do set /a "d=%%l" & set /a "e=%%m"
if not defined e Goto :SetRange
if %d% gtr %e% Goto :SetRange
if %d% lss 1 Goto :SetRange
if %e% lss 1 Goto :SetRange
if %d% gtr 255 Goto :SetRange
if %e% gtr 255 Goto :SetRange

set /a sum=%e%-%d%
if %sum% lss 15 (Goto :SinglePing) else Goto:MultiPing

Echo Please wait....

:SinglePing
for /l %%i in (%d%,1,%e%) do (ping -n 1 -l 1 -w 6 %a%.%b%.%c%.%%i | find "来自" >>D:\pingall.log & echo 正在Ping%a%.%b%.%c%.%%i中，请稍候..)
cls & Goto :ShowPing

:MultiPing

echo wscript.sleep 10 >>sleep.vbs
echo ping ^%%1 -n 1 -l 1 -a >>checkip.bat
echo if ^%%errorlevel^%%==0 (echo ^%%1 OK^>^>D:\pingall.log) >>checkip.bat
for /l %%i in (%d%,1,%e%) do (@cscript sleep.vbs >nul & start /min cmd /c checkip.bat %a%.%b%.%c%.%%i & @echo on & echo 正在Ping%a%.%b%.%c%.%%i中，请稍候.. & @echo off) 

:ShowPing
if exist "sleep.vbs" del sleep.vbs
if exist "checkip.bat" del checkip.bat & cls
if not exist "D:\pingall.log" echo %a%.%b%.%c%.%Range%的范围错误或没在使用！请重新输入 & pause>nul & Goto :CMDTool4
set n=0
for /f "delims=" %%a in ('type "D:\pingall.log"') do set /a n+=1
if "%n%"=="0" echo %a%.%b%.%c%.%Range%的范围错误或没在使用！请重新输入 & pause>nul & Goto :CMDTool4
type D:\pingall.log
echo.
echo %a%.%b%.%c%.%Range%的范围共%n%个IP在使用中
echo.
choice /C YN /M "是否保存并查看记录文件，查看请按 Y ，删除请按 N
if errorlevel 2 del d:\pingall.log & Goto :CMDTool
if errorlevel 1 start /wait notepad.exe d:\pingall.log & Goto :CMDTool

Rem =====================================请算1到n的总和================================

:CMDTool5
cls
set n=
set /p n=输入你想计算的数字n[Q=主菜单]：
if /i "!n!"=="Q" Goto :CMDTool
if "!n!"=="" Goto :CMDTool5
if %n% lss 1 Goto :CMDTool5
if %n% gtr 999999999 Goto :CMDTool5
for /l %%i in (1 1 %n%) do ( set /a sum=sum+%%i)
echo 1+2+....+n=%sum%
pause>nul && goto :CMDTool

Rem =====================================清理系统垃圾================================

:CMDTool6
color 5a
cls
@echo off
echo 正在清除系统垃圾文件，请稍等......
del /f /s /q  %systemdrive%\*.tmp
del /f /s /q  %systemdrive%\*._mp
del /f /s /q  %systemdrive%\*.log
del /f /s /q  %systemdrive%\*.gid
del /f /s /q  %systemdrive%\*.chk
del /f /s /q  %systemdrive%\*.old
del /f /s /q  %systemdrive%\recycled\*.*
del /f /s /q  %windir%\*.bak
del /f /s /q  %windir%\prefetch\*.*
rd /s /q %windir%\temp & md  %windir%\temp
del /f /q  %userprofile%\cookies\*.*
del /f /q  %userprofile%\recent\*.*
del /f /s /q  "%userprofile%\Local Settings\Temporary Internet Files\*.*"
del /f /s /q  "%userprofile%\Local Settings\Temp\*.*"
del /f /s /q  "%userprofile%\recent\*.*"
echo 清除系统LJ完成！任意键返回
pause>nul && goto :CMDTool

Rem =====================================这是JAVA小工具程序================================

:CMDTool7
cls  
@echo off  
title JAVA 小 工 具 
color 3f   
cls
set /p Dr=设置JAVA原码目录[Q=主菜单]：
if /i "!Dr!" =="Q" Goto :CMDTool
if "!Dr!" =="" Goto :CMDTool7
if not exist !Dr! (Goto :CMDTool7)
cd /d !Dr!
:java
set class=
set name=
set name2=
set name3=
cls
echo                     ───────────────  
echo     ───────┤     Java Applet 小 工 具     ├────────
echo    │               ───────────────                 │
echo    │                                                              │
echo    │[1] 新建JAVA程序                 [2] 编译JAVA程序             │
echo    │                                                              │
echo    │[3] 生成Html文件                 [4] 运行Java程序             │
echo    │                                                              │
echo    │[5] 返回主菜单                   [M] 浏览目录文件             │
echo    │                                                              │
echo    │[0] 退出                             17年10月30日             │
echo     ────────────────────────────────
echo     当前JAVA原码目录为%Dr%，按M可浏览目录文件
Echo.
choice /C 12345M0 /M "请选择！！
if errorlevel 7 exit
if errorlevel 6 start %Dr% && goto :java
if errorlevel 5 Goto :CMDTool
if errorlevel 4 Goto :java3
if errorlevel 3 Goto :java2
if errorlevel 2 Goto :java1
if errorlevel 1 goto :CreateClass

:CreateClass
cls
Echo		[1]新建JAVA程序
set class=
set identify=0
set /p class=请输入类名：
If exist "!class!".java cls & echo 注意:文件%class%.java已存在，请从输入！！！& pause>nul & Goto :CreateClass
if "!class!"=="" cls & echo 注意: 类名不能为空！！！& echo 提示：类名必须符合Java命名标准（如：类名第一个字符不能为数字）& pause>nul & goto CreateClass
for /l %%i in (0,1,9) do (
if "%class:~0,1%"=="%%i" set identify=1
)
if "%identify%"=="0" (Goto :Begin) else ( cls & echo 注意: 类名不符合Java命名标准,请从输入！！！&echo 提示：类名必须符合Java命名标准（如：类名第一个字符不能为数字）& pause>nul & Goto :CreateClass)

:Begin
echo public class %class%{  >%Dr%\%class%.java
echo	   public static void main(String[] args) {   >>%Dr%\%class%.java
echo                          /*请输入编程内容*/	 >>%Dr%\%class%.java
echo. >>%Dr%\%class%.java
echo. >>%Dr%\%class%.java
echo. >>%Dr%\%class%.java
echo. >>%Dr%\%class%.java
echo	}             >>%Dr%\%class%.java
echo }  >>%Dr%\%class%.java

:Modify
start /wait notepad.exe %Dr%\%class%.java

:Build
set build=0
choice /C YN /M "是否需要编译%class%.java,请按 Y 编绎，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java1

:java1
cls
Echo		[2]编译JAVA程序
set name=%class%
set /p name=	请输入文件名默认为%class%[C=菜单]:
if /i "!name!"=="C" Goto :java
If not exist %name%.java Goto :java1
javac %name%.java
If exist !name!.class Goto :if1
Echo	编译错误，请查看错误代码！
choice /C YN /M "请按 Y 返回重输，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java1

:if1
Echo	%name%.class编译成功,请牢记！
choice /C YN /M "请按 Y 生成Html，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java2

:java2
cls
Echo		[3] 生成Html文件
set name2=%name%
set /p name2=	请输入文件名默认为%name%[C=菜单]:
if "!name2!"=="" Goto :java2
if /i "!name2!"=="C" Goto :java
if exist "!name2!".class Goto :if2
choice /C YN /M "找不到%name2%.class，按 Y 重输，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java2

:if2
Echo ^<html^> >>%name2%.html
Echo ^<body^> >>%name2%.html
Echo ^<applet code = "%name2%.class" height = 500 width = 800^> >>%name2%.html
Echo ^</applet^> >>%name2%.html
Echo ^</body^> >>%name2%.html
Echo ^</html^> >>%name2%.html
cls
Echo	%name2%.html已生成,请牢记！
choice /C YN /M "请按 Y 调试程序，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java3

:java3
cls
Echo		[4] 运行Java程序
set name3=%name2%
set /p name3=	请输入文件名默认为%name2%[C=菜单]:
if /i "!name3!"=="C" Goto :java
if "!name3!"=="" Goto :java3
if exist "!name3!".html Goto :if3
choice /C YN /M "找不到%name3%.html，按 Y 重输，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java3

:if3
appletviewer %name3%.html
cls
Echo		Java程序已停止，任意键返回……
pause>nul && Goto :java

::=============================重启打印服务=========================================

:CMDTool8
cls
choice /C YN /M "是否需要重启打印服务，按 Y 重启，或按 N 取消并返回主菜单
if errorlevel 2 Goto :CMDTool
if errorlevel 1 echo Please wait....
sc stop spooler
echo.wscript.sleep(1000)>sleep.vbs
cscript //nologo sleep.vbs
del sleep.vbs
choice /C YN /M "是否需要清理打印任务，按 Y 清理，或按 N 不清理
if errorlevel 2 sc start spooler
if errorlevel 1 echo y|del %windir%\system32\spool\printers\*.*
sc start spooler
cls
echo 打印服务已重新启动.任意键返回主菜单
pause>nul && Goto :CMDTool

::===========================生成一键以管理员启动程序BAT================================

:CMDTool9
cls
Echo 任意地方输入字母Q可返回主菜单
set /p Name=请输入用户名[域Domain\User]:
if /i "!Name!"=="Q" Goto CMDTool
set /p Pass=请输入密码[注：特殊符号可能有问题]:
if /i "!Pass!"=="Q" Goto CMDTool
:Program
cls
set /p Program=请输入程序或直接把程序拖至本窗口释放:
if /i "!Program!"=="Q" Goto CMDTool
if not exist !Program! (Goto :Program)
choice /C YN /M "是否以管理员："%Name%"生成一键以管理员启动程序BAT，按 Y 生成，或按 N 返回主菜单
if errorlevel 2 Goto :CMDTool
if errorlevel 1 echo Please wait....
Echo ^@if (@CodeSection == @Batch) @then >>1KeyRunAsAdmin.bat
Echo ^@echo off >>1KeyRunAsAdmin.bat
Echo start "" runas /user:%Name% %Program% >>1KeyRunAsAdmin.bat
ECHO.set sh=WScript.CreateObject("WScript.Shell")>1KeyRunAsAdmin.VBS 
ECHO.WScript.Sleep 2000   >>1KeyRunAsAdmin.VBS 
ECHO.sh.SendKeys "%Pass%"   >>1KeyRunAsAdmin.VBS 
ECHO.sh.SendKeys "{enter}"  >>1KeyRunAsAdmin.VBS 
ECHO.start /B cmd.EXE  >>1KeyRunAsAdmin.bat
ECHO.cscript //nologo   1KeyRunAsAdmin.VBS    >>1KeyRunAsAdmin.bat 

Echo 已生成1KeyRunAsAdmin.bat,请检查第一个SendKeys后的密码是否正确，修改后请保存。

start /wait notepad.exe 1KeyRunAsAdmin.VBS

set build=0
choice /C YN /M "是否立即运行程序，按 Y 运行，或按 N 返回主菜单
if errorlevel 2 Goto:CMDTool
if errorlevel 1 start 1KeyRunAsAdmin.bat

::===============================IP释放并更新==============================================

:CMDTool10
cls
choice /C YN /M "是否立即释放并更新IP，期间网络将会短暂断开，按 Y 运行，或按 N 返回主菜单
if errorlevel 2 Goto:CMDTool
if errorlevel 1 echo 正在更新IP信息.....
ipconfig /release
ipconfig /renew
cls
Echo IP已释放并更新，任意键返回主菜单
pause>nul && Goto :CMDTool

::====================================BAT 加 密 工 具===============================================

:CMDTool11
cls
%%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a %%a   
cls  
@echo off  
title BAT 加 密 工 具 
color 1f  
:start  
cls
echo                        ────────────────  
echo     ─────────┤     　 BAT 加 密 工 具 　    ├──────────
echo    │                  ────────────────                    │
echo    │                                                                      │
echo    │            1、本工具用来对明文批处理文件进行加密!                    │
echo    │                                                                      │
echo    │            2、直接把待加密批处理文件拖至本窗口释放即可!              │
echo    │                                                                      │
echo    │            3、加密后会在当前目录下生成NewCode.bat文件!               │
echo    │                                                                      │
echo    │                                        17年09月18日                  │
echo     ────────────────────────────────────  
echo.
set /p file=请输入需要加密的批处理文件名后按回车键[Q=主菜单]: 
if "%file%"=="Q" goto :CMDTool
echo %file%|findstr /i "\.bat">nul && goto :go
echo %file%|findstr /i "\.c*">nul && goto :go
cls
echo ==============
echo 请正确输入!
echo ==============
echo.
echo.
echo 按任意键重新输入......
pause>nul && goto :start
:go
if not exist "%file%" goto :newly
if exist encrypt.bat copy encrypt.bat encryptbak.bat
echo %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a >"%tmp%\encrypt.tmp"
echo cls>>"%tmp%\encrypt.tmp"
type "%file%">>"%tmp%\encrypt.tmp"
setlocal enabledelayedexpansion
for %%i in ("%tmp%\encrypt.tmp") do (
    echo %%~zi >nul 2>nul
    set size=%%~zi
    set num=!size:~-1!
    set /a mod=!num!%%2
    if !mod! equ 0 (goto :even) else (goto :odd)
)
:even
copy "%tmp%\encrypt.tmp" NewCode.bat
del "%tmp%\encrypt.tmp"
cls
echo ==========================================
echo 恭喜你, 批处理加密成功,已保存为NewCode.bat
echo ==========================================
echo.
echo.
echo 按任意键返回主菜单......
pause>nul && goto :CMDTool
:odd
echo. >>"%tmp%\encrypt.tmp"
copy "%tmp%\encrypt.tmp" NewCode.bat
del "%tmp%\encrypt.tmp"
cls
echo ==========================================
echo 恭喜你, 批处理加密成功,已保存为NewCode.bat
echo ==========================================
echo.
echo.
echo 按任意键返回主菜单......
pause>nul && goto :CMDTool
:newly
cls
echo ================================
echo 找不到批处理文件, 请重新输入!
echo ================================
echo.
echo.
echo 按任意键开始......
pause>nul && goto :start
:quit
exit

::===============================IP显示主机名和MAC=======================

:CMDTool12
cls
set IpAdd=
set /p IpAdd=请输入要查询的IP地址[Q=主菜单]:
if /i "!IpAdd!"=="Q" Goto :CMDTool
echo %IpAdd%|findstr "^[0-9]*\.[0-9]*\.[0-9]*\.[0-9]*$">nul|| (echo 输入错误,按任意键重输^^! & pause>nul & goto :CMDTool12)
set _IpAdd=%IpAdd:.= %
call :checkIpAdd %_IpAdd%
:checkIpAdd
if "%4"=="" (echo 输入错误,按任意键重输^^! & pause>nul & goto :CMDTool12)
for %%i in (%1 %2 %3 %4) do (
    if %%i gtr 255 (echo 输入错误,按任意键重输^^! & pause>nul & goto :CMDTool12)
)
nbtstat -A %IpAdd%
echo 按任意键返回主菜单...... 
pause>nul && Goto :CMDTool

::=============================显示系统信息===============================

:CMDTool13
cls
systeminfo
echo 按任意键返回主菜单......
pause>nul && Goto :CMDTool

:============================跟踪指定IP的路由=============================

:CMDTool14
cls
set Router=
set /p Router=请输入要跟踪的IP或域名[Q=主菜单]:
if /i "!Router!"=="Q" Goto :CMDTool
cls
echo 正在跟踪%Router%所通过的路由中,请稍后.....
tracert %Router%
echo 按任意键返回主菜单...... 
pause>nul && Goto :CMDTool

::===========================获取管理员所有权================================

:CMDTool15
cls
echo 正在添加权限........
echo Windows Registry Editor Version 5.00 >>reg.reg
echo [HKEY_CLASSES_ROOT\*\shell\runas] >>reg.reg
echo ^@="获取管理员所有权" >>reg.reg
echo "NoWorkingDirectory"="" >>reg.reg
echo [HKEY_CLASSES_ROOT\*\shell\runas\command] >>reg.reg
echo ^@="cmd.exe /c takeown /f \"^%%1\" && icacls \"^%%1\" /grant administrators:F" >>reg.reg
echo "IsolatedCommand"="cmd.exe /c takeown /f \"^%%1\" && icacls \"^%%1\" /grant administrators:F" >>reg.reg
echo [HKEY_CLASSES_ROOT\exefile\shell\runas2] >>reg.reg
echo ^@="获取管理员所有权" >>reg.reg
echo "NoWorkingDirectory"="" >>reg.reg
echo [HKEY_CLASSES_ROOT\exefile\shell\runas2\command] >>reg.reg
echo ^@="cmd.exe /c takeown /f \"^%%1\" && icacls \"^%%1\" /grant administrators:F" >>reg.reg
echo "IsolatedCommand"="cmd.exe /c takeown /f \"^%%1\" && icacls \"^%%1\" /grant administrators:F" >>reg.reg
echo [HKEY_CLASSES_ROOT\Directory\shell\runas] >>reg.reg
echo ^@="获取管理员所有权" >>reg.reg
echo "NoWorkingDirectory"="" >>reg.reg
echo [HKEY_CLASSES_ROOT\Directory\shell\runas\command] >>reg.reg
echo ^@="cmd.exe /c takeown /f \"^%%1\" /r /d y && icacls \"^%%1\" /grant administrators:F /t" >>reg.reg
echo "IsolatedCommand"="cmd.exe /c takeown /f \"^%%1\" /r /d y && icacls \"^%%1\" /grant administrators:F /t" >>reg.reg


regedit /s reg.reg
del reg.reg
echo 添加完成，按任意键返回主菜单...... 
pause>nul && Goto :CMDTool

::===================================这是局域网共享工具程序================================

:CMDTool16
cls
@echo off
title 局 域 网 共 享 工 具
color 4f
cls
echo                     ───────────────  
echo     ───────┤     局 域 网 共 享 工 具     ├────────
echo    │               ───────────────                 │
echo    │                                                              │
echo    │[1] 开通局域网共享               [2] 开通局域网共享(需验证)   │
echo    │                                                              │
echo    │[3] 关闭局域网共享               [4] 返回主菜单               │
echo    │                                                              │
echo    │[0] 退出                             17年10月28日             │
echo     ────────────────────────────────
Echo.
choice /C 12340 /M "请选择！！
if errorlevel 5 exit
if errorlevel 4 Goto :CMDTool
if errorlevel 3 Goto :ShareOff
if errorlevel 2 Goto :ShareOn2
if errorlevel 1 Goto :ShareOn

:ShareOn
cls
@ ECHO OFF
@ ECHO.
@ ECHO.                            说      明
@ ECHO --------------------------------------------------------------------
@ ECHO 本批处理执行后，将作以下一些设置：
@ ECHO 1、允许SAM帐户和共享的匿名枚举(原版系统允许，本系统默认是禁用)。
@ ECHO 2、本机帐户若空密码，允许其它机访问本机。
@ ECHO 3、Windows防火墙：允许文件和打印机共享。
@ ECHO 4、共享方式：本地用户以来宾身份验证。
@ ECHO 5、来宾帐户：启用。
@ ECHO --------------------------------------------------------------------
@ ECHO.
@ ECHO 采用这种共享方式，其它机访问本机都不用输用户名和密码。举例来说，家庭
@ ECHO 局域网，彼此都是可以信任的，请使用这种方式。
@ ECHO.
@ ECHO 无论采用哪一种共享方式，共享只是方便内部使用，在用路由器上网的场合，
@ ECHO 外网不能访问到您的机，无需担心共享了就会被入侵。您只需记住，单机拨号
@ ECHO 上网时，不要打开共享就可以了。
@ ECHO --------------------------------------------------------------------
@ ECHO.
echo 请详细阅读说明，任意键继续....
PAUSE>nul

::============================生成开通局域网共享.reg===============================

echo>>开通局域网共享.reg Windows Registry Editor Version 5.00

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo>>开通局域网共享.reg "restrictanonymous"=dword:00000000

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo>>开通局域网共享.reg "restrictanonymous"=dword:00000000
: 以上两行在系统中的位置是：本地安全策略-安全选项-网络访问：不允许SAM帐户和共享
: 的匿名枚举。系统默认值是：已停用。
: 解说：操作系统默认:利用ipc$通道可以建立空连接,匿名枚举出该机有多少帐户。显然
: 有一定的安全隐患。本系统已设为不允许空连接了。以此提高单机拨号上网的安全性。
: 负面影响是局域网不能互访了。要更改一下才可以解决。

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo>>开通局域网共享.reg "limitblankpassworduse"=dword:00000000

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo>>开通局域网共享.reg "limitblankpassworduse"=dword:00000000
: 以上两行在系统中的位置是：本地安全策略--安全选项--帐户：使用空白密码的本地帐户
: 只允许进行控制台登录。系统默认值是：已启用。
: 解说：很多人的帐户是不加密码的。这样，当局域网中别的电脑访问本机时，会弹出错误提示：
: 登录失败：用户帐户限制………。这是XP系统的一条安全策略造成的，防止别人趁你空密码时
: 进入你的电脑。如果你觉得无所谓，不必做这些限制，那就把它设为：已停用。

echo>>开通局域网共享.reg [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count]
echo>>开通局域网共享.reg "HRZR_EHAPCY"=hex:0C,00,00,00,26,00,00,00,F0,FB,E5,52,64,95,C6,01
echo>>开通局域网共享.reg "HRZR_EHAPCY:"P:\JVAQBJF\flfgrz32\sverjnyy.pcy",Jvaqbjf 防火墙"=hex:0C,00,00,00,08,00,00,00,F0,FB,E5,52,64,95,C6,01

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo>>开通局域网共享.reg "445:TCP"="445:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22005"
echo>>开通局域网共享.reg "137:UDP"="137:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22001"
echo>>开通局域网共享.reg "138:UDP"="138:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22002"
echo>>开通局域网共享.reg "139:TCP"="139:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22004"

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Epoch]
echo>>开通局域网共享.reg "Epoch"=dword:000001ED

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Print\Providers]
echo>>开通局域网共享.reg "LogonTime"=hex:E8,31,8E,4F,64,95,C6,01

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo>>开通局域网共享.reg "445:TCP"="445:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22005"
echo>>开通局域网共享.reg "137:UDP"="137:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22001"
echo>>开通局域网共享.reg "138:UDP"="138:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22002"
echo>>开通局域网共享.reg "139:TCP"="139:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22004"

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Epoch]
echo>>开通局域网共享.reg "Epoch"=dword:000001ED
: 以上数值对应系统中的位置：控制面板--防火墙--例外--文件和打印机共享。系统默认：不选。
: 解说：所有的策略都设置好了，局域网依然不能访问，提示：您没有权限使用网络资源，找
: 不到网络路径！呵呵，真是令人火冒三丈！其实XP还有一道关卡，就是防火墙，必须要经过
: 防火墙的允许才行。

echo>>开通局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo>>开通局域网共享.reg "forceguest"=dword:00000001
: 以上数值对应系统中的位置是：控制面板--管理工具--本地安全策略--本地策略--安全选项，
: 网络访问：本地帐户的共享和安全模式：仅来宾-本地用户以来宾份验证。这时，当局域网
: 其他机访问本机时，不会弹出对话框，就可以直接进入。在家庭网等完全可以信任的区域，
: 建议使用这种方式。

regedit /s 开通局域网共享.reg
net user Guest /active:yes
del 开通局域网共享.reg
cls
@ ECHO.
@ ECHO --------------------------------------------------------------------
@ ECHO 操作完成。按任意键返回菜单......
@ ECHO 注意：本机要重启后才会生效。
@ ECHO --------------------------------------------------------------------
@ ECHO.
@ ECHO 疑难问题补充：
@ ECHO   如果以前的共享方式是“本地用户以自己自己身份验证”时共享了文件夹，
@ ECHO 则现在改为以来宾身份验证后再访问该文件夹,会弹出错误：“无法访问，您
@ ECHO 没有权限使用网络资源.”解决办法是：在该文件夹属性上把原共享取消，然
@ ECHO 后重新共享，就行了。
@ ECHO --------------------------------------------------------------------

pause>nul && Goto :CMDTool16

:ShareOn2
cls
@ ECHO OFF
@ ECHO.
@ ECHO.                            说      明
@ ECHO --------------------------------------------------------------------
@ ECHO 本批处理执行后，将作以下一些设置：
@ ECHO 1、允许SAM帐户和共享的匿名枚举(原版系统允许，本系统默认是禁用)。
@ ECHO 2、本机帐户若空密码，允许其它机访问本机。
@ ECHO 3、Windows防火墙：允许文件和打印机共享。
@ ECHO 4、共享方式：本地用户以自己的身份验证。
@ ECHO 5、来宾帐户：不启用。
@ ECHO --------------------------------------------------------------------
@ ECHO.
@ ECHO 采用这种共享方式，访问本机时必须要输入正确的用户名和密码，才能访问。
@ ECHO.
@ ECHO 无论采用哪一种共享方式，共享只是方便内部使用，在用路由器上网的场合，
@ ECHO 外网不能访问到您的机，无需担心共享了就会被入侵。您只需记住，单机拨号
@ ECHO 上网时，不要打开共享就可以了。
@ ECHO --------------------------------------------------------------------
@ ECHO.
echo 请详细阅读说明，任意键继续....
PAUSE>nul

::============================生成开通局域网共享需验证.reg===============================

echo>>开通局域网共享需验证.reg Windows Registry Editor Version 5.00

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo>>开通局域网共享需验证.reg "restrictanonymous"=dword:00000000

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo>>开通局域网共享需验证.reg "restrictanonymous"=dword:00000000
: 以上两行在系统中的位置是：本地安全策略-安全选项-网络访问：不允许SAM帐户和共享
: 的匿名枚举。系统默认值是：已停用。
: 解说：操作系统默认:利用ipc$通道可以建立空连接,匿名枚举出该机有多少帐户。显然
: 有一定的安全隐患。本系统已设为不允许空连接了。以此提高单机拨号上网的安全性。
: 负面影响是局域网不能互访了。要更改一下才可以解决。

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo>>开通局域网共享需验证.reg "limitblankpassworduse"=dword:00000000

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo>>开通局域网共享需验证.reg "limitblankpassworduse"=dword:00000000
: 以上两行在系统中的位置是：本地安全策略--安全选项--帐户：使用空白密码的本地帐户
: 只允许进行控制台登录。系统默认值是：已启用。
: 解说：很多人的帐户是不加密码的。这样，当局域网中别的电脑访问本机时，会弹出错误提示：
: 登录失败：用户帐户限制………。这是XP系统的一条安全策略造成的，防止别人趁你空密码时
: 进入你的电脑。如果你觉得无所谓，不必做这些限制，那就把它设为：已停用。

echo>>开通局域网共享需验证.reg [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count]
echo>>开通局域网共享需验证.reg "HRZR_EHAPCY"=hex:0C,00,00,00,26,00,00,00,F0,FB,E5,52,64,95,C6,01
echo>>开通局域网共享需验证.reg "HRZR_EHAPCY:"P:\JVAQBJF\flfgrz32\sverjnyy.pcy",Jvaqbjf 防火墙"=hex:0C,00,00,00,08,00,00,00,F0,FB,E5,52,64,95,C6,01

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo>>开通局域网共享需验证.reg "445:TCP"="445:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22005"
echo>>开通局域网共享需验证.reg "137:UDP"="137:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22001"
echo>>开通局域网共享需验证.reg "138:UDP"="138:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22002"
echo>>开通局域网共享需验证.reg "139:TCP"="139:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22004"

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Epoch]
echo>>开通局域网共享需验证.reg "Epoch"=dword:000001ED

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Print\Providers]
echo>>开通局域网共享需验证.reg "LogonTime"=hex:E8,31,8E,4F,64,95,C6,01

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo>>开通局域网共享需验证.reg "445:TCP"="445:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22005"
echo>>开通局域网共享需验证.reg "137:UDP"="137:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22001"
echo>>开通局域网共享需验证.reg "138:UDP"="138:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22002"
echo>>开通局域网共享需验证.reg "139:TCP"="139:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22004"

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Epoch]
echo>>开通局域网共享需验证.reg "Epoch"=dword:000001ED
: 以上数值对应系统中的位置：控制面板--防火墙--例外--文件和打印机共享。系统默认：不选。
: 解说：所有的策略都设置好了，局域网依然不能访问，提示：您没有权限使用网络资源，找
: 不到网络路径！呵呵，真是令人火冒三丈！其实XP还有一道关卡，就是防火墙，必须要经过
: 防火墙的允许才行。

echo>>开通局域网共享需验证.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo>>开通局域网共享需验证.reg "forceguest"=dword:00000000
: 以上数值对应系统中的位置是：控制面板--管理工具--本地安全策略--本地策略--安全选项，
: 网络访问：本地帐户的共享和安全模式：经典-本地用户以自己的身份验证。这时，当局域网
: 其他机访问本机时，会弹出对话框，需要填写本机正确的用户名和密码才允许访问。这种方式
: 是安全的。建议使用。

regedit /s 开通局域网共享需验证.reg
net user Guest /active:no
del 开通局域网共享需验证.reg
cls
@ ECHO.
@ ECHO -------------------------------------------------------------------
@ ECHO 操作完成。按任意键返回菜单.....
@ ECHO 无需重启，其它机现在就可以访问本机了。
@ ECHO.
@ ECHO -------------------------------------------------------------------
@ ECHO.
@ ECHO 常见疑问：
@ ECHO    经上述处理后，访问本机，如果仍然是直接就进去了，没出现提示输入帐
@ ECHO 号和密码的对话框，那是因为其他电脑的帐户名称跟本机帐户名一样(比如双
@ ECHO 方都是administrator)，且本机无密码。您应该把本机帐户改名，或加密码。
@ ECHO 这样，未经授权的用户就不能随意访问您共享的资源了。
@ ECHO -------------------------------------------------------------------
pause>nul && Goto :CMDTool16

:ShareOff
cls
@ ECHO OFF
@ ECHO.
@ ECHO.                      说     明
@ ECHO ----------------------------------------------------------
@ ECHO 本批处理执行后，将作以下一些设置：
@ ECHO 1、不允许SAM帐户和共享的匿名枚举(原版系统默认是允许的)。
@ ECHO 2、本机帐户若空密码，不允许其它机访问本机。
@ ECHO 3、Windows防火墙：不允许文件和打印机共享。
@ ECHO 4、来宾帐户：禁用。
@ ECHO.
@ ECHO 如果您不需要常在局域网内互传文件，可以关闭共享功能以提高
@ ECHO 安全性。尤其是单机拨号上网的用户，更应关闭共享。
@ ECHO ----------------------------------------------------------
@echo.
echo 请详细阅读说明，任意键继续....
PAUSE>nul

::============================生成关闭局域网共享.reg===============================

echo>>关闭局域网共享.reg Windows Registry Editor Version 5.00

echo>>关闭局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo>>关闭局域网共享.reg "restrictanonymous"=dword:00000001

echo>>关闭局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo>>关闭局域网共享.reg "restrictanonymous"=dword:00000001
:以上两行在系统中的位置是：本地安全策略-安全选项-网络访问：不允许SAM帐户和共享
:的匿名枚举。系统默认值是：已停用。
:解说：操作系统默认:利用ipc$通道可以建立空连接,匿名枚举出该机有多少帐户。显然
:有一定的安全隐患。本系统已设为不允许空连接了。以此提高单机拨号上网的安全性。
:负面影响是局域网不能互访了。要更改一下才可以解决。

echo>>关闭局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo>>关闭局域网共享.reg "limitblankpassworduse"=dword:00000001

echo>>关闭局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo>>关闭局域网共享.reg "limitblankpassworduse"=dword:00000001
:以上两行在系统中的位置是：本地安全策略--安全选项--帐户：使用空白密码的本地帐户
:只允许进行控制台登录。系统默认值是：已启用。
:解说：很多人的帐户是不加密码的。这样，当局域网中别的电脑访问本机时，会弹出错误提示：
:登录失败：用户帐户限制………。这是XP系统的一条安全策略造成的，防止别人趁你空密码时
:进入你的电脑。如果你觉得无所谓，不必做这些限制，那就把它设为：已停用。

echo>>关闭局域网共享.reg [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count]
echo>>关闭局域网共享.reg "HRZR_EHAPCY"=hex:0C,00,00,00,2A,00,00,00,90,AF,A4,87,A4,95,C6,01
echo>>关闭局域网共享.reg "HRZR_EHAPCY:"P:\JVAQBJF\flfgrz32\sverjnyy.pcy",Jvaqbjf 防火墙"=hex:0C,00,00,00,13,00,00,00,90,AF,A4,87,A4,95,C6,01

echo>>关闭局域网共享.reg [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Cryptography\RNG]
echo>>关闭局域网共享.reg "Seed"=hex:AC,6F,9A,2B,11,64,44,68,EC,90,1B,76,72,A7,0A,14,\
echo>>关闭局域网共享.reg 4C,79,37,BB,FD,BD,70,B2,B2,58,D5,B5,89,5C,B6,4E,\
echo>>关闭局域网共享.reg 3B,18,A5,26,46,BC,3E,6A,30,A4,7D,A0,56,E6,6A,B5,\
echo>>关闭局域网共享.reg 57,3A,BF,A1,CD,CA,B6,64,4C,F9,0E,D2,64,ED,86,1F,\
echo>>关闭局域网共享.reg 61,F6,D1,01,0B,7C,8D,BD,73,10,C8,4E,57,93,4E,90

echo>>关闭局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo>>关闭局域网共享.reg "445:TCP"="445:TCP:LocalSubNet:Disabled:@xpsp2res.dll,-22005"
echo>>关闭局域网共享.reg "137:UDP"="137:UDP:LocalSubNet:Disabled:@xpsp2res.dll,-22001"
echo>>关闭局域网共享.reg "138:UDP"="138:UDP:LocalSubNet:Disabled:@xpsp2res.dll,-22002"
echo>>关闭局域网共享.reg "139:TCP"="139:TCP:LocalSubNet:Disabled:@xpsp2res.dll,-22004"

echo>>关闭局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Epoch]
echo>>关闭局域网共享.reg "Epoch"=dword:000001FC

echo>>关闭局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo>>关闭局域网共享.reg "445:TCP"="445:TCP:LocalSubNet:Disabled:@xpsp2res.dll,-22005"
echo>>关闭局域网共享.reg "137:UDP"="137:UDP:LocalSubNet:Disabled:@xpsp2res.dll,-22001"
echo>>关闭局域网共享.reg "138:UDP"="138:UDP:LocalSubNet:Disabled:@xpsp2res.dll,-22002"
echo>>关闭局域网共享.reg "139:TCP"="139:TCP:LocalSubNet:Disabled:@xpsp2res.dll,-22004"

echo>>关闭局域网共享.reg [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Epoch]
echo>>关闭局域网共享.reg "Epoch"=dword:000001FC
:以上数值对应系统中的位置：控制面板--防火墙--例外--文件和打印机共享。系统默认：不选。
:解说：所有的策略都设置好了，局域网依然不能访问，提示：您没有权限使用网络资源，找
:不到网络路径！呵呵，真是令人火冒三丈！其实XP还有一道关卡，就是防火墙，必须要经过
:防火墙的允许才行。

regedit /s 关闭局域网共享.reg
net user Guest /active:no
del 关闭局域网共享.reg
cls
@ ECHO.
@ ECHO ----------------------------------------------------------
@ ECHO 操作完成。按任意键返回菜单......
@ ECHO 不必重启，设置已生效。
@ ECHO ----------------------------------------------------------
pause>nul && Goto :CMDTool16

::================================本机开放的端口及使用该端口的进程======================

:CMDTool17
cls
echo ╔-                              -╗ 
echo   本机开放的端口及使用该端口的进程 
echo ╚-                              -╝ 
echo ------------------------------------    
ECHO TCP协议: 本机地址             外部地址              进程名称
::利用netstat命令找出使用TCP协议通信的端口，并将结果分割； 
::将第二个参数(IP加端口)传给%%i，第五个参数(PID号)传给%%j; 
for /F "usebackq skip=4 tokens=2,3,5" %%i in (`"netstat -ano -p TCP"`) do ( 
  call :Assoc %%i TCP %%k %%j
  echo          !TCP_Port:~,17!    !TCP_OutPort:~,17!    !TCP_Proc_Name:~,20!  
) 

ECHO UDP协议: 本机地址                     进程名称
for /F "usebackq skip=4 tokens=2,4" %%i in (`"netstat -ano -p UDP"`) do (  
  call :Assoc %%i UDP %%j 
  echo          !UDP_Port:~,17!            !UDP_Proc_Name:~,20! 
) 
echo 按任意键返回主菜单
pause>nul & Goto :CMDTool

:Assoc 
set "kong=          "
::对%1(第一个参数）进行分割，将第二个参数传给%%e。在本程序中，%1即为上面的%%i(形式为：IP:端口号) 
for /F "delims=" %%e in ("%1") do ( 
    set  %2_Port=%%e%kong%
  ) 

for /F "delims=" %%f in ("%4") do ( 
    set  %2_OutPort=%%f%kong%
  ) 

:: 查询PID等于%3(第三个参数)的进程，并将结果传给变量?_Proc_Name,?代表UDP或者TCP； 
for /F "skip=1 usebackq delims=, tokens=1" %%a in (`"Tasklist /FI "PID eq %3" /FO CSV"`) do ( 
   ::%%~a表示去掉%%a外面的引号，因为上述命令的结果是用括号括起来的。  
   set %2_Proc_Name=%%~a%kong%
  ) 
goto :eof

::============================================禁启用 任务管理器===============================

:CMDTool18
cls
echo 禁启用任务管理器
echo.
set /p YN=ON-开启/OFF-关闭/Q-主菜单:
if /i "%yn%"=="q" Goto :CMDTool
if /i "%yn%"=="on" (set dword=0 & Echo 任务管理器已启用) else (if /i "%yn%"=="off" (set dword=1 & Echo 任务管理器已禁用) else (cls & echo 输入错误，任意键返回主菜单 & pause>nul & Goto :CMDTool))
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\system" /v disabletaskmgr /t REG_DWORD /d %dword% /f
pause>nul & Goto :CMDTool
复制代码

wom087

W
::echo @ECHO OFF >>aaa.bat
::echo title 倒计时 >>aaa.bat
::echo SETLOCAL ENABLEDELAYEDEXPANSION >>aaa.bat
::echo mode con: cols=40 lines=3 >>aaa.bat
::echo for /F "usebackq delims=, tokens=2" %%%%a in (`"Tasklist /v /fo csv | findstr /i "倒计时""`) do (  >>aaa.bat
::echo set /a PID=%%%%~a  >>aaa.bat
::echo ) >>aaa.bat
::echo SET /a s=%%a%% >>aaa.bat
::echo :AAA >>aaa.bat
::echo FOR /l %%%%i in (1,1,%%s%%) do ( >>aaa.bat
::echo SET /a s-=1 >>aaa.bat
::echo choice /T 1 /C QY /D Y /N ^>nul >>aaa.bat
::echo if %%s%%==120 msg %%username%% /time:5 "系统即将在120秒后关闭，请注意保存资料" ^& goto :AAA >>aaa.bat
::echo if errorlevel 2 cls ^& echo 倒计时开始 %%s%% 按Q关闭自动关机并退出 ^& goto :AAA >>aaa.bat
::echo if errorlevel 1 del aaa.bat ^& shutdown -a ^& taskkill /F /PID %%PID%% /T >>aaa.bat
::echo ) >>aaa.bat
::echo mshta vbscript:msgbox("系统即将关闭",64,"自动关机提醒")(window.close) >>aaa.bat
::echo del aaa.bat >>aaa.bat
::echo :eof >>aaa.bat
::start aaa.bat %a%

这段本来想做成倒计时的，但一会就和主机时间不准了，也就注释掉了，高手们有没有办法可以做到准确的倒计时

0000

帮忙优化了一下

@Echo Off
Setlocal enabledelayedexpansion
title  CMD 工 具 箱
cls
set user=
set pwd=
set times=4

:check
cls
echo;
echo This is a secure system. Authorized Access Only!!!
echo;
echo User Access Verification
echo;
set /p user= UserName: 
set /p pwd= Password: 
if "!user!"=="admin" if "!pwd!"=="admin" goto CMDTool

if %times% == 0 goto :Close
set /a times-=1,checkup=times+1
echo;
echo 帐号密码错误,还有%checkup%机会^^!
pause>nul
goto check

:Close
ECHO;
echo Logon Failed^^!
pause>nul & exit


:CMDTool
title  CMD 工 具 箱
color 2f
REM mode con: cols=80 lines=27
cls
echo                        ────────────────  
echo     ─────────┤        　CMD 工 具 箱　      ├─────────
echo    │                  ────────────────                   │
echo    │  [1] WIFI共享网络工具                    [2] 自动关机               │
echo    │                                                                     │
echo    │  [3] 停止自动关机                        [4] Ping网段所有IP         │
echo    │                                                                     │
echo    │  [5] 请算1到n的总和                      [6] 清理系统垃圾           │
echo    │                                                                     │
echo    │  [7] JAVA小工具                          [8] 重新启动打印服务       │
echo    │                                                                     │
echo    │  [9] 生成一键以管理员运行                [A] IP释放并更新           │
echo    │                                                                     │
echo    │  [B] BAT加密工具                         [C] IP显示主机名和MAC      │
echo    │                                                                     │
echo    │  [D] 显示系统信息                        [E] 跟踪指定IP或域名路由   │
echo    │                                                                     │
echo    │  [F] 添加右键获取管理员所有权            [G] 局域网共享工具         │
echo    │                                                                     │
echo    │  [H] 显示使用TCP^&UDP端口的进程           [I] 禁启用任务管理器       │
echo    │                                                                     │
echo    │  [0] 退出                                17年11月17日               │
echo     ───────────────────────────────────
echo;
choice /C 123456789abcdefghi0 /d 0 /t 30  /M "请选择！！30秒自动退出
if errorlevel 19 exit
for /l %%N in (18,-1,1) do if errorlevel %%N Goto :CMDTool%%N

Rem =========================WIFI 共 享 网 络 工 具================================

:CMDTool1
color 5f
title  WIFI 共 享 网 络 工 具 
cls
echo                     ───────────────  
echo     ───────┤    WIFI 共 享 网 络 工 具   ├────────
echo    │               ───────────────                 │
echo    │                                                              │
echo    │[1] 开始配置共享网络（如SSID和WIFI密码） [2] 启用无线共享     │
echo    │                                                              │
echo    │[3] 停止无线共享                         [4] 删除共享网络配置 │
echo    │                                                              │
echo    │[5] 显示连接的客户端                     [6]返回主菜单        │
echo    │                                                              │
echo    │[0] 退出                                 17年10月28日         │
echo     ────────────────────────────────
choice /C 1234560 /M "请选择！！
if errorlevel 7 exit
if errorlevel 6 Goto :CMDTool
if errorlevel 5 Goto :wifiset4
if errorlevel 4 Goto :wifiset3
if errorlevel 3 Goto :wifiset2
if errorlevel 2 Goto :wifiset1
if errorlevel 1 goto :wifiset

Rem ====================开始配置共享网络（如SSID和WIFI密码）=======================

:wifiset
cls
set ssid=
set pass=
choice /C YN /M "是否设置共享网络，按Y设置，按N返回菜单
if errorlevel 2 Goto :CMDTool1
if errorlevel 1 echo Please wait....
netsh wlan stop hostednetwork
netsh wlan set hostednetwork mode=disallow
cls
Echo		本程序是Windows7以上系统共享WIFI设置的工具。
Echo		注：计算机必须要两个以上可用的网卡，且要一个是无线网卡。
Echo;
Set /p ssid=请输入SSID名字，默认为360WIFI-AC:
Set /p pass=请输入WIFI密码，默认为1234567890:
if "!ssid!"=="" set ssid=360WIFI-AC
if "!pass!"=="" set pass=1234567890
netsh wlan set hostednetwork mode=allow ssid=!ssid! key=!pass!
netsh wlan start hostednetwork
netsh interface set interface name="本地连接 2" newname="虚拟WIFI"
echo;
Echo	设置Internet连接共享
Echo	右键,宽带连接（不用宽带连接的就用本地连接）,选择“属性”
Echo	“共享”，勾上“允许其他······连接(N)”并选择“虚拟WiFi”。
Echo	===================================================================
Echo	WIFI共享配置成功，WIFI名字为!ssid!,密码为!pass!,请牢记！任意键返回……
pause>nul && goto :CMDTool1

Rem ================================启用无线共享================================

:wifiset1
cls
netsh wlan start hostednetwork
echo;
Echo		网络共享已启动，任意键返回……
pause>nul && goto :CMDTool1

Rem ===================================停止无线共享===============================

:wifiset2
cls
netsh wlan stop hostednetwork
echo;
Echo		网络共享已停用，任意键返回……
pause>nul && goto :CMDTool1

Rem ====================================删除共享网络配置================================

:wifiset3
cls
netsh wlan stop hostednetwork
netsh wlan set hostednetwork mode=disallow
echo;
Echo		网络共享已删除，任意键返回……
pause>nul && goto :CMDTool1

Rem =====================================显示连接的客户端================================

:wifiset4
cls
netsh wlan show hostednetwork
Echo	=================任意键返回=================
pause>nul && goto :CMDTool1


Rem =====================================这是自动关机程序================================

:CMDTool2
shutdown -a 2>nul
set settime=
set sum=
set time_begin=%time:~0,-6%
for /f "tokens=1,2 delims=:" %%i in ("%time_begin%") do (
    set /a hour_b=%%i,munite_b=%%j
)

for /f "tokens=1,2,3 delims=-" %%i in ("%date%") do (
    set /a yea_b=%%i,mon_b=%%j,dat_b=%%k
)
cls
echo 当前时间是%yea_b%年%mon_b%月%dat_b%日%time_begin%[Q=主菜单]
echo;
set /p settime=请输入分钟[n]或具体时间[如12:30]:
if /i "!settime!"=="Q" Goto :CMDTool
if "!settime!"=="" Goto :CMDTool2

echo !settime!|findstr ":">nul && Goto :shutdown2 || Goto :shutdown1


:shutdown1
if !settime! lss 1 goto :CMDTool2
if !settime! gtr 1440 goto :CMDTool2
set /a sum=settime,hour_=settime/60,munite_=settime%%60
Goto :Showtime

:shutdown2
set time_end=%settime%
for /f "tokens=1,2 delims=:" %%i in ("%time_end%") do (
    set /a hour_e=%%i
    set /a munite_e=%%j
)
if not defined hour_e Goto :CMDTool2
if not defined munite_e Goto :CMDTool2
if %hour_e% lss 0 Goto :CMDTool2
if %hour_e% gtr 23 Goto :CMDTool2
if %munite_e% lss 0 Goto :CMDTool2
if %munite_e% gtr 59 Goto :CMDTool2
echo %hour_e% : %munite_e%
call :time_lapse
set /a sum=hour_*60+munite_

:Showtime
set /a a=sum*60
cls
echo 剩余 %hour_% 小时 %munite_% 分，合计 %sum% 分钟。
echo;
choice /C YNC /M "计算机将在%sum%分钟后自动关闭,是请按 Y ，按 N 重输，按C返回主菜单
if errorlevel 3 Goto :CMDTool
if errorlevel 2 Goto :CMDTool2
if errorlevel 1 Goto :DW

:DW
(
 echo @ECHO off
 echo IF "%%1"=="WaitKey" GOTO WaitKey

 echo TITLE 倒计时
 echo MODE con: cols=40 lines=3
 echo CD.^>$ ^& START /b "" "%%~f0" WaitKey

 echo SET s=%%1
 echo FOR /l %%%%i in (%%s%%,-1,0^) do (
 echo  TIMEOUT 1 /nobreak ^>nul
 echo  IF %%%%i == 120 START MSG %%username%% /time:5 "系统即将在120秒后关闭，请注意保存资料"
 echo  IF EXIST $ (
 echo   CLS ^& ECHO 倒计时开始 %%%%i 按Q关闭自动关机并退出
 echo  ^) ELSE (
 echo   DEL "%%~f0" ^& SHUTDOWN -a 2^>nul ^& EXIT
 echo  ^)
 echo ^)
 echo DEL $
 echo MSHTA vbscript:msgbox("系统即将关闭",64,"自动关机提醒"^)(window.close^)
 echo DEL "%%~f0" ^& EXIT

 echo :WaitKey
 echo CHOICE /c 1Q /d 1 /t 1 ^>nul
 echo IF NOT EXIST $ EXIT
 echo IF ERRORLEVEL 2 DEL $ ^& EXIT
 echo GOTO WaitKey
)>aaa.bat
start aaa.bat %a%
shutdown -a 2>nul & cls & shutdown -s -f -t %a%
echo 自动关机设置完成，请查看屏幕右下角信息，任意键返回主菜单
pause>nul & Goto :CMDTool

:time_lapse
if %munite_e% lss %munite_b% (
    set /a hour_e=hour_e-1
    set /a munite_e=munite_e+60
)
set /a munite_=munite_e-munite_b

if %hour_e% lss %hour_b% (
    set /a hour_e=hour_e+24
)
set /a hour_=hour_e-hour_b
Goto :eof

Rem =====================================这是取消自动关机程序================================

:CMDTool3
cls
ECHO;
choice /C YN /M "是否取消自动关机,是请按 Y ，否按 N 返回主菜单
if errorlevel 2 Goto :CMDTool
if errorlevel 1 shutdown -a
cls
Echo 自动关机已取消，任意键返回……
pause>nul & goto :CMDTool

Rem =====================================Ping网段所有IP================================

:CMDTool4
if exist "D:\pingall.log" del D:\pingall.log
cls
Set Ping=
set /a a=-1,b=-1,c=-1

Set /p Ping=请输入要Ping的网段[Q=主菜单]：
if /i "!Ping!"=="Q" Goto :CMDTool
if not defined Ping Goto :CMDTool4

for /f "tokens=1,2,3 delims=." %%i in ("!Ping!") do set /a "a=%%i,b=%%j,c=%%k"
if not defined c Goto :CMDTool4
if !a! lss 1 Goto :CMDTool4
if !b! lss 0 Goto :CMDTool4
if !c! lss 0 Goto :CMDTool4
if !a! gtr 255 Goto :CMDTool4
if !b! gtr 255 Goto :CMDTool4
if !c! gtr 255 Goto :CMDTool4

:SetRange
set Range=
set /a d=0,e=0
cls
Set /p Range=请输入%a%.%b%.%c%的范围[1-255]：
for /f "tokens=1,2 delims=-" %%l in ("!Range!") do set /a "d=%%l,e=%%m"
if not defined e Goto :SetRange
if !d! gtr !e! Goto :SetRange
if !d! lss 1 Goto :SetRange
if !e! lss 1 Goto :SetRange
if !d! gtr 255 Goto :SetRange
if !e! gtr 255 Goto :SetRange

set /a sum=e-d
if %sum% lss 15 (Goto :SinglePing) else Goto:MultiPing

Echo Please wait....

:SinglePing
for /l %%i in (%d%,1,%e%) do (
 echo 正在Ping%a%.%b%.%c%.%%i中，请稍候..
 ping -n 1 -l 1 -w 6 %a%.%b%.%c%.%%i | find "来自" >>D:\pingall.log
)
cls & Goto :ShowPing

:MultiPing
echo wscript.sleep 10 >sleep.vbs
(
 @echo ping %%1 -n 1 -l 1 -a
 @echo if ^%%errorlevel^%%==0 echo ^%%1 OK^>^>D:\pingall.log
)>checkip.bat
for /l %%i in (%d%,1,%e%) do (
 cscript /nologo sleep.vbs
 start /b cmd /c checkip.bat %a%.%b%.%c%.%%i >nul 2>nul
 echo 正在Ping%a%.%b%.%c%.%%i中，请稍候..
)
timeout 10 /nobreak

:ShowPing
if exist "sleep.vbs" del sleep.vbs
if exist "checkip.bat" del checkip.bat
if not exist "D:\pingall.log" echo %a%.%b%.%c%.!Range!的范围错误或没在使用！请重新输入 & pause>nul & Goto :CMDTool4
set n=0
for /f "delims=" %%a in ('type "D:\pingall.log"') do set /a n+=1
if "%n%"=="0" echo %a%.%b%.%c%.!Range!的范围错误或没在使用！请重新输入 & pause>nul & Goto :CMDTool4
type D:\pingall.log
ECHO;
echo %a%.%b%.%c%.!Range!的范围共%n%个IP在使用中
ECHO;
choice /C YN /M "是否保存并查看记录文件，查看请按 Y ，删除请按 N
if errorlevel 2 del d:\pingall.log & Goto :CMDTool
if errorlevel 1 start /wait notepad.exe d:\pingall.log & Goto :CMDTool

Rem =====================================请算1到n的总和================================

:CMDTool5
cls
set n=
set /p n=输入你想计算的数字n[Q=主菜单]：
if /i "!n!"=="Q" Goto :CMDTool
if "!n!"=="" Goto :CMDTool5
if !n! lss 1 Goto :CMDTool5
if !n! gtr 10000 Goto :CMDTool5
for /l %%i in (1 1 !n!) do set /a sum+=%%i
echo 1+2+....+n=%sum%
pause>nul & goto :CMDTool

Rem =====================================清理系统垃圾================================

:CMDTool6
color 5a
cls
echo 正在清除系统垃圾文件，请稍等......
del /f /s /q  %systemdrive%\*.tmp
del /f /s /q  %systemdrive%\*._mp
del /f /s /q  %systemdrive%\*.log
del /f /s /q  %systemdrive%\*.gid
del /f /s /q  %systemdrive%\*.chk
del /f /s /q  %systemdrive%\*.old
del /f /s /q  %systemdrive%\recycled\*.*
del /f /s /q  %windir%\*.bak
del /f /s /q  %windir%\prefetch\*.*
rd /s /q %windir%\temp & md  %windir%\temp
del /f /q  %userprofile%\cookies\*.*
del /f /q  %userprofile%\recent\*.*
del /f /s /q  "%userprofile%\Local Settings\Temporary Internet Files\*.*"
del /f /s /q  "%userprofile%\Local Settings\Temp\*.*"
del /f /s /q  "%userprofile%\recent\*.*"
echo 清除系统LJ完成！任意键返回
pause>nul & goto :CMDTool

Rem =====================================这是JAVA小工具程序================================

:CMDTool7
cls  
title JAVA 小 工 具 
color 3f   
cls
set /p Dr=设置JAVA原码目录[Q=主菜单]：
if /i "!Dr!"=="Q" Goto :CMDTool
if not defined Dr Goto :CMDTool7
if not exist !Dr! (Goto :CMDTool7)
cd /d !Dr!
:java
set class=
set name=
set name2=
set name3=
cls
echo                     ───────────────  
echo     ───────┤     Java Applet 小 工 具     ├────────
echo    │               ───────────────                 │
echo    │                                                              │
echo    │[1] 新建JAVA程序                 [2] 编译JAVA程序             │
echo    │                                                              │
echo    │[3] 生成Html文件                 [4] 运行Java程序             │
echo    │                                                              │
echo    │[5] 返回主菜单                   [M] 浏览目录文件             │
echo    │                                                              │
echo    │[0] 退出                             17年10月30日             │
echo     ────────────────────────────────
echo     当前JAVA原码目录为!Dr!，按M可浏览目录文件
ECHO;
choice /C 12345M0 /M "请选择！！
if errorlevel 7 exit
if errorlevel 6 start !Dr! && goto :java
if errorlevel 5 Goto :CMDTool
if errorlevel 4 Goto :java3
if errorlevel 3 Goto :java2
if errorlevel 2 Goto :java1
if errorlevel 1 goto :CreateClass

:CreateClass
cls
Echo		[1]新建JAVA程序
set class=
set identify=0
set /p class=请输入类名：
If exist "!class!".java (
 cls
 echo 注意:文件!class!.java已存在，请从输入！！！
 pause>nul & Goto :CreateClass
)

if "!class!"=="" (
 cls
 echo 注意: 类名不能为空！！！
 echo 提示：类名必须符合Java命名标准（如：类名第一个字符不能为数字）
 pause>nul & goto CreateClass
)

for /l %%i in (0,1,9) do if "!class:~0,1!"=="%%i" set identify=1
if "%identify%"=="0" (
 Goto Begin
) else (
 cls
 echo 注意: 类名不符合Java命名标准,请从输入！！！
 echo 提示：类名必须符合Java命名标准（如：类名第一个字符不能为数字）
 pause>nul & Goto :CreateClass
)

:Begin
(
 echo public class !class!{
 echo	   public static void main(String[] args) {
 echo                          /*请输入编程内容*/
 echo;&echo;&echo;&echo;
 echo	   }
 echo }
)>!Dr!\!class!.java

:Modify
start /wait notepad.exe !Dr!\!class!.java

:Build
set build=0
choice /C YN /M "是否需要编译!class!.java,请按 Y 编绎，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java1

:java1
cls
Echo		[2]编译JAVA程序
set name=!class!
set /p name=	请输入文件名默认为!class![C=菜单]:
if /i "!name!"=="C" Goto :java
If not exist !name!.java Goto :java1
javac !name!.java
If exist !name!.class Goto :if1
Echo	编译错误，请查看错误代码！
choice /C YN /M "请按 Y 返回重输，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java1

:if1
Echo	!name!.class编译成功,请牢记！
choice /C YN /M "请按 Y 生成Html，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java2

:java2
cls
Echo		[3] 生成Html文件
set name2=!name!
set /p name2=	请输入文件名默认为!name![C=菜单]:
if "!name2!"=="" Goto :java2
if /i "!name2!"=="C" Goto :java
if exist "!name2!".class Goto :if2
choice /C YN /M "找不到!name2!.class，按 Y 重输，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java2

:if2
(
 Echo ^<html^>
 Echo ^<body^>
 Echo ^<applet code = "!name2!.class" height = 500 width = 800^>
 Echo ^</applet^>
 Echo ^</body^>
 Echo ^</html^>
)>!name2!.html
cls
Echo	!name2!.html已生成,请牢记！
choice /C YN /M "请按 Y 调试程序，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java3

:java3
cls
Echo		[4] 运行Java程序
set name3=!name2!
set /p name3=	请输入文件名默认为!name2![C=菜单]:
if /i "!name3!"=="C" Goto :java
if "!name3!"=="" Goto :java3
if exist "!name3!".html Goto :if3
choice /C YN /M "找不到!name3!.html，按 Y 重输，或按 N 返回菜单
if errorlevel 2 Goto :java
if errorlevel 1 Goto :java3

:if3
appletviewer !name3!.html
cls
Echo		Java程序已停止，任意键返回……
pause>nul & Goto :java

::=============================重启打印服务=========================================

:CMDTool8
cls
choice /C YN /M "是否需要重启打印服务，按 Y 重启，或按 N 取消并返回主菜单
if errorlevel 2 Goto :CMDTool
if errorlevel 1 echo Please wait....
sc stop spooler
timeout 2 /nobreak >nul
choice /C YN /M "是否需要清理打印任务，按 Y 清理，或按 N 不清理
if errorlevel 2 sc start spooler
if errorlevel 1 del %windir%\system32\spool\printers\*.* /Q
sc start spooler
cls
echo 打印服务已重新启动.任意键返回主菜单
pause>nul && Goto :CMDTool

::===========================生成一键以管理员启动程序BAT================================

:CMDTool9
cls
Echo 任意地方输入字母Q可返回主菜单
set /p Name=请输入用户名[域Domain\User]:
if /i "!Name!"=="Q" Goto CMDTool
set /p Pass=请输入密码[注：特殊符号可能有问题]:
if /i "!Pass!"=="Q" Goto CMDTool
:Program
cls
set /p Program=请输入程序或直接把程序拖至本窗口释放:
if /i "!Program!"=="Q" Goto CMDTool
if not exist !Program! Goto Program
choice /C YN /M "是否以管理员："!Name!"生成一键以管理员启动程序BAT，按 Y 生成，或按 N 返回主菜单
if errorlevel 2 Goto :CMDTool
if errorlevel 1 echo Please wait....

(
 Echo ^@if (@CodeSection == @Batch^) @then
 Echo ^@echo off
 Echo start "" runas /user:!Name! !Program!
 ECHO start /B cmd.EXE
 ECHO cscript //nologo 1KeyRunAsAdmin.VBS
)>1KeyRunAsAdmin.bat 

(
 ECHO set sh=WScript.CreateObject("WScript.Shell"^)
 ECHO WScript.Sleep 2000
 ECHO sh.SendKeys "!Pass!"
 ECHO sh.SendKeys "{enter}"
)>1KeyRunAsAdmin.VBS 

Echo 已生成1KeyRunAsAdmin.bat,请检查第一个SendKeys后的密码是否正确，修改后请保存。

start /wait notepad.exe 1KeyRunAsAdmin.VBS

set build=0
choice /C YN /M "是否立即运行程序，按 Y 运行，或按 N 返回主菜单
if errorlevel 2 Goto CMDTool
if errorlevel 1 start 1KeyRunAsAdmin.bat
Goto CMDTool

::===============================IP释放并更新==============================================

:CMDTool10
cls
choice /C YN /M "是否立即释放并更新IP，期间网络将会短暂断开，按 Y 运行，或按 N 返回主菜单
if errorlevel 2 Goto CMDTool
if errorlevel 1 echo 正在更新IP信息.....
ipconfig /release
ipconfig /renew
cls
Echo IP已释放并更新，任意键返回主菜单
pause>nul & Goto :CMDTool

::====================================BAT 加 密 工 具===============================================

:CMDTool11
cls
title BAT 加 密 工 具 
color 1f  
:start  
cls
echo                        ────────────────  
echo     ─────────┤     　 BAT 加 密 工 具 　    ├──────────
echo    │                  ────────────────                    │
echo    │                                                                      │
echo    │            1、本工具用来对明文批处理文件进行加密!                    │
echo    │                                                                      │
echo    │            2、直接把待加密批处理文件拖至本窗口释放即可!              │
echo    │                                                                      │
echo    │            3、加密后会在当前目录下生成NewCode.bat文件!               │
echo    │                                                                      │
echo    │                                        17年09月18日                  │
echo     ────────────────────────────────────  
ECHO;
set /p file=请输入需要加密的批处理文件名后按回车键[Q=主菜单]: 
if "!file!"=="Q" goto :CMDTool
echo !file!|findstr /i "\.bat">nul && goto :go
echo !file!|findstr /i "\.c*">nul && goto :go
cls
echo ==============
echo 请正确输入!
echo ==============
ECHO;
ECHO;
echo 按任意键重新输入......
pause>nul & goto :start
:go
if not exist "!file!" goto :newly
if exist encrypt.bat copy encrypt.bat encryptbak.bat
echo %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a %%%%a >"%tmp%\encrypt.tmp"
echo cls>>"!tmp!\encrypt.tmp"
type "!file!">>"!tmp!\encrypt.tmp"
setlocal enabledelayedexpansion
for %%i in ("!tmp!\encrypt.tmp") do (
    echo %%~zi >nul 2>nul
    set size=%%~zi
    set num=!size:~-1!
    set /a mod=num%%2
    if !mod! equ 0 (goto even) else goto odd
)
:even
copy "!tmp!\encrypt.tmp" NewCode.bat
del "!tmp!\encrypt.tmp"
cls
echo ==========================================
echo 恭喜你, 批处理加密成功,已保存为NewCode.bat
echo ==========================================
ECHO;
ECHO;
echo 按任意键返回主菜单......
pause>nul & goto :CMDTool
:odd
ECHO; >>"!tmp!\encrypt.tmp"
copy "!tmp!\encrypt.tmp" NewCode.bat
del "!tmp!\encrypt.tmp"
cls
echo ==========================================
echo 恭喜你, 批处理加密成功,已保存为NewCode.bat
echo ==========================================
ECHO;
ECHO;
echo 按任意键返回主菜单......
pause>nul & goto :CMDTool
:newly
cls
echo ================================
echo 找不到批处理文件, 请重新输入!
echo ================================
ECHO;
ECHO;
echo 按任意键开始......
pause>nul & goto :start
:quit
exit

::===============================IP显示主机名和MAC=======================

:CMDTool12
cls
set IpAdd=
set /p IpAdd=请输入要查询的IP地址[Q=主菜单]:
if /i "!IpAdd!"=="Q" Goto :CMDTool
echo !IpAdd!|findstr "^[0-9]*\.[0-9]*\.[0-9]*\.[0-9]*$">nul|| (echo 输入错误,按任意键重输^^! & pause>nul & goto :CMDTool12)
set _IpAdd=!IpAdd:.= !
call :checkIpAdd !_IpAdd!
echo 按任意键返回主菜单...... 
pause>nul & Goto :CMDTool

:checkIpAdd
if "%4"=="" (echo 输入错误,按任意键重输^^! & pause>nul & goto :CMDTool12)
for %%i in (%1 %2 %3 %4) do (
    if %%i gtr 255 (echo 输入错误,按任意键重输^^! & pause>nul & goto :CMDTool12)
)
nbtstat -A !IpAdd!
goto :eof

::=============================显示系统信息===============================

:CMDTool13
cls
systeminfo
echo 按任意键返回主菜单......
pause>nul & Goto :CMDTool

:============================跟踪指定IP的路由=============================

:CMDTool14
cls
set Router=
set /p Router=请输入要跟踪的IP或域名[Q=主菜单]:
if /i "!Router!"=="Q" Goto :CMDTool
cls
echo 正在跟踪!Router!所通过的路由中,请稍后.....
tracert !Router!
echo 按任意键返回主菜单...... 
pause>nul & Goto :CMDTool

::===========================获取管理员所有权================================

:CMDTool15
cls
echo 正在添加权限........
(
 echo Windows Registry Editor Version 5.00
 echo [HKEY_CLASSES_ROOT\*\shell\runas]
 echo ^@="获取管理员所有权"
 echo "NoWorkingDirectory"=""
 echo [HKEY_CLASSES_ROOT\*\shell\runas\command]
 echo ^@="cmd.exe /c takeown /f \"^%%1\" && icacls \"^%%1\" /grant administrators:F"
 echo "IsolatedCommand"="cmd.exe /c takeown /f \"^%%1\" && icacls \"^%%1\" /grant administrators:F"
 echo [HKEY_CLASSES_ROOT\exefile\shell\runas2]
 echo ^@="获取管理员所有权"
 echo "NoWorkingDirectory"=""
 echo [HKEY_CLASSES_ROOT\exefile\shell\runas2\command]
 echo ^@="cmd.exe /c takeown /f \"^%%1\" && icacls \"^%%1\" /grant administrators:F"
 echo "IsolatedCommand"="cmd.exe /c takeown /f \"^%%1\" && icacls \"^%%1\" /grant administrators:F"
 echo [HKEY_CLASSES_ROOT\Directory\shell\runas]
 echo ^@="获取管理员所有权"
 echo "NoWorkingDirectory"=""
 echo [HKEY_CLASSES_ROOT\Directory\shell\runas\command]
 echo ^@="cmd.exe /c takeown /f \"^%%1\" /r /d y && icacls \"^%%1\" /grant administrators:F /t"
 echo "IsolatedCommand"="cmd.exe /c takeown /f \"^%%1\" /r /d y && icacls \"^%%1\" /grant administrators:F /t"
)>reg.reg

regedit /s reg.reg
del reg.reg
echo 添加完成，按任意键返回主菜单...... 
pause>nul & Goto :CMDTool

::===================================这是局域网共享工具程序================================

:CMDTool16
cls
title 局 域 网 共 享 工 具
color 4f
cls
echo                     ───────────────  
echo     ───────┤     局 域 网 共 享 工 具     ├────────
echo    │               ───────────────                 │
echo    │                                                              │
echo    │[1] 开通局域网共享               [2] 开通局域网共享(需验证)   │
echo    │                                                              │
echo    │[3] 关闭局域网共享               [4] 返回主菜单               │
echo    │                                                              │
echo    │[0] 退出                             17年10月28日             │
echo     ────────────────────────────────
ECHO;
choice /C 12340 /M "请选择！！
if errorlevel 5 exit
if errorlevel 4 Goto :CMDTool
if errorlevel 3 Goto :ShareOff
if errorlevel 2 Goto :ShareOn2
if errorlevel 1 Goto :ShareOn

:ShareOn
cls
ECHO;
ECHO                             说      明
ECHO --------------------------------------------------------------------
ECHO 本批处理执行后，将作以下一些设置：
ECHO 1、允许SAM帐户和共享的匿名枚举(原版系统允许，本系统默认是禁用)。
ECHO 2、本机帐户若空密码，允许其它机访问本机。
ECHO 3、Windows防火墙：允许文件和打印机共享。
ECHO 4、共享方式：本地用户以来宾身份验证。
ECHO 5、来宾帐户：启用。
ECHO --------------------------------------------------------------------
ECHO;
ECHO 采用这种共享方式，其它机访问本机都不用输用户名和密码。举例来说，家庭
ECHO 局域网，彼此都是可以信任的，请使用这种方式。
ECHO;
ECHO 无论采用哪一种共享方式，共享只是方便内部使用，在用路由器上网的场合，
ECHO 外网不能访问到您的机，无需担心共享了就会被入侵。您只需记住，单机拨号
ECHO 上网时，不要打开共享就可以了。
ECHO --------------------------------------------------------------------
ECHO;
echo 请详细阅读说明，任意键继续....
PAUSE>nul

::============================生成开通局域网共享.reg===============================

(

echo Windows Registry Editor Version 5.00

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo "restrictanonymous"=dword:00000000

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo "restrictanonymous"=dword:00000000
rem 以上两行在系统中的位置是：本地安全策略-安全选项-网络访问：不允许SAM帐户和共享
rem 的匿名枚举。系统默认值是：已停用。
rem 解说：操作系统默认:利用ipc$通道可以建立空连接,匿名枚举出该机有多少帐户。显然
rem 有一定的安全隐患。本系统已设为不允许空连接了。以此提高单机拨号上网的安全性。
rem 负面影响是局域网不能互访了。要更改一下才可以解决。

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo "limitblankpassworduse"=dword:00000000

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo "limitblankpassworduse"=dword:00000000
rem 以上两行在系统中的位置是：本地安全策略--安全选项--帐户：使用空白密码的本地帐户
rem 只允许进行控制台登录。系统默认值是：已启用。
rem 解说：很多人的帐户是不加密码的。这样，当局域网中别的电脑访问本机时，会弹出错误提示：
rem 登录失败：用户帐户限制………。这是XP系统的一条安全策略造成的，防止别人趁你空密码时
rem 进入你的电脑。如果你觉得无所谓，不必做这些限制，那就把它设为：已停用。

echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count]
echo "HRZR_EHAPCY"=hex:0C,00,00,00,26,00,00,00,F0,FB,E5,52,64,95,C6,01
echo "HRZR_EHAPCY:"P:\JVAQBJF\flfgrz32\sverjnyy.pcy",Jvaqbjf 防火墙"=hex:0C,00,00,00,08,00,00,00,F0,FB,E5,52,64,95,C6,01

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo "445:TCP"="445:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22005"
echo "137:UDP"="137:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22001"
echo "138:UDP"="138:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22002"
echo "139:TCP"="139:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22004"

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Epoch]
echo "Epoch"=dword:000001ED

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Print\Providers]
echo "LogonTime"=hex:E8,31,8E,4F,64,95,C6,01

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo "445:TCP"="445:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22005"
echo "137:UDP"="137:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22001"
echo "138:UDP"="138:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22002"
echo "139:TCP"="139:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22004"

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Epoch]
echo "Epoch"=dword:000001ED
rem 以上数值对应系统中的位置：控制面板--防火墙--例外--文件和打印机共享。系统默认：不选。
rem 解说：所有的策略都设置好了，局域网依然不能访问，提示：您没有权限使用网络资源，找
rem 不到网络路径！呵呵，真是令人火冒三丈！其实XP还有一道关卡，就是防火墙，必须要经过
rem 防火墙的允许才行。

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo "forceguest"=dword:00000001
rem 以上数值对应系统中的位置是：控制面板--管理工具--本地安全策略--本地策略--安全选项，
rem 网络访问：本地帐户的共享和安全模式：仅来宾-本地用户以来宾份验证。这时，当局域网
rem 其他机访问本机时，不会弹出对话框，就可以直接进入。在家庭网等完全可以信任的区域，
rem 建议使用这种方式。

)>开通局域网共享.reg

regedit /s 开通局域网共享.reg
net user Guest /active:yes
del 开通局域网共享.reg
cls
ECHO;
ECHO --------------------------------------------------------------------
ECHO 操作完成。按任意键返回菜单......
ECHO 注意：本机要重启后才会生效。
ECHO --------------------------------------------------------------------
ECHO;
ECHO 疑难问题补充：
ECHO   如果以前的共享方式是“本地用户以自己自己身份验证”时共享了文件夹，
ECHO 则现在改为以来宾身份验证后再访问该文件夹,会弹出错误：“无法访问，您
ECHO 没有权限使用网络资源.”解决办法是：在该文件夹属性上把原共享取消，然
ECHO 后重新共享，就行了。
ECHO --------------------------------------------------------------------

pause>nul && Goto :CMDTool16

:ShareOn2
cls
ECHO;
ECHO;                            说      明
ECHO --------------------------------------------------------------------
ECHO 本批处理执行后，将作以下一些设置：
ECHO 1、允许SAM帐户和共享的匿名枚举(原版系统允许，本系统默认是禁用)。
ECHO 2、本机帐户若空密码，允许其它机访问本机。
ECHO 3、Windows防火墙：允许文件和打印机共享。
ECHO 4、共享方式：本地用户以自己的身份验证。
ECHO 5、来宾帐户：不启用。
ECHO --------------------------------------------------------------------
ECHO;
ECHO 采用这种共享方式，访问本机时必须要输入正确的用户名和密码，才能访问。
ECHO;
ECHO 无论采用哪一种共享方式，共享只是方便内部使用，在用路由器上网的场合，
ECHO 外网不能访问到您的机，无需担心共享了就会被入侵。您只需记住，单机拨号
ECHO 上网时，不要打开共享就可以了。
ECHO --------------------------------------------------------------------
ECHO;
echo 请详细阅读说明，任意键继续....
PAUSE>nul

::============================生成开通局域网共享需验证.reg===============================

(

echo Windows Registry Editor Version 5.00

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo "restrictanonymous"=dword:00000000

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo "restrictanonymous"=dword:00000000
rem 以上两行在系统中的位置是：本地安全策略-安全选项-网络访问：不允许SAM帐户和共享
rem 的匿名枚举。系统默认值是：已停用。
rem 解说：操作系统默认:利用ipc$通道可以建立空连接,匿名枚举出该机有多少帐户。显然
rem 有一定的安全隐患。本系统已设为不允许空连接了。以此提高单机拨号上网的安全性。
rem 负面影响是局域网不能互访了。要更改一下才可以解决。

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo "limitblankpassworduse"=dword:00000000

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo "limitblankpassworduse"=dword:00000000
rem 以上两行在系统中的位置是：本地安全策略--安全选项--帐户：使用空白密码的本地帐户
rem 只允许进行控制台登录。系统默认值是：已启用。
rem 解说：很多人的帐户是不加密码的。这样，当局域网中别的电脑访问本机时，会弹出错误提示：
rem 登录失败：用户帐户限制………。这是XP系统的一条安全策略造成的，防止别人趁你空密码时
rem 进入你的电脑。如果你觉得无所谓，不必做这些限制，那就把它设为：已停用。

echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count]
echo "HRZR_EHAPCY"=hex:0C,00,00,00,26,00,00,00,F0,FB,E5,52,64,95,C6,01
echo "HRZR_EHAPCY:"P:\JVAQBJF\flfgrz32\sverjnyy.pcy",Jvaqbjf 防火墙"=hex:0C,00,00,00,08,00,00,00,F0,FB,E5,52,64,95,C6,01

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo "445:TCP"="445:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22005"
echo "137:UDP"="137:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22001"
echo "138:UDP"="138:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22002"
echo "139:TCP"="139:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22004"

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Epoch]
echo "Epoch"=dword:000001ED

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Print\Providers]
echo "LogonTime"=hex:E8,31,8E,4F,64,95,C6,01

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo "445:TCP"="445:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22005"
echo "137:UDP"="137:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22001"
echo "138:UDP"="138:UDP:LocalSubNet:Enabled:@xpsp2res.dll,-22002"
echo "139:TCP"="139:TCP:LocalSubNet:Enabled:@xpsp2res.dll,-22004"

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Epoch]
echo "Epoch"=dword:000001ED
rem 以上数值对应系统中的位置：控制面板--防火墙--例外--文件和打印机共享。系统默认：不选。
rem 解说：所有的策略都设置好了，局域网依然不能访问，提示：您没有权限使用网络资源，找
rem 不到网络路径！呵呵，真是令人火冒三丈！其实XP还有一道关卡，就是防火墙，必须要经过
rem 防火墙的允许才行。

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo "forceguest"=dword:00000000
rem 以上数值对应系统中的位置是：控制面板--管理工具--本地安全策略--本地策略--安全选项，
rem 网络访问：本地帐户的共享和安全模式：经典-本地用户以自己的身份验证。这时，当局域网
rem 其他机访问本机时，会弹出对话框，需要填写本机正确的用户名和密码才允许访问。这种方式
rem 是安全的。建议使用。

)>开通局域网共享需验证.reg

regedit /s 开通局域网共享需验证.reg
net user Guest /active:no
del 开通局域网共享需验证.reg
cls
ECHO;
ECHO -------------------------------------------------------------------
ECHO 操作完成。按任意键返回菜单.....
ECHO 无需重启，其它机现在就可以访问本机了。
ECHO;
ECHO -------------------------------------------------------------------
ECHO;
ECHO 常见疑问：
ECHO    经上述处理后，访问本机，如果仍然是直接就进去了，没出现提示输入帐
ECHO 号和密码的对话框，那是因为其他电脑的帐户名称跟本机帐户名一样(比如双
ECHO 方都是administrator)，且本机无密码。您应该把本机帐户改名，或加密码。
ECHO 这样，未经授权的用户就不能随意访问您共享的资源了。
ECHO -------------------------------------------------------------------
pause>nul && Goto :CMDTool16

:ShareOff
cls
ECHO OFF
ECHO;
ECHO;                      说     明
ECHO ----------------------------------------------------------
ECHO 本批处理执行后，将作以下一些设置：
ECHO 1、不允许SAM帐户和共享的匿名枚举(原版系统默认是允许的)。
ECHO 2、本机帐户若空密码，不允许其它机访问本机。
ECHO 3、Windows防火墙：不允许文件和打印机共享。
ECHO 4、来宾帐户：禁用。
ECHO;
ECHO 如果您不需要常在局域网内互传文件，可以关闭共享功能以提高
ECHO 安全性。尤其是单机拨号上网的用户，更应关闭共享。
ECHO ----------------------------------------------------------
@ECHO;
echo 请详细阅读说明，任意键继续....
PAUSE>nul

::============================生成关闭局域网共享.reg===============================

(

echo Windows Registry Editor Version 5.00

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo "restrictanonymous"=dword:00000001

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo "restrictanonymous"=dword:00000001
rem 以上两行在系统中的位置是：本地安全策略-安全选项-网络访问：不允许SAM帐户和共享
rem 的匿名枚举。系统默认值是：已停用。
rem 解说：操作系统默认利用ipc$通道可以建立空连接,匿名枚举出该机有多少帐户。显然
rem 有一定的安全隐患。本系统已设为不允许空连接了。以此提高单机拨号上网的安全性。
rem 负面影响是局域网不能互访了。要更改一下才可以解决。

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
echo "limitblankpassworduse"=dword:00000001

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Lsa]
echo "limitblankpassworduse"=dword:00000001
rem 以上两行在系统中的位置是：本地安全策略--安全选项--帐户：使用空白密码的本地帐户
rem 只允许进行控制台登录。系统默认值是：已启用。
rem 解说：很多人的帐户是不加密码的。这样，当局域网中别的电脑访问本机时，会弹出错误提示：
rem 登录失败：用户帐户限制………。这是XP系统的一条安全策略造成的，防止别人趁你空密码时
rem 进入你的电脑。如果你觉得无所谓，不必做这些限制，那就把它设为：已停用。

echo [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count]
echo "HRZR_EHAPCY"=hex:0C,00,00,00,2A,00,00,00,90,AF,A4,87,A4,95,C6,01
echo "HRZR_EHAPCY:"P:\JVAQBJF\flfgrz32\sverjnyy.pcy",Jvaqbjf 防火墙"=hex:0C,00,00,00,13,00,00,00,90,AF,A4,87,A4,95,C6,01

echo [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Cryptography\RNG]
echo "Seed"=hex:AC,6F,9A,2B,11,64,44,68,EC,90,1B,76,72,A7,0A,14,\
echo 4C,79,37,BB,FD,BD,70,B2,B2,58,D5,B5,89,5C,B6,4E,\
echo 3B,18,A5,26,46,BC,3E,6A,30,A4,7D,A0,56,E6,6A,B5,\
echo 57,3A,BF,A1,CD,CA,B6,64,4C,F9,0E,D2,64,ED,86,1F,\
echo 61,F6,D1,01,0B,7C,8D,BD,73,10,C8,4E,57,93,4E,90

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo "445:TCP"="445:TCP:LocalSubNet:Disabled:@xpsp2res.dll,-22005"
echo "137:UDP"="137:UDP:LocalSubNet:Disabled:@xpsp2res.dll,-22001"
echo "138:UDP"="138:UDP:LocalSubNet:Disabled:@xpsp2res.dll,-22002"
echo "139:TCP"="139:TCP:LocalSubNet:Disabled:@xpsp2res.dll,-22004"

echo [HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\SharedAccess\Epoch]
echo "Epoch"=dword:000001FC

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List]
echo "445:TCP"="445:TCP:LocalSubNet:Disabled:@xpsp2res.dll,-22005"
echo "137:UDP"="137:UDP:LocalSubNet:Disabled:@xpsp2res.dll,-22001"
echo "138:UDP"="138:UDP:LocalSubNet:Disabled:@xpsp2res.dll,-22002"
echo "139:TCP"="139:TCP:LocalSubNet:Disabled:@xpsp2res.dll,-22004"

echo [HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Services\SharedAccess\Epoch]
echo "Epoch"=dword:000001FC
rem 以上数值对应系统中的位置：控制面板--防火墙--例外--文件和打印机共享。系统默认：不选。
rem 解说：所有的策略都设置好了，局域网依然不能访问，提示：您没有权限使用网络资源，找
rem 不到网络路径！呵呵，真是令人火冒三丈！其实XP还有一道关卡，就是防火墙，必须要经过
rem 防火墙的允许才行。

)>关闭局域网共享.reg

regedit /s 关闭局域网共享.reg
net user Guest /active:no
del 关闭局域网共享.reg
cls
ECHO;
ECHO ----------------------------------------------------------
ECHO 操作完成。按任意键返回菜单......
ECHO 不必重启，设置已生效。
ECHO ----------------------------------------------------------
pause>nul & Goto :CMDTool16

::================================本机开放的端口及使用该端口的进程======================

:CMDTool17
cls
echo ╔-                              -╗ 
echo   本机开放的端口及使用该端口的进程 
echo ╚-                              -╝ 
echo ------------------------------------    
ECHO TCP协议rem 本机地址             外部地址              进程名称
::利用netstat命令找出使用TCP协议通信的端口，并将结果分割； 
::将第二个参数(IP加端口)传给%%i，第五个参数(PID号)传给%%j; 
for /F "usebackq skip=4 tokens=2,3,5" %%i in (`"netstat -ano -p TCP"`) do ( 
  call :Assoc %%i TCP %%k %%j
  echo          !TCP_Port:~,17!    !TCP_OutPort:~,17!    !TCP_Proc_Name:~,20!  
) 

ECHO UDP协议rem 本机地址                     进程名称
for /F "usebackq skip=4 tokens=2,4" %%i in (`"netstat -ano -p UDP"`) do (  
  call :Assoc %%i UDP %%j 
  echo          !UDP_Port:~,17!            !UDP_Proc_Name:~,20! 
) 
echo 按任意键返回主菜单
pause>nul & Goto :CMDTool

:Assoc 
set "kong=          "
::对%1(第一个参数）进行分割，将第二个参数传给%%e。在本程序中，%1即为上面的%%i(形式为：IP:端口号) 
for /F "delims=" %%e in ("%1") do set %2_Port=%%e!kong!

for /F "delims=" %%f in ("%4") do set %2_OutPort=%%f!kong!

::查询PID等于%3(第三个参数)的进程，并将结果传给变量?_Proc_Name,?代表UDP或者TCP； 
for /F "skip=1 usebackq delims=, tokens=1" %%a in (`"Tasklist /FI "PID eq %3" /FO CSV"`) do ( 
   rem %%~a表示去掉%%a外面的引号，因为上述命令的结果是用括号括起来的。  
   set %2_Proc_Name=%%~a!kong!
) 
goto :eof

::============================================禁启用 任务管理器===============================

:CMDTool18
cls
echo 禁启用任务管理器
ECHO;
set /p YN=ON-开启/OFF-关闭/Q-主菜单:
if /i "!yn!"=="q" Goto :CMDTool
if /i "!yn!"=="on" (
 set dword=0
 Echo 任务管理器已启用
) else (
 if /i "!yn!"=="off" (
  set dword=1
  Echo 任务管理器已禁用
 ) else (
  cls
  echo 输入错误，任意键返回主菜单 & pause>nul & Goto :CMDTool
))
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\system" /v disabletaskmgr /t REG_DWORD /d %dword% /f
pause>nul & Goto :CMDTool
复制代码