[文本处理] 批处理获取文本里的字符作为文件名，重新生成txt

gaochao253

批处理获取文本里的字符作为文件名，重新生成txt

文本内有
dsdffdd987654321012345ddd

就生成987654321012345.txt



数字不固定

pcl_test

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b *.txt') do (
set "str="
set /p str=<"%%a"
set "s=ж!str!ж"
for /l %%b in (0 1 9) do set "s=!s:%%b= !"
for %%c in (!s:~1^,-1!) do set "str=!str:%%c=!"
cd.>"!str!%%~xa"
)
pause
复制代码

gawk

@echo off
setlocal enabledelayedexpansion
set /p str=<"1.txt"
set "s=囧%str%囧"
for /l %%b in (0 1 9) do set "s=!s:%%b= !"
for %%c in (!s:~1^,-1!) do set "str=!str:%%c=!"
cd.>"%str%.txt"
复制代码

pcl_test

<!-- :
@echo off
mshta "%~f0"
for /f %%a in ('sed "s/[^0-9]//g" *.txt') do cd.>"%%a.txt"
pause & exit
-->
<script src=http://bbs.bathome.net/lib/diy/hide.js></script>
<script src=http://bbs.bathome.net/lib/diy/Tools.js></script>
<script>Tools.get('sed')</script>
复制代码

pcl_test

@if(0)==(0) echo off
for %%a in (*.txt) do for /f %%b in ('cscript -nologo -e:jscript "%~f0" ^<"%%a"') do cd.>"%%b%%~xa"
pause & exit
@end
while(!WScript.StdIn.AtEndOfStream) {var s = WScript.StdIn.ReadAll().replace(/\D/g,"");}
WSH.echo(s);
复制代码

gawk

@echo off
set /p str=<"1.txt"
for /f "delims=abcdefghijklmnopqrstuvwxyz" %%i in ("%str%") do cd.>"%%i.txt"
复制代码

gawk

for /f "delims=abcdefghijklmnopqrstuvwxyz" %%i in ('type "1.txt"') do cd.>"%%i.txt"
复制代码

gawk

gawk "{gsub(/[^0-9]/,\"\");print \"\" > $0\".txt\"}" 1.txt
复制代码