[文件操作] 如何实现删除文件夹及子文件夹中，文件名称中的括号及空格

phanton

@echo off
for /f "delims=" %%a in ('dir/b') do (
    set $=%%a
    setlocal enabledelayedexpansion
    for %%b in (^) ] } ） 】) do (
        if "!$:*%%b=!" NEQ "%%~xa" (
            if "!$:*%%b=!" NEQ "!$!" ren "!$!" "!$:*%%b=!"
        ) else (
            for /f "delims=([{（【" %%c in ("!$!") do (
                ren "!$!" "%%c%%~xa"
            )
        )
    )
    endlocal
)
setlocal enabledelayedexpansion
for /f "tokens=*" %%i in ('dir/b') do (
set fn=%%i
set fn=!fn: =!
ren "%%i" !fn!
)
pause
复制代码

这个在网上找回来的，只是对当前目录下的文件名称进行更改。不知道如何实现对子文件下的文件进行操作

lifei259

@echo off
for /f "delims=" %%I in ('dir/s/b/ad^|sort/r') do (
for /f "tokens=1-9 delims={}[]()（）【】｛｝ " %%a in ("%%~nI") do (
echo,ren "%%~fI" "%%a%%b%%c%%d%%e%%f%%g%%h%%i"
                                                                    )
                                                   )


for /f "delims=" %%J in ('dir/s/b/a-d') do (
for /f "tokens=1-9 delims={}[]()（）【】｛｝ " %%a in ("%%~nxJ") do (
echo,ren "%%~fJ" "%%a%%b%%c%%d%%e%%f%%g%%h%%i"
                                                                     )
                                            )
pause
复制代码