[文本处理] 批处理如何搜索日志中的关键字并锁屏？

lion991128

有个软件在每天会产生很多LOG文件（TXT文本格式），在文本里面会有DONE或者ERROR表示成功或者失败：

如何用批处理进行文本的搜索如果是有ERROR的复制一份到桌面并且对本机进行锁屏操作。是否这样可以用批处理实现？

lion991128

没有人能教教我吗？

DAIC

@echo off
if exist "%userprofile%\Desktop\" (
    set "mydesk=%userprofile%\Desktop"
) else if exist "%userprofile%\桌面\" (
    set "mydesk=%userprofile%\Desktop"
) else (
    echo 找不到桌面的位置
)
for /f "delims=" %%i in ('findstr /m "ERROR" *.log') do (
    copy /y "%%i" %mydesk%
)
pause
复制代码

lion991128

谢谢老大慷慨赐教 但是还有一个问题 我何如能在搜索到错误信息时锁定本机呢？

lion991128

还有一个问题 在XP下运行会出现语法错误 是怎么回事呢

apang

修改3楼的：

@echo off
if exist "%userprofile%\Desktop\" (
    set "mydesk=%userprofile%\Desktop"
) else (
    if exist "%userprofile%\桌面\" (
        set "mydesk=%userprofile%\桌面"
    ) else echo 找不到桌面的位置
)

for /f "delims=" %%i in ('findstr /m "ERROR" *.log') do (
    copy /y "%%i" "%mydesk%\"
)
rundll32.exe user32.dll,LockWorkStation
复制代码

lion991128

完美运行 谢谢2位高手的帮忙

DAIC

回复 7# lion991128


    6楼的代码在搜索不到错误信息的情况下也会锁屏，你试试。

DAIC

回复 5# lion991128


    不管什么时候，请把报错信息贴出来，否则大家没有办法继续帮助你。

lion991128

Date;2013-06-11;09:15:48
Product-Sequence;Melco;Calibration_Test_FAST
PartNumber-SerialNumber;783801-0029;QF0464S
TestTime;29.24;sec
Result-Error-Description;Failed;75;Range OUT of Limits
Start Calibration Mode;;;Exp;OK;Meas;OK;/;1;/assed;0
Initialization Value Mem;;;Exp;01;Meas;01;/;;;Passed;0
Initialization Value Check;;;Exp;01;Meas;01;/;;;Passed;0
Range Temp;Min;360;Max;440;Meas;408;bit;;;Passed;0
Communication Speed;;;;;Meas;250;/;;;Passed;0
CAN_NML_SND;;;;;Meas;18FF1002;/;;;Passed;0
CAN_NML_REC;;;;;Meas;18FF1000;/;;;Passed;0
Range;;;;;Meas;408;bit;;;Passed;0
Range;;;;;Meas;408;bit;;;Passed;0
Range;;;;;Meas;408;bit;;;Passed;0
Sweep Time;Min;500;Max;3000;Meas;1495;msec;;;Passed;0
FOHS;;;;;Meas;2;bit;;;Passed;0
Screw FOHS Position;Min;13;Max;15;Meas;13;bit;;;Passed;0
Recheck Screw FOHS Position;Min;13;Max;15;Meas;12;bit;;;Failed;75

这个是错误信息

Date;2013-06-11;07:11:47
Product-Sequence;Melco;Calibration_Test_FAST
PartNumber-SerialNumber;783801-0029;QF0410S
TestTime;133.72;sec
Result-Error-Description;Passed;0;
Start Calibration Mode;;;Exp;OK;Meas;OK;/;1;/;Passed;0
Initialization Value Mem;;;Exp;01;Meas;01;/;;;Passed;0
Initialization Value Check;;;Exp;01;Meas;01;/;;;Passed;0
Range Temp;Min;360;Max;440;Meas;411;bit;;;Passed;0
Communication Speed;;;;;Meas;250;/;;;Passed;0
CAN_NML_SND;;;;;Meas;18FF1002;/;;;Passed;0
CAN_NML_REC;;;;;Meas;18FF1000;/;;;Passed;0
Range;;;;;Meas;411;bit;;;Passed;0

以上是成功的信息

lion991128

回复 8# DAIC

这位老兄真细心 是有这个问题存在，而且还有一个问题就是如果以前的错误信息也会在判定成功失败的时候认为是现在出现的失败。

是否能达到进行一个差备的比较或者是能根据系统时间去认证只在今天产生的LOG中是否有错误存在？

terse

这样行不

@echo off
set "flag="
set reg=reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
for /f "skip=4 tokens=2*" %%i in ('%reg% /v "desktop"') do set "desktop=%%j"
for /f "delims=" %%i in ('findstr /im "%date:~,10%" *.log') do (
	findstr /im ERROR "%%i" >nul && (
		copy "%%i" "%desktop%"
		set flag=rundll32.exe user32.dll,LockWorkStation
	)
)
%flag%
复制代码

lion991128

这样行不
terse 发表于 2013-9-18 13:46

%date:~ 的这里是取系统时间的值吗？但是生成的LOG并不是标准的时间格式：783801-0029_QF0464S_20130611_091548.txt 例如这样的名字 红色的地方是标识日期的这个如何识别啊？

terse

回复 13# lion991128
文件名含当天日期

@echo off
set "flag="
set reg=reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
set dt=%date:~,10%
for /f "skip=4 tokens=2*" %%i in ('%reg% /v "desktop"') do (
	for /f "tokens=*" %%k in ("%%j") do set "desktop=%%k"
)
for /f "delims=" %%i in ('findstr /im "ERROR" *.log^|findstr "%dt:-=-*%"') do (
        copy "%%i" "%desktop%"
        set flag=rundll32.exe user32.dll,LockWorkStation    
)
%flag%
pause
复制代码

文件内容含当天日期

@echo off
set "flag="
set reg=reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
set dt=%date:~,10%
for /f "skip=4 tokens=2*" %%i in ('%reg% /v "desktop"') do (
	for /f "tokens=*" %%k in ("%%j") do set "desktop=%%k"
)

for /f "delims=" %%i in ('findstr /im "%dt:-=-*%" *.log') do (
        findstr /im ERROR "%%i" >nul && (
                copy "%%i" "%desktop%"
                set flag=rundll32.exe user32.dll,LockWorkStation
        )
)
%flag%
pause
复制代码

当天日期文件

@echo off
set "flag="
set reg=reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
for /f "skip=4 tokens=2*" %%i in ('%reg% /v "desktop"') do (
	for /f "tokens=*" %%k in ("%%j") do set "desktop=%%k"
)
for /f "delims=" %%i in ('findstr /im "ERROR" *.log') do (
    for /f %%j in ("%%~ti") do (
        if /i "%%j" == "%date:~,10%" (
           copy "%%i" "%desktop%"
           set flag=rundll32.exe user32.dll,LockWorkStation
        )
    )   
)
%flag%
pause
复制代码

lion991128

回复 14# terse


  回大大 这个运行说是语法错误。