[加密解密] 批处理版文件夹加密（2008-08-02更新）

jsj30651

闲着没事做，写了个文件夹加密的批处理。
当然，方法很简单，只能对付那些菜鸟^_^
和市面上大部分的文件夹加密软件原理差不多……


加密原理就是：在与本批处理相同的目录下新建一个名为“控制面板”的文件夹，设置隐藏、系统属性，把它伪装控制面板，双击打开会直接进入控制面板。
再在“控制面板”文件夹中新建一个文件夹“files..”由于这个文件夹在windows并不是合法的文件夹，所以无法在windows中删除，用批处理打开，就等
于打开了隐藏在这个目录中的文件夹
.\控制面板\files..\

为了不让别人清空回收站时把文件删除，已把回收站改成控制面板，
其实可以在回收站里面新建一个“nul”或“aux”之类的文件夹，然后把文件放在新建的这个文件夹中，这样就不怕清空回收站了

原先路径中不能有空格（不能在桌面上运行）现已经修改

另外本批处理只是简单的把文件给隐藏了，如果有重要文件，建议还是用专业的加密软件，现在市面上像“高强度文件夹加密大师”之类的文件夹加密软件原理类似，
很容易破解……

@echo off&title 文件夹加密&color 0f&mode con cols=30 lines=15

set l1= ============================
set l2=    编写：      野菜
set l3= ----------------------------
set l4=   ＱＱ：９５９２１２６７７
set l5= ============================

if exist 控制面板\ goto start
md 控制面板
attrib 控制面板 +s +h
echo [.ShellClassInfo]>控制面板\desktop.ini
echo CLSID={21EC2020-3AEA-1069-A2DD-08002B30309D}>>控制面板\desktop.ini
attrib 控制面板\desktop.ini +s +h +r

:once
echo %l1%
echo %l2%
echo %l3%
echo %l4%
echo %l5%
echo.
echo          首次使用
echo.
goto pwd
:pwd0
cls
echo 两次输入密码不一致，请重新输入
echo.
:pwd
set /p pwd="请设置密码："
if '%pwd%'=='' goto pwd
set /p pwd0="请再输一次："
if not '%pwd%'=='%pwd0%' goto pwd0
echo %pwd%>控制面板\pwd.lnk
attrib 控制面板\pwd.lnk +s +h
echo.
echo 密码设置成功
ping 127.1 -n 3 >nul 2>nul
md 控制面板\files..\
goto start0

:start
if not exist 控制面板\pwd.lnk goto once
for /f "tokens=*" %%a in (控制面板\pwd.lnk) do set mima=%%a
echo %l1%
echo %l2%
echo %l3%
echo %l4%
echo %l5%
set /p pass="请输入密码："
goto kaishihou
:kaishi
set /p pass="请输入密码："
:kaishihou
if '%pass%'=='' goto kaishi
if '%pass%'=='%mima%' goto start0
cls
echo 对不起，密码错误！请重新输入！
goto kaishi

:start0
cls
echo %l1%
echo %l2%
echo %l3%
echo %l4%
echo %l5%
echo.
echo      １、打开加密文件夹
echo.
echo      ２、删除加密文件夹
echo.
set /p choose="请选择："
if '%choose%'=='' goto start0
if %choose%==1 goto open
if %choose%==2 goto 2

:2
cls
echo 删除后原先加密文件夹中的文件也将被删除，请确定您已经备份过重要文件！！！
echo.
set /p del="确认删除？ Y/N ？"
if /i '%del%'=='y' (
  rd /q /s 控制面板
  echo 操作成功！
  ping 127.1 -n 3 >nul 2>nul
  exit
)
echo 已取消操作
ping 127.1 -n 3 >nul 2>nul
goto start0

:open
cd 控制面板
start "" "%cd%\files..\"
复制代码

鹤冲天

收藏了，学习一哈！
3Q！！

drwtsn66

高明
学习中..................

namejm

　　市面上很多加密软件都是用这个思路加密，会严重威胁数据的安全：很多人都有随手清理回收站的习惯，要是哪天心血来潮了，用户就等着呼天抢地吧。

jsj30651

那就把回收站改成控制面板或其他的，当然重要数据不能这么加密，要用专业的磁盘加密软件，这种方法只能应付菜鸟^_^

初级干部

我在我的电脑上测试的时候,在<１、打开加密文件夹２、删除加密文件夹>的时候,1选项没反应.不过我还是在桌面上找到了它,并将它给删掉了.

jsj30651

因为路径中不能有空格……

fuwei880306

没看明白，不知道到底是给哪个文件夹加密，也不能把要加密的文件夹脱到这个.bat文件里

jsj30651

原来的代码有点问题，重新编辑后代码中凡是含有“：o”的都会被忽略，开始没发现这个问题，现在已修改。

都市浪子666

原帖由 jsj30651 于 2008-7-12 19:02 发表
闲着没事做，写了个文件夹加密的批处理。

但是路径中不能带空格，比如在桌面上运行批处理，那么，运行打开命令是就成了
start C:\Documents and Settings\Administrator\桌面\控制面板\files..\，由于Documents and Settings间有空格，所以会出错，

有空格的路径一样可以打开,嘿嘿.拦不住滴

用这个命令可以打开

 

start "" "C:\Documents and Settings\Administrator\桌面\控制面板\files..\"
复制代码

[ 本帖最后由 Batcher 于 2009-5-9 20:09 编辑 ]

jsj30651

谢谢 “都市浪子666”  start "" "C:\Documents and Settings\Administrator\桌面\控制面板\files..\"  我还第一次知道可以这么用^_^

jawe

好东西呀，学习中。。。。。。。。

caojianjia

好顶顶顶试试看

sampeck

原帖由 jsj30651 于 2008-8-2 14:52 发表
谢谢 “都市浪子666”  start "" "C:\Documents and Settings\Administrator\桌面\控制面板\files..\"  我还第一次知道可以这么用^_^

其实包括畸型文件夹在内都是可以用这么方法打开或删除的(曾经在XP-SP2 XP-SP3测试通过).