[文本处理] 文件目录名如何用批处理正则处理？

friendtasy

要求，把目录拖到批处理图标，按要求处理目录或文件名

文件名如(a10_XXX.DOC,B112_AAED.TXT)格式，目录就如D16_mm之类的，要求把a10_变为空值，重新命名文件名或目录名，如(a10_XXX.DOC变为XXX.DOC），处理可深入到子目录，现附以前求高手弄的一个批处理供参考修改，希望大侠能帮忙解决这个问题。
下划线前可能是不固定的字母数字组合

@echo off
rem 请不要修改本批处理，修改之后有可能运行不了
rem 把要处理的文件夹拖到本批处理的图标上
rem 如果是把文件拖到本本批处理的图标上，批处理不能正确执行
mode con COLS=35 LINES=10
call :tt
setlocal enabledelayedexpansion
:began
cls
for /f "delims=〓" %%i in ('dir "%~1\-*" /b /s') do  (
set aa=%%~ni
set aa2=%%~fi
set aa2=!aa2:~-3!
set aa=!aa:~1!
attrib -r -s -h "%%~fi"
echo  "!aa!%%~xi" >nul
ren "%%~fi" "!aa!%%~xi"
)
shift
if /i not "%~1" == "" goto began
color 1b
echo 文件已处理完
echo 按任意键退出
pause >nul
goto :eof
:tt
title 批处理改名
goto :eof
复制代码

apang

正则处理啊？
需要处理文件夹还是文件呢？

terse

@echo off&setlocal enabledelayedexpansion
if "%~1" == "" exit
for /f "delims=" %%a in ('dir /b /s %1^|sort /r') do (
    set "str=%%~nxa"
    ren "%%a" "!str:*_=!"
)
pause
复制代码

friendtasy

terse 发表于 2014-9-3 17:07

    非常感谢，试用一下，应该能满足要求了，朋友dir 一条命令怎么分出文件和目录呢？以前我处理一些类似的会用DIR用参数区分文件和目录。