[文本处理] [已解决]求解释：批处理中的 call set 语句

garyv

call set var2=%%!var1!:~0,1%%

为什么这条set语句可以被call？是什么含义，会进入什么地方定义的function呢？

林小七

call...？？？set被call？？？你去看看变量延迟吧....

@echo off
set a=10&&@echo a=%a%
@echo a=%a%
set b=20&&call echo b=%%b%%
复制代码

看看结果？？懂了没？？

林小七

@echo off
setlocal EnableDelayedExpansion
set d=100&&echo d=%d%
set c=100&&echo c=!c!
复制代码

这个和call的效果一样.....开启setlocal EnableDelayedExpansion
.

garyv

回复 3# 林小七


    看了几个关于 setlocal enabledelayedexpansion 的链接，但是都没有讲解"call set xxx"例子，还是不明白 call set。。。

这位高手能否提供一个合适的链接或文档？

CrLf

http://bbs.bathome.net/viewthread.php?tid=3231

林小七

回复 4# garyv


    楼上给了哦...如果你系统的看bathome的教程会有这个 的..不要心急哦

garyv

回复 6# 林小七


    你的例子我是看明白了，但是下面从网上找到的大小写转换的代码没弄明白：

echo off
setlocal enabledelayedexpansion

set str=aA bB cC dD eE fF gG hH iI jJ kK lL mM nN oO pP qQ rR sS tT uU vV wW xX yY zZ
for %%i in (%str%) do set "var=%%i" & set !var:~0,1!=%%i

set "TS="
set /P TS=请输入测试字符：
for /l %%i in (0 1 100) do (
        set "T3=!TS:~%%i,1!"
        if "!T3!"=="" goto :Res
        if defined !T3! (
                call set T2=%%!T3!:~0,1%%
                if "!T3!"=="!T2!" call set T2=%%!T3!:~1,1%%) else set "T2=!T3!"
        set Res=!Res!!T2!
)
:Res
echo.&echo 转换前：!TS!
echo 转换后：!Res!
复制代码

疑问：
1）如果没有"setlocal enabledelayedexpansion"语句下面的set...和for...那2行，运行结果是不对的，有这2行就是正确的！
2）这2行语句中"!var:~0,1!=%%i"，不知什么含义，难道是：取出var中的第一个字符然后被%%i赋值？一个常量怎么被赋值呢？

garyv

请高手帮我看看

Python

回复 7# garyv

难道是：取出var中的第一个字符然后被%%i赋值？一个常量怎么被赋值呢？

它就是一个普通的字母而已，为什么说它是常量呢？

Python

回复 7# garyv

如果没有"setlocal enabledelayedexpansion"语句下面的set...和for...那2行，运行结果是不对的，有这2行就是正确的！

就是变量延迟的两种不同方法而已

@echo off
REM Method 1
set str=aA
for %%i in (%str%) do (
    set "var=%%i"
    call set %%var:~0,1%%=%%i
    call echo %%a%%
)

REM Method 2
setlocal enabledelayedexpansion
set str=aA
for %%i in (%str%) do (
    set "var=%%i"
    set !var:~0,1!=%%i
    echo !a!
)
复制代码

garyv

回复 9# Python


    从C的角度分析，左边取出的字符没有显式地保存到一个变量中，这种左值是不能被赋值的，难道是替换？

Python

回复 11# garyv


    这是BAT，不能从C的角度去分析。

garyv

回复 10# Python


    这2种方法打印出来都是 aA，没有进行大小写转换，还有那条echo后面的变量%a%是从哪里来的呢？

顺便解释一下我贴上去的大小写转换代码，谢谢。

Python

回复 13# garyv


10楼的代码是给你演示两种不同的变量延迟扩展，不是为了大小写转换。
你希望解释代码里面的哪个部分？

林小七

请问具体哪里不明白呢？？？