[文本处理] 批处理如何批量提取文本里百度网盘链接？

qlit

如何批量提取文本里百度网盘链接  
当前文件夹内N个这样的文本，内容基本都是这样格式的

例子：
链接：https://pan.baidu.com/s/130Ah3RkSzRSJxF50TQh3ZA
提取码：cd1u
--来自百度网盘超级会员V8的分享

如何将这1千多个文本内这样的链接和提取码 保存到一个新文本里呢？
最好保存格式为一行一个
提取后保存后的格式为：
链接：https://pan.baidu.com/s/130Ah3RkSzRSJxF50TQh3ZA 提取码：cd1u



PS：我知道怎么写提取一行关键字到新文本，这个属实不会，请大佬教一下。。

ShowCode

回复 4# qlit


可以考虑直接生成这种格式：
https://pan.baidu.com/s/130Ah3RkSzRSJxF50TQh3ZA?pwd=cd1u
可以直接打开，不需要再手工输入提取码。

qlit

回复 3# ShowCode


    多谢已解决！！！

ShowCode

回复 1# qlit


V2.bat

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "OldFile=1.txt"
set "NewFile=2.txt"
(for /f "delims=" %%i in ('type "%OldFile%"') do (
    set "ThisRow=%%i"
    if "!ThisRow:链接=!" neq "!ThisRow!" (
        set /p =!ThisRow! <nul
    ) else if "!ThisRow:提取码=!" neq "!ThisRow!" (
        echo,!ThisRow!
    )
))> "%NewFile%"
复制代码

ShowCode

回复 1# qlit


V1.bat

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "OldFile=1.txt"
set "NewFile=2.txt"
type nul > "%NewFile%"
for /f "delims=" %%i in ('type "%OldFile%"') do (
    set "ThisRow=%%i"
    if "!ThisRow:链接=!" neq "!ThisRow!" (
        set /p =!ThisRow! <nul
        >> "%NewFile%" set /p =!ThisRow! <nul
    ) else if "!ThisRow:提取码=!" neq "!ThisRow!" (
        echo,!ThisRow!
        >> "%NewFile%" echo,!ThisRow!
    )
)
复制代码