[文件操作] [已解决]批处理怎么统计文件夹中图片的个数？

001011

E:\图片\     下面有很多文件夹  路径深度不同  想统计每个文件夹中的图片个数
图片格式有两种  pdf和jpg
把结果放到：统计.txt中   要带路径  否则就不知道那个文件夹中有多少图片了
比如：E:\图片\20150325\2015-03-23\2013\C\0001\001  有图片58个
E:\图片\20150325\2015-03-23\2013\C\0001\002  有图片123个
感谢

bailong360

@Echo Off
Cd /d E:\图片\ 
(For /R /D %%i In (*) Do (
	For /F %%j In ('Dir "%%i" *.jpg *.pdf^|Findstr "个文件"') Do (
		Echo %%i 有图片%%j个
	)
))>统计.txt
复制代码

pcl_test

@echo off
cd /d "E:\图片\"
(for /f "tokens=*" %%a in ('dir /s *.jpg *.pdf ^|findstr /r "的目录 个文件 文件总数"') do echo %%a)>"%~dp0\统计.txt"
pause
复制代码

DAIC

@echo off
setlocal enabledelayedexpansion
pushd "E:\图片"
(for /r /d  %%i in (*) do (
    set n=0
    pushd "%%i"
    for /f %%j in ('dir /b *.jpg *.pdf 2^>nul') do (
        set /a n+=1
    )
    echo %%i 有图片!n!个
    popd
))>统计.txt
复制代码

001011

非常感谢  但是4楼的代码运行后没有反应
2楼的运行比较慢
3楼的最好  
再次感谢

001011

再麻烦一下  能表达出  jpg有几个  pdf有几个吗  谢谢

DAIC

回复 5# 001011


专治“一闪而过”、“闪退”的秘方：

代码里面的 @echo off 删掉
保存为 C:\test.bat
打开一个CMD窗口，执行命令：
C:\test.bat

这样可以看到详细的报错信息或者线索，以及具体哪一行代码在报错。

DAIC

回复 6# 001011

@echo off
setlocal enabledelayedexpansion
pushd "E:\图片"
(for /r /d  %%i in (*) do (
    pushd "%%i"
    set x=0
    for /f %%j in ('dir /b *.jpg 2^>nul') do (
        set /a x+=1
    )
    echo %%i 里面 jpg 有 !x! 个
    set y=0
    for /f %%j in ('dir /b *.pdf 2^>nul') do (
        set /a y+=1
    )
    echo %%i 里面 pdf 有 !y! 个
    popd
))>统计.txt
复制代码

001011

完美达到目的  非常感谢