[网络连接] [已解决]批处理获取ip地址并判断的代码，能否进一步简化？

ygqiang

for /f "tokens=2 delims=:" %%b in ('ipconfig^|find /i "ip"') do set fsip=%%b
echo %fsip%
Set fsip=%fsip: =%
echo 去掉ip前面的空格
echo %fsip%

if "%fsip%" == "10.10.9.200"   exit
if "%fsip%" == "10.10.93.100"  exit
if "%fsip%" == "10.10.94.200"  exit
if "%fsip%" == "10.10.127.200" exit

;--------------------------------------------------------------------------------------------------

for /f "tokens=15 delims= " %%i in ('ipconfig ^| find /i "IP Address"') do set i=%%i
for /f "tokens=1,2,3 delims=." %%i in ("%i%") do (set a=%%i.%%j.%%k)
set Gateway=%a%.1

echo %a%.1

if "%a%" == "10.10.9"   set a=%a%.200 & goto :next
if "%a%" == "10.10.93"  set a=%a%.100 & goto :next
if "%a%" == "10.10.94"  set a=%a%.200 & goto :next
if "%a%" == "10.10.127" set a=%a%.200 & goto :next
exit

:next
复制代码

我要实现的目的是：

先判断ip地址是否是（10.10.9.200 10.10.93.100 10.10.94.200 10.10.127.200）其中的一个，如果是，就直接退出；如果不是，就继续下面的判断

判断ip地址前面三位是否是（10.10.9 10.10.93 10.10.94 10.10.127）其中的一个，如果是，就跳转到:next，否则就退出

上面的批处理，是否有简化的可能？谢谢

awk

你既然知道怎样用空格做为列分隔符获取IP地址，为何开头还要使用那么蛋疼的方法去替换空格呢？

awk

连续的4行if改成if...else...的结构，减少执行代码时浪费在毫无意义的重复判断上面的时间。

ygqiang

不好意思。

上面的代码，都是从论坛或者qq好友 获得的。

能否帮忙整体修改下？谢谢。

ygqiang

for /f "tokens=2 delims=:" %%b in ('ipconfig^|find /i "ip"') do set fsip=%%b

echo %fsip%

Set fsip=%fsip: =%

echo 去掉ip前面的空格

echo %fsip%
echo "%fsip%"|findstr "10.10.9.200 10.10.93.100 10.10.94.200 10.10.127.200">nul&&exit

后面是别的代码
复制代码

这是有人给出的代码。

awk

@echo off
for /f "tokens=15 delims= " %%i in ('ipconfig ^| find /i "IP Address"') do (
    set fsip=%%i
)
echo %fsip%
if "%fsip%" equ "10.10.9.200" (
    goto :end
) else if "%fsip%" equ "10.10.93.100" (
    goto :end
) else if "%fsip%" equ "10.10.94.200" (
    goto :end
) else if "%fsip%" equ "10.10.127.200" (
    goto :end
)

for /f "tokens=1,2,3 delims=." %%i in ("%fsip%") do (
    set a=%%i.%%j.%%k
)
set Gateway=%a%.1
echo %a%.1
if "%a%" equ "10.10.9" (
    set a=%a%.200
) else if "%a%" equ "10.10.93" (
    set a=%a%.100
) else if "%a%" equ "10.10.94" (
    set a=%a%.200
) else if "%a%" equ "10.10.127" (
    set a=%a%.200
)

:end
复制代码

ygqiang

多谢楼上。

初步测试，代码可以正常运行。

@echo off

:stat

md d:\0beifen >nul 2>nul
md d:\0beifen\soft >nul 2>nul

copy /y 00-00robocopy.exe "c:\windows\system32\" >nul 2>nul
copy /y 开通局域网共享(访问本机无需验证即可进入).reg "c:\WINDOWS\system32\" >nul 2>nul

rem 获取本机ip
for /f "tokens=14 delims=: " %%b in ('ipconfig^|find /i "ip"') do set fsip=%%b
echo %fsip%
pause

rem 获取本机ip前3段
for /f "tokens=1,2,3 delims=." %%i in ("%fsip%") do (
    set a=%%i.%%j.%%k
)
echo %a%
pause


if "%fsip%" equ "10.10.9.200" (
    goto :set0
) else if "%fsip%" equ "10.10.93.100" (
    goto :set0
) else if "%fsip%" equ "10.10.94.200" (
    goto :set0
) else if "%fsip%" equ "10.10.127.200" (
    goto :set0
)
goto :set1


cls
;--------------------------------------------------------------------------------------------------
:set0
;--------------------------------------------------------------------------------------------------
cls

echo 设定文件服务器为：%fsip%
pause

regedit /s 开通局域网共享(访问本机无需验证即可进入).reg
net user Guest /active:yes

reg add "HKLM\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t reg_dword /d 0  /f
rem 取消“使用简单文件共享”方式

net share soft=d:\0beifen\soft

exit


cls
;--------------------------------------------------------------------------------------------------
:set1
;--------------------------------------------------------------------------------------------------
cls

if "%a%" equ "10.10.9" (
    set a=%a%.200
) else if "%a%" equ "10.10.93" (
    set a=%a%.100
) else if "%a%" equ "10.10.94" (
    set a=%a%.200
) else if "%a%" equ "10.10.127" (
    set a=%a%.200
) else (
    echo 本机ip非设定范围！
    exit
)
echo %a%
pause

:ptaget
ping.exe %a% -n 1 -w 300 >nul&&goto :lineon||goto :lineoff

:lineoff
echo 文件服务器：%a%----离线
pause
ping 127.0.0.1 -n 60
goto :ptaget



cls
;--------------------------------------------------------------------------------------------------
:lineon
;--------------------------------------------------------------------------------------------------
cls

echo 文件服务器：%a%----在线
pause

rem 创建文件夹的快捷方式
cls
SET link=%UserProfile%\桌面\常用软件.url  
ECHO [InternetShortcut]>"%link%" 
ECHO URL=d:\0beifen\soft>>"%link%" 
ECHO WorkingDirectory=%SystemRoot%>>"%link%" 
ECHO ShowCommand=7>>"%link%" 
ECHO IconFile=C:\WINDOWS\system32\url.dll>>"%link%" 
ECHO IconIndex=^0>>"%link%" 
ECHO HotKey=>>"%link%" 
cls

echo 文件服务器为：%a%，下载数据到本地
pause

:nextaaa

ping.exe %a% -n 1 -w 300 >nul&&goto :lineon1||goto :lineoff1

:lineoff1
echo 文件服务器：%a%----离线
ping 127.0.0.1 -n 120
goto :nextaaa

:lineon1
00-00robocopy "\\%a%\soft" "d:\0beifen\soft" /mir
ping 127.0.0.1 -n 120

goto :nextaaa

;--------------------------------------------------------------------------------------------------
cls
复制代码

awk

回复 7# ygqiang


47行、82行可以删掉

ygqiang

多谢楼上。7楼已经重新更新了代码。