[文本处理] [已解决]批处理怎样把每行都有的10位数字按行重写？

w1983912

TXT   GBK   每行都有3个 不同的10位数字  能否直接把10位数字变成一样的 并且该数字每行增加3000
内容示例  2行:
INSERT INTO `dede33_archives` VALUES('1','10','0','1262245911','c','1','1','-2','0','0','引起痛经几大病症(图)','','','','','','1268045911','1267115111','1','痛经,引起几大病症(图)','0','0','0','0','0','引起痛经的几大病症(图),健康','','0','0','0');
INSERT INTO `dede33_archives` VALUES('2','10','0','1261145911','c','1','1','-2','0','0','经期不适试喝玫瑰花茶俏丽逛街装','','','admin','未知','/uploads/allimg/100307/2103595C7-0.jpg','1267045911','1267945011','1','孕前,适可尝试喝玫瑰花茶(','0','0','0','0','0','经期不适可尝试喝玫瑰花茶(图),健康','','0','0','0');

每行都有3个10位数字哦   只有这个特征 我都无法用什么来表达了.....

请从第一行开始 3个10位数都变  1295097000
第2行 就在上行得到的数字上+3030  3个10位数字变成  1295100030
第3行 变 1295103060
...........一直接下去  只变这3个数字哦

希望哪位朋友能帮帮我 谢谢

batman

请问楼主1295097000与第一行的三个数字有什么联系？如何运算得来的

batman

暂时没有找到好方法

@echo off&setlocal enabledelayedexpansion
(for /f "delims=" %%a in (a.txt) do (
    set "str=%%a"&set "str=!str:''=' '!"
    if not defined n (
       set /a n=129509700
       ) else (
       set /a n+=3030
    )
    for /f "tokens=5,18,19 delims=,'" %%a in ("!str!") do (
        for %%i in (!n!) do (
            set "str=!str:%%a=%%i!"
            set "str=!str:%%b=%%i!"
            set "str=!str:%%c=%%i!"
        )
    )
    echo !str:' '=''!
))>tem
del /q a.txt&ren tem a.txt
start a.txt
复制代码

随风

貌似这样加下去很快就会超过cmd的计算范围了

@echo off
set /a n=1295097000-3030
for /f "delims=" %%i in (a.txt) do (
   set "str=%%i"
   set /a n+=3030
   setlocal enabledelayedexpansion
   set aus=!str:'= !
   for %%j in (!aus!) do (
       set var=%%ja&set num=%%j
       for /l %%L in (0 1 9) do (
          set var=!var:%%L=!
          set num=!num:%%L= %%L !
       )
       if "!var!"=="a" (
          set i=0
          for %%j in (!num!) do set /a i+=1
          if !i! equ 10 (
             set num=!num: =!
             for %%j in (!num!) do (
                 for %%k in (!n!) do set str=!str:%%j=%%k!
             )
           )
        )
    )
    echo !str!
    endlocal
)
pause
复制代码

w1983912

谢谢 两位  已经解决 能实现  太爽了