[文件操作] 批处理如何将多级文件夹串联起来并平级排序？

wxlong

最外层文件夹中有名称为001,002,003……128（名称可能没规律）的文件夹，001文件夹中又有从a001到a0**的文件夹，002，003……文件夹中也有类似的文件夹排列，有时a001中又有b001到b0**的文件夹排列，现在希望能够将文件夹名称串起来，然后将最里层文件夹（包括夹内文件）移动到新文件夹中。最终结果是在新文件夹中，文件夹不再嵌套，而是平级排列，名称分别为：
001-a001-b001，
001-a001-b002，
001-a001-b003，
……
001-a002-b001，
001-a002-b002
001-a002-b003
……
128-a099-b001
128-a099-b002
……
128-a099-b101

terse

发生同名文件怎么处理呢?

@echo off&setlocal enabledelayedexpansion
for /d /r %%i in (*) do (
set N=a
for /d %%i in ("%%i\*") do set N=
if defined N XCOPY /E /Y /H /R "%%i" "%%~nxi\" >nul
)
pause
复制代码

apang

@echo off
for /f "delims=" %%a in ('dir /ad/b/s') do (
  for /d %%b in ("%%a\*") do set flag=1
  if not defined flag (
    set "Name=%%a"
    setlocal enabledelayedexpansion
    set "Name1=!Name:%~dp0=!"
    xcopy "!Name!\*" "%~dp0New\!Name1:\=-!\"
    rd /s /q "!Name!"
    endlocal
  ) else set flag=
)
pause
复制代码

terse

移动的 可考虑 MOVE

apang

回复 4# terse

嗯。要事先有创建New文件夹。

@echo off
md New 2>nul
for /f "delims=" %%a in ('dir /ad/b/s^|findstr /iv "\\New$"') do (
  for /d %%b in ("%%a\*") do set flag=1
  if not defined flag (
    set "Name=%%a"
    setlocal enabledelayedexpansion
    set "Name1=!Name:%~dp0=!"
    Move "!Name!" "%~dp0New\!Name1:\=-!"
    endlocal
  ) else set flag=
)
pause
复制代码