[文件操作] 移动当天文件夹和文件到当天日期文件夹的bat代码怎么写？

onging

当天日期文件夹也想要通过bat生成，谢谢大佬们！

aloha20200628

回复 32# qixiaobin0715

一枚手误  阁下真是细心
29楼代码已订正

qixiaobin0715

回复 29# aloha20200628
%td%是经过第2行处理得到的，所以不可能含有空格，那么%td:~8,1%的值也永远不可能是空格，应当是"%date:~8,1%"==" "吧，或者是"%td:~8%"==""。

aloha20200628

29楼代码第三行是为兼容系统日期变量 %date% 和 %%~tF 被取值 yyyy*mm*dd 或 yy*mm*dd 两种实况，以便后续的字符串截取偏移量能自适应10位或8位日期值，其实29楼代码还可更简化一步，用 for/f 分割器一气呵成（确保%date%与%%~tF的日期取值方法相同），同时也省略了循环体内的延迟变量... 代码如下

@echo off &setlocal
for /f "tokens=1 delims= " %%a in ("%date%") do set "td=%%a"
cd /d "d:\目标文件夹" &set "dt=d:\目的地文件夹\%td:/=-%"
md "%dt%" 2>nul
for /f "delims=" %%F in ('dir /b/tw/o-d') do if "%%~fF" neq "%~f0" (
    for /f "tokens=1 delims= " %%t in ("%%~tF") do if "%td%"=="%%t" (
        move /y "%%F" "%dt%\") else pause&exit/b
)
pause&exit/b
复制代码

qixiaobin0715

没看明白第3行是啥意思，好像最终都是else成立。


既然日期字符数有差异，那么就都取8位是否更直接，就不用什么if再else了。


大概看了看，修改时间日期格式后，%date%和文件中（%~tI）的格式同步变化，并无不同，所以不用考虑格式问题，该如何就如何。

aloha20200628

     进一步验证》系统日期的格式设置确实有很多种，其设置结果基本与资源管理器的日期显示格式一致，但与%date%, %%~tF和dir列表的日期取值格式不一定相同，无论系统日期格式如何调整，后三者除了分隔符与其保持一致之外，日期值净长度总是在8位(如24-01-31)或10位(如2024-01-31)取值，而资源管理器的日期显示格式可在6-10位之间变化，因此%date%的更稳妥取值方法是用 for /f "tokens=1 delims= " %%a in ("%date%") do set "td=%%a"
     以下代码是将15楼代码重写成不调用findstr筛选当日数据的版本，直接用dir/b/tw/o-d排序，令当日数据置顶，从而能对其首先处理并及时结束退出，也免去了采用findstr须检测时间字段个数等关联处理问题...

@echo off &setlocal
for /f "tokens=1 delims= " %%a in ("%date%") do set "td=%%a"
if "%td:~8,1%"=="" (set "e=tt:~0,8") else set "e=tt:~0,10"
cd /d "d:\目标文件夹" &set "dt=d:\目的地文件夹\%td:/=-%"
md "%dt%" 2>nul
for /f "delims=" %%F in ('dir /b/tw/o-d') do if "%%~fF" neq "%~f0" (
	setlocal enabledelayedexpansion &set "tt=%%~tF" &set "tt=!%e%!"
	if "%td%"=="!tt!" (endlocal & move /y "%%F" "%dt%\") else endlocal&pause&exit/b
)
endlocal&pause&exit/b
复制代码

77七

多谢11楼、27楼两位大佬提醒
重新写了一个，尽量排除 不同系统或者个性化设置导致的日期时间格式不同影响。

@echo off
cd /d "%~dp0"
for /f %%a in ('wmic os get localdatetime ^| findstr [0-9]') do (
	set d=%%a
)
set d=%d:~0,4%-%d:~4,2%-%d:~6,2%
cd.>d.d
for /f "tokens=1*" %%i in ('dir /tc "d.d" ^| findstr "d\.d$"') do (
	for %%a in (%%j) do (
		set /a n+=1
	)
	set _d=%%i
)
del d.d
for /f "tokens=%n%*" %%a in ('dir /tc ^| findstr "^%_d%" ^| findstr /iv "\.$ \.cmd$ \.bat$ [0-9][0-9][0-9][0-9]-[0-9][0-9]-[0-9][0-9]$"') do (
	if exist "%%b\" (
		robocopy "%%b" "%d%\%%b" /e /move
	) else (
		robocopy . "%d%" "%%b" /mov
	)
)
pause
复制代码

qixiaobin0715

需要什么格式可以再系统里自己设置：

onging

回复 25# aloha20200628
谢谢！，也一样可以了

aloha20200628

回复 24# onging

老美用的英文版有可能采用 08/31/2024 这类时间格式，可先用小样本数据试一下代码看看结果...

onging

回复 23# aloha20200628
谢谢！还想问一下，英文系统和中文系统都会通用的吗？主要是时间格式

aloha20200628

回复 22# onging

代码最后一行改为》 del /q "%tf%"&endlocal&exit/b  即可

onging

回复  onging

在已被订正的15楼代码第二行》
   d:\目标文件夹  可改为你要移动当日数据的文件夹名（须 ...
aloha20200628 发表于 2024-9-7 18:53

谢谢！这个更完美，但还想取消“请按任意键继续”的弹窗，应该删除那一段呢？

aloha20200628

回复 20# onging

在已被订正的15楼代码第二行》
   d:\目标文件夹  可改为你要移动当日数据的文件夹名（须是全路径，例如 d:\abc\1）
   d:\目的地文件夹  可改为被移动数据的目的地文件夹名（须是全路径，例如 d:\xyz\1），在此文件夹下将生成名如 ‘2024-09-07’ 的当日文件夹

onging

回复  onging

是要指定一个已有的 ‘目的地’ 文件夹？还是要新建一个自定义名称的 ‘目的地’ 文件夹？ ...
aloha20200628 发表于 2024-9-7 16:33

谢谢！这段代码在那里更改“要移动的当天文件夹和文件的目录”和“当天日期文件夹的目录”呢，不好意思，菜鸟一枚！