[文件操作] 【已解决】批处理如何获取当前目录下包含关键词内的文件，并复制出来？

zhengzhenhui

如当前目录   
文件夹结构     文件夹1/三班/图片文件/需要复制的文件
                     文件夹1/四班/图片文件/需要复制的文件

结果   三班/复制的文件
        四班/复制的文件


每个班级文件夹里面都有一个叫图片文件的文件夹
把里面的文件复制出来，沿用班级名的文件夹【目录排序是固定的】班级会在二级目录

麻烦大佬出手帮忙

aloha20200628

回复 4# zhengzhenhui

根据网盘提供的示例目录结构，订正3楼代码如下，存于 ‘XXXX学校’ 目录下运行...
先锚定 ‘XXXX学校’ 目录下的每一个班级子目录，再从中获取其下的关键词子目录并将其中的全部文件复制到当前的班级子目录中...

@echo off &for /f "delims=" %%D in ('dir /b/ad "*班*" ') do for /f "delims=" %%d in ('dir /b/s/ad "%%D\*关键词*" ') do copy /y "%%d\*.*" "%%D\"
pause&exit/b
复制代码

zhengzhenhui

回复 8# smss


    谢谢你了

smss

@echo off&setlocal enabledelayedexpansion
rem 设置源目录、目标目录和关键词(按实际情况设置)
set "source=D:\学校"
set "target=D:\结果"
set "keyword=关键词"

if exist "%target%" rd/s/q "%target%" >nul
rem 遍历每个班级目录（二级目录）
for /d %%a in ("%source%\*")do (set "class=%%~nxa" 
    if not exist "%target%\!class!\" md "%target%\!class!"
    rem 查找班级目录下所有包含关键词的子目录
    for /f "delims=" %%b in ('dir /s/b/ad "%%a\*" ^|findstr /i /r "\\%keyword%$"')do (pushd "%%b"
        rem 递归遍历子目录中的文件
        for /r %%c in (*)do (set "dest=%target%\!class!\%%~nxc"
            if exist "!dest!" set n=1&set "nc=%%~nc"&set "xc=%%~xc"&call :check
            echo 复制 [%%c] 到 [!dest!]
            copy "%%c" "!dest!" >nul
        )
        popd
    )
)
endlocal

echo 文件复制完成！
echo 按任意键退出！
pause >nul&exit/b
:check
:: 如果有同名文件 则以原名(1)递增数字命名
set "dest=%target%\!class!\!nc!(!n!)!xc!"
if exist "!dest!" set/a n+=1&goto check 
exit/b
复制代码

zhengzhenhui

回复 6# smss


    不好意思。我给您发个测试包，这样直观一些https://zhenghui.lanzouu.com/iLG4V2pgy80b  复制出来的结果是放在批处理那边的  ，就是每个班级都有这个关键词的文件夹不会重复，就是放的目录层级不同

smss

回复  smss



    谢谢您， 但是文件夹如果在底下子文件夹，就会移动或者复制图片失败


结构  文 ...
zhengzhenhui 发表于 2025-3-3 19:44

你是想移动到上一级 还是想把所有子目录下文件也移动到固定的三班 四班（相对脚本来说二级目录）
表述清楚能让问题迅速彻底解决，亏你还当老师呢 真替学生 家长 校长 堪忧

zhengzhenhui

回复 2# smss



    谢谢您， 但是文件夹如果在底下子文件夹，就会移动或者复制图片失败


结构  文件夹1/三班/文件***/***/需要复制的文件
        文件夹1/四班/文件***/需要复制的文件


结果          三班/复制的文件
                四班/复制的文件

zhengzhenhui

回复 3# aloha20200628


    抱歉，可能是我没表达清楚

结构  文件夹1/三班/文件***/需要复制的文件
        文件夹1/四班/文件***/需要复制的文件


结果          三班/复制的文件
                四班/复制的文件
就是文件放在当前目录中，复制的文件沿用/b /s就是三班 这个文件夹名
但是会出现好几个三班，所以还得避免重复，谢谢您了

aloha20200628

回复 1# zhengzhenhui

以下代码存为 test.bat 放在 ‘文件夹1’ 目录中运行...

@echo off &for /f "delims=" %%d in ('dir /b/s/ad "图片文件" ') do copy /y "%%d\*.*" "%%~dpd">nul
pause&exit/b
复制代码

smss

@echo off&setlocal enabledelayedexpansion
set 关键字=图片文件
for /f "delims=" %%F in ('dir /s/b "*%关键字%"')do (
    set "D=%%~dpF."
    robocopy "%%F" "!D!" /mov /e /njh /njs /nc /ns /np /r:1 /w:1 >nul
    REM /mov 移动后自动删除源文件
    REM /e 包含空子目录
    REM /njh /njs /nc /ns /np 静默模式提升执行速度
    REM /r:1 /w:1 失败操作自动重试
    if !errorlevel!==8 (echo [!] %%F 移动失败
    ) else (echo [√] %%F 移动成功
    rd/s/q "%%F" 2>nul && echo [√] 删除空目录%%F成功
    )
)
pause
复制代码

移动三级目录中的文件至上级目录 例如 D:\二年级\三班\图片文件\新建文本文档.txt—>D:\二年级\三班\新建文本文档.txt