[文本处理] 批处理如何检测srt每行字数，超出设定字数换行？

小白来了

大佬们好，想批量检测多个srt文件每行的字数，超出30个字加空格或者换行

不检测时间码，只检测每一行的字数~

两个文件如下

链接：https://pan.baidu.com/s/1-xmRDW2-5L3JQB6YBOtsvg?pwd=0ydb

77七

回复 24# 小白来了


   19行下面添加一行

        move "%%~ni_2%%~xi" "%%i"
复制代码

小白来了

回复 20# 77七


    大哥，这段代码改成覆盖原文件，应该怎样修改呢？我自己修改的操作完成空白文件了。求您指教~谢谢！

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /a-d *.srt') do (
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		if "%%b" equ "" (
			echo=
		) else (
			set "str=%%b"
			setlocal enabledelayedexpansion
			set "_str=!str:~0,1!"
			if !_str! gtr Z (
				call :1
			) else (
				echo !str!
			)
			endlocal
		)
	))>"%%~ni_2%%~xi"
)
pause & exit

	:1
	echo !str:~0,30!
	set "_str=!str:~30!"
	if "!_str!" neq "" (
		set "str=!_str!"
		goto :1
	) else (
		exit /b
	)
复制代码

terse

powershell

<# :
@echo off 
powershell -noprofile -NoLogo "iex (${%~f0} | out-string)"
pause
exit 
#>
$re = "^\d{2}:\d{2}:\d{2},\d{3} --> \d{2}:\d{2}:\d{2},\d{3}$"
$n = 30
[IO.Directory]::EnumerateFiles($pwd, "*.srt")|%{ [IO.File]::WriteAllLines("$_._new.txt",([IO.File]::ReadAllLines($_)|%{if($_ -match $re){$_ }else{$_ -split "(?<=\G.{$n})(?=.)"}}),[Text.Encoding]::UTF8)}
复制代码

qixiaobin0715

感谢14楼指出代码错误。下面代码最多可进行2次换行，即适合一行不超过90个字符，原字幕文件空行保留：

@echo off
chcp 65001>nul
for /f "delims=" %%i in ('dir /b /a-d *.srt') do (
    (for /f "delims=" %%j in ('type "%%i"') do (
        set "str=%%j"
        setlocal enabledelayedexpansion
        set /a t=str
        if !t! equ !str! (
            echo,%%j
        ) else if not "!str:-->=!"=="!str!" (
            echo,%%j
        ) else (
            if not "!str:~30!"=="" (
                echo,!str:~,30!
                set str=!str:~30!
                if not "!str:~30!"=="" (
                    echo,!str:~,30!
                    echo,!str:~30!
                    echo,
                ) else (
                    echo,!str!
                    echo,
                )
            ) else (
                echo,%%j
                echo,
            )
        )
        endlocal
    ))>"New-%%i"
)
复制代码

小白来了

回复 20# 77七


    成功了，大佬威武霸气！感谢您的专业帮助~祝您财源广进~一起顺利！！

77七

回复 19# 小白来了


  

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /a-d *.srt') do (
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		if "%%b" equ "" (
			echo=
		) else (
			set "str=%%b"
			setlocal enabledelayedexpansion
			set "_str=!str:~0,1!"
			if !_str! gtr Z (
				call :1
			) else (
				echo !str!
			)
			endlocal
		)
	))>"%%~ni_2%%~xi"
)
pause & exit

	:1
	echo !str:~0,30!
	set "_str=!str:~30!"
	if "!_str!" neq "" (
		set "str=!_str!"
		goto :1
	) else (
		exit /b
	)
复制代码

小白来了

回复 16# 77七


大佬好，感谢您！还有一点小问题~

如果时间码超过字数的话 也会跟着换行。能否只检测文字，不检测数字时间码呢？

时间码格式：00:09:30,401 --> 00:09:30,971

小白来了

回复 15# Five66


    感谢大佬！谢谢

小白来了

回复 14# buyiyang


    厉害了我的哥！技术专业！谢谢谢谢！

77七

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /a-d *.srt') do (
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		if "%%b" equ "" (
			echo=
		) else (
			set "str=%%b"
			setlocal enabledelayedexpansion
			call :1
			endlocal
		)
	))>"%%~ni_2%%~xi"
)
pause & exit

	:1
	echo !str:~0,30!
	set "_str=!str:~30!"
	if "!_str!" neq "" (
		set "str=!_str!"
		goto :1
	) else (
		exit /b
	)
复制代码

Five66

试试下面的看看吧，没有百度账号，下不了网盘文件
srt编码gbk或ansi，srt文件名不要以new_开头（因为会生成以new_开头的新的srt文件）

@echo off&chcp 936

set changdu=30

for %%a in (*.srt) do (
cd.>"new_%%~na.newnew"
set "newfile=new_%%~na.newnew"
for /f "delims=" %%b in ('findstr /n .* "%%a"') do (
set line=%%b
setlocal enabledelayedexpansion
set line=!line:*:=!
if not defined line (
rem echo,>>"!newfile!" 
echo,>>"!newfile!"
) else if "!line:~%changdu%!" == "" (
rem echo,!line:*:=!>>"!newfile!"
echo,!line!>>"!newfile!"
) else (
set n=0
set /a m=%changdu%
rem set line=!line:*:=!
call :aaa
)
endlocal
)
)
rename *.newnew *.srt
del *.newnew 2>nul
echo done&pause&exit/b

:aaa
echo,!line:~%n%,%changdu%!>>"!newfile!"
set /a n+=%changdu%
set /a m+=%changdu%
if "!line:~%m%!" neq "" (goto :aaa) else (
if "!line:~%n%!" neq "" echo,!line:~%n%!>>"!newfile!"
)
复制代码

buyiyang

回复 13# 小白来了


    9楼代码第四行

    (for /f "delims=" %%j in ('type "%%i"') do (
复制代码

小白来了

回复 12# Batcher


    UTF-8也是生成的空白文件。是因为srt文件格式吗

Batcher

回复 10# 小白来了


请参考Q-04把9楼.bat文件保存为UTF-8编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA