[文本处理] 【已解决】请帮忙给txt增加空白行的bat脚本

kokoxx

RT，这个bat脚本的作用是

将bat脚本同一个文件夹下的*.txt打开

检测到txt内容中有一个文本行的开头是“第 xxx 章”（xx是阿拉伯数字，允许xxx前后有若干空格，或没有空格），则在该文本行之前和之后添加三个空白文本行

举例：

【原版】

我是谁啊啊啊
第 1 章 奥特曼
谁说的啊啊啊

【修改版】

我是谁啊啊啊



第 1 章 奥特曼



谁说的啊啊啊

kokoxx

回复 32# 77七


    大佬您好，您之前写过一个脚本，用于删除txt包含特定文本（比如“标签”）的文本行附近的文本行

@echo off
chcp 65001 >nul
for /f "useback delims=" %%i in (`dir /b /a-d *.txt`) do (
	setlocal
            for /f "useback tokens=1* delims=[]" %%a in (`find /n "标签" ^<"%%i"`) do (
		for %%x in ( 0 ) do (
			set /a n=%%a+%%x
			call set _"%%n%%"=1
		)
	)
	(for /f "useback tokens=1* delims=[]" %%a in (`find /n /v "" ^<"%%i"`) do (
		if not defined _"%%a" (
			echo=%%b
		)
	))>$
	move $ "%%i"
	endlocal
)
pause
复制代码

现在想用类似的bat写法实现

【处理前】

=== 第1章奥特曼

【处理后】

=== 第1章 奥特曼

（案例结束）

也就是将符合标准的文本行（关键词是“=== 第”）中的“章”变成“章 ”

该怎么修改？

77七

回复 30# kokoxx


  

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
cd /d "%~dp0"
set /a x=3,y=2
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
	setlocal
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		if "%%b" equ "" (
			set /a n+=1
		) else if defined n (
			set /a m=n/x*y+n%%x
			set n=
			setlocal enabledelayedexpansion
			for /l %%l in (1,1,!m!) do (
				echo=
			)
			endlocal
			echo=%%b
		) else (
			echo=%%b
		)
	))>$
	move $ "%%i"
	endlocal
)
pause
复制代码

hfxiang

回复 30# kokoxx

可试一下sed（ http://bcn.bathome.net/tool/4.9/sed.exe ）

假定 x=3，y=2

sed -z -r  "s/^\n{3}\b/\n\n/;s/\b\n{4}\b/\n\n\n/g" 1.txt>2.txt
复制代码

假定 x=3~10，y=2

sed -z -r  "s/^\n{3,10}\b/\n\n/;s/\b\n{4,11}\b/\n\n\n/g" 1.txt>2.txt
复制代码

kokoxx

回复 11# 77七


    大佬，抱歉又来叨扰您了

您能不能出手写一个bat，实现将bat同文件夹下的txt里的x个连续空白文本行替换成y个空白行（用wps或word的话，如果txt很大（超过4m），程序就会卡死T-T）

这里假定x=3，y=2

【处理前】

我是谁



我是谁

我是谁

【处理后】

我是谁


我是谁

我是谁

77七

回复 28# kokoxx


  

	(for /f "useback tokens=1* delims=[]" %%a in (`find /n /v "" ^<"%%i"`) do (
		if not defined _"%%a" (
			echo=%%b
		)
	))>$
复制代码

12-18行改为上面的，即去掉else (echo=)

kokoxx

回复 17# 77七


    大佬您好，时隔多日后，再度叨扰您

如果这里要求是将符合指定关键字条件（“猜你喜欢:”和“更多推荐”）的所在行直接删除，而不是将之变成一个空白行，将如何修改第14行的“echo=%%b”？

qixiaobin0715

回复 8# kokoxx

@echo off
chcp 65001>nul
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    (for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%%i"') do (
        if "%%b"=="" (
            echo,
        ) else (
            for /f "tokens=1,2* delims=0123456789 " %%j in ("%%b") do (
                if "%%j%%k"=="第章" (
                    if "%%l"=="此行不做添加空行处理" (
                        echo,%%b
                    ) else (
                        echo,
                        echo,
                        echo,
                        echo,%%b
                        echo,
                        echo,
                        echo,
                    )
                ) else (
                    echo,%%b
                )
            )
        )
    ))>temp
move "temp" "%%i"
)
pause
复制代码

qixiaobin0715

回复 18# kokoxx

@echo off
chcp 65001>nul
set /a _"猜你喜欢"=_"更多推荐"=1
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    (for /f "tokens=1,2* delims=：:" %%a in ('findstr /n .* "%%i"') do (
        if defined _"%%b" (
            echo,
        ) else (
            if "%%c"=="" (
                echo,%%b
            ) else (
                echo,%%b：%%c
            )
        )
    ))>temp
move "temp" "%%i"
)
pause
复制代码

qixiaobin0715

回复 22# kokoxx
行数过多的话可以这样写比较简洁一些：

for /l %%i in (-4,1,2) do (...
复制代码

qixiaobin0715

回复 20# kokoxx
使用变量迭代法不知是否可行。这样可以防止定义变量太多而引起的效率不高的问题：

@echo off
chcp 65001>nul
for /f "delims=" %%I in ('dir /b /a-d *.txt') do (
    setlocal enabledelayedexpansion
    set n=1
    (for /f "tokens=1* delims=:" %%i in ('findstr /n .* "%%I"') do (
        set /a n+=1
        set s1=!s2!
        set s2=!s3!
        set s3=%%j
        if defined s3 (
            set s=!s3:.html=!
            if not "!s!"=="!s3!" (
                set n=0
                echo,
            )
        )
        if !n! geq 4 echo,!s1!
    )
    if !n! geq 3 (
        echo,!s2!
        echo,!s3!
    ) else if !n! equ 2 (
        echo,!s3!
    ))>temp
    move "temp" "%%I"
    endlocal
)
pause
复制代码

代码未经测试，可能有问题，思路应当是对的。

77七

回复 22# kokoxx


   对的，7行缩成一行空白

kokoxx

回复 21# 77七


    感谢大佬，测试通过

提问：如果我要实现在.html所在文本行上数4行，下数2行都做成空白行

就是将

for %%x in (-2 -1 0 1) do (

改成

for %%x in (-4 -3 -2 -1 0 1 2) do (

对吧？

77七

回复 20# kokoxx


  

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "useback delims=" %%i in (`dir /b /a-d *.txt`) do (
	setlocal
	for /f "useback tokens=1* delims=[]" %%a in (`find /n ".html" ^<"%%i"`) do (
		for %%x in (-2 -1 0 1) do (
			set /a n=%%a+%%x
			call set _"%%n%%"=1
		)
	)
	(for /f "useback tokens=1* delims=[]" %%a in (`find /n /v "" ^<"%%i"`) do (
		if not defined _"%%a" (
			if defined m (
				echo=
				set m=
			)
			echo=%%b
		) else (
			set m=1
		)
	))>$
	move $ "%%i"
	endlocal
)
pause
复制代码

kokoxx

回复 19# 77七


    大佬，我又双叒叕要叨扰您了～

还是处理txt文本，希望能实现如下功能：

查找定位bat同文件夹下*.txt中所有带.html的文本行

将该文本行连同该文本行上面的两个文本行和下面的一行文本行，替换成一个文本行

举例

【原版】

1我是是是是www啊啊
2www啊啊
3呜呜呜呜谁反对
4奥术大师多
5 1212.html 我说的
6阿勒泰堵塞
7阿萨德
8大额ad


【修改后版】

1我是是是是www啊啊
2www啊啊

7阿萨德
8大额ad

--------

测试样本

https://www.123pan.com/s/pbxrVv-lOAY.html