[文件操作] 移动当天文件夹和文件到当天日期文件夹的bat代码怎么写？

onging

当天日期文件夹也想要通过bat生成，谢谢大佬们！

flashercs

@echo off
cd /d "%~dp0"
@REM 把当前目录下 创建日期是今天的文件和文件夹移动到 今天'yyyy-MM-dd'文件夹
set "batchfile=%~f0"
powershell -c "$today=[datetime]::Today;$di=[io.directory]::CreateDirectory($today.ToString('yyyy-MM-dd'));gci|where{$_.CreationTime.Date -eq $today -and $_.FullName -ne $di.FullName -and $_.FullName -ne $env:batchfile}|Move-Item -Destination ($di.FullName) -Verbose"
pause
复制代码

aloha20200628

回复 1# onging

新建当天文件夹例如 "2024-09-06" 与当前文件夹平级
以下批处代码存为 test.bat 置于当前文件夹下运行，将当前文件夹下当天创建生成的全部文件（排除本批处脚本文件）和子文件夹移到新建当天文件夹中 ...

@echo off &md "..\%date:~,10%" 2>nul
(for /f "tokens=3* delims= " %%a in ('dir /tc/o-d^|findstr /bc:"%date:~,10% " ') do if "%%b" neq "." if "%%b" neq ".." if /i "%%b" neq "%~nx0" move /y "%%b" "..\%date:~,10%\") 2>nul
pause&exit/b
复制代码

onging

回复 3# aloha20200628
谢谢！您的代码不起作用呢，flashercs大佬的就可以

onging

回复 2# flashercs
谢谢！可以了！

aloha20200628

回复 4# onging

我测试顺利通过的系统:
   系统日期变量 %date% 采用的序列和分隔符如是 2024-09-06，命令行用 echo,%date% 即可查看结果；
   系统码页（命令行用 chcp 查看）是936，不是65001
   与楼主有差别吗？
重新调整了3楼代码获取当天时间值的方法，如果与楼主采用的系统码页没有差别，再试试3楼代码应该可以了...

ppll2030

回复 6# aloha20200628


    楼主的系统日期可能还是默认用的 / 分隔符。所以无法正确创建文件夹

aloha20200628

回复 7# ppll2030
回复 4# onging

谢谢！据此再修理一下3楼代码如下。
想起了以前曾和77七讨论过不同系统版本的%date%返回值不一定相同的问题，稳妥之策还是要用 %date:~0,10% 取值...

@echo off &setlocal &set "td=%date:/=-%"
md "..\%td:~0,10%" 2>nul
(for /f "tokens=3* delims= " %%a in ('dir /tc/o-d^|findstr /bc:"%td:~0,10% " ') do if "%%b" neq "." if "%%b" neq ".." if /i "%%b" neq "%~nx0" move /y "%%b" "..\%td:~0,10%\") 2>nul
endlocal&pause&exit/b
复制代码

onging

回复 8# aloha20200628
依然不起作用
我的是win7系统，日期应该是默认的，上传图片失败呢？

ppll2030

回复 9# onging


    哈哈，大佬今天可能有点晕。

你试试把第三行前半部分的个地方改一下试试。

/bc:"%td:~0,10% " 改为 /bc:"%date:~0,10% "

flashercs

回复 9# onging
上传图片可用图床: http://bbs.bathome.net/thread-60985-1-1.html
系统日期格式

dir日期格式

77七

@echo off
cd /d "%~dp0"
for /f %%a in ('wmic os get localdatetime ^| findstr [0-9]') do (
	set d=%%a
)
for /f "tokens=1-3*" %%a in ('dir /tc ^| findstr /rive /c:"\." /c:"\.bat" /c:"\.cmd"') do (
	if "%%a" equ "%d:~0,4%/%d:~4,2%/%d:~6,2%" (
		if "%%d" neq "%d:~0,4%-%d:~4,2%-%d:~6,2%" (
			if exist "%%d\" (
				robocopy "%%d" "%d:~0,4%-%d:~4,2%-%d:~6,2%/%%d" /e /move
			) else (
				robocopy . "%d:~0,4%-%d:~4,2%-%d:~6,2%" "%%d" /mov
			)
		)
	)
)
pause
复制代码

Batcher

回复 9# onging


如果需要上传文件，请用使用网盘。

如果需要上传截图，可以找个图床，例如：
http://bbs.bathome.net/thread-60985-1-1.html

aloha20200628

回复 9# onging

谢谢10,11楼提醒
若楼主 dir 列表显示的时间格式如11楼所示 2024/09/06 周五 .... 则8楼代码须订正如下，其实就是多了一个 ‘周五’ 的字段

@echo off &setlocal &set "td=%date:/=-%"
md "..\%td:~0,10%" 2>nul
(for /f "tokens=4* delims= " %%a in ('dir /tc/o-d^|findstr /bc:"%date:~0,10% " ') do if "%%b" neq "." if "%%b" neq ".." if /i "%%b" neq "%~nx0" move /y "%%b" "..\%td:~0,10%\") 2>nul
endlocal&pause&exit/b
复制代码

aloha20200628

为批处应对此类题型留下前车之鉴》
   取值 %date% 须截取 %date:~0,10%，
   用其创建目录前须置换其中分隔符 %date:/=-%，
   提取 dir 全量列表后几项数据前须检测其中时间字段的个数...
以下代码是对3，8，14楼代码的完整修复... 运行结果会将 ‘d:\目标文件夹’ 中当日创建生成的目录和文件移至 ‘d:\目的地文件夹\20240907’ 目录中...

@echo off &setlocal &set "td=%date:/=-%"
cd /d "d:\目标文件夹" &set "td=d:\目的地文件夹\%td:~0,10%"
md "%td%" 2>nul &set "tf=%td%\all.tmp"
dir /tc/o-d|findstr /bc:"%date:~0,10% ">"%tf%" &set/p s=<"%tf%" 
if "%s:~14,1%"==":" (set "q=3") else (set "q=4")
(for /f "tokens=%q%* delims= " %%a in (%tf%) do if "%%b" neq "." if "%%b" neq ".." if /i "%%b" neq "%~nx0" move /y "%%b" "%td%\")>nul 2>nul
del /q "%tf%"&endlocal&pause&exit/b
复制代码