[文本处理] [已解决]more如何获取文本指定范围内的行内容？

522235677

more /e +5 %0 >"%temp%\down.vbs"
复制代码

这个只能从读取从第五行一只到最后。
我就是想只读取 第五行到第十行这五行内容。不知道能不能行。看了系统的帮助more /？ 弄了半天都不行

Batcher

more命令没有这样的参数，你得自己想办法。

yukunldhy

不知道这样行不？ for(累加取行)+if(判断，大于等于5，小于等于10)

@echo off 
set num=0 
nul>"%temp%\5-10.txt"
setlocal enabledelayedexpansion 
for /f "delims=" %%i in (XXX.txt) do ( 
set /a num+=1 
set str=%%i 
if !num! geq 5 (
 if !num! leq 10 echo !str! >>"%temp%\5-10.txt"
 )
)
pause 
复制代码

CrLf

打印 5 ～ 12 行的内容，需要用第三方工具 sed：

sed "5,12!d"
复制代码

因为 more 是外部命令，所以效率不比 sed 有优势

CrLf

非要用 more 的话，就比较猥琐了，适合处理超大文件，比起 sed 唯一点优势是系统自带：

@echo off
set "file=a.txt"
set /a min=5,max=12
for /f %%a in ('find /c /v ""^<"%file%"') do set /a rev=max-%%a
more +%min% "%file%"|sort /+65535 /rec 65535 /o "%file%.tmp"
more +%rev% "%file%.tmp"|sort /+65535 /rec 65535 /o "%file%"
del "%file%.tmp" >nul
pause
复制代码

CrLf

纯内部命令可以这样：

@echo off
set "file=a.txt"
set /a min=5,max=12

setlocal enabledelayedexpansion
for /f "skip=%min% tokens=1* delims=:" %%a in ('findstr /n .* "!file!"') do (
   if %%a leq %max% echo;%%b
)>!file!.txt
复制代码

CrLf

或这样

@echo off
set "file=a.txt"
set /a min=5,max=12

setlocal enabledelayedexpansion
for /f "delims=" %%a in ('more +%min% "!file!"') do (
   set /a min+=1
   if !min! neq %max% echo;%%a
)>!file!.txt
复制代码

CrLf

这样也行：

@echo off
set "file=a.txt"
set /a min=5,max=12

setlocal enabledelayedexpansion
for /f "skip=%min%" %%a in (!file!) do (
   set /a min+=1
   if !min! neq %max% echo;%%a
)>!file!.txt
复制代码

CrLf

也可以这样：

@echo off
set "file=a.txt"
set /a min=5,max=12

setlocal enabledelayedexpansion
(for /l %%a in (1 1 %min%) do set /p=
for /l %%a in (%min% 1 %max%) do set /p str=&echo;!str!
)<!file!>!file!.txt
pause
复制代码

522235677

回复 8# CrLf


    这么多办法，我怎么就没想到呢

522235677

:uu
set hs=0
for /f "delims=" %%a in ('more +%1 "%n0%"') do (
	set /a hs+=1
	echo %%a >>%3
	if "!hs!"=="%2" goto :eof)
复制代码

感谢楼上几位帮忙，得到启发了。具体的我就是这么写的。

34205

回复 8# CrLf


    学习了1111111111

happy886rr

@echo off
CALL :More 3 2 "%~f0"
set/p=&exit
显示的内容为过滤头部3行和过滤尾部2行
:More <HeadCut> <EndCut> <FileName>
more +%1 %3|sort /+1024 /rec 1024|more +%2|sort /+1024 /rec 1024|more +1
复制代码