[文本处理] 【已解决】求精简带有BOM的UFT-8文本的批处理

hfstar

要求：保留 {$CP936=    {$CP936=                    {$CP0=
                   ............       .................                   ...............        
                              $}                       $}                               $}
  各位大佬，请帮忙看看能不能实现
  因无法上传附件，只能使用123网盘上传修改内容，请见谅！
   https://www.123pan.com/s/UQLA-Tp0eh.html

hfstar

回复 20# buyiyang


    搞定了，多谢大佬的指点。

buyiyang

回复 18# hfstar


    你的%YB%和%TH%中的^$符号需要\转义

77七

回复 17# buyiyang


   谢谢大佬指点！这样用bat生成 utf-8 带bom方便多了。

hfstar

回复 17# buyiyang


   刚刚写的，替换不成功，能否指点一下问题出在哪？
@echo off & cd/d "%~dp0"

chcp 65001

set YB='{$CP949^=간단 팝업 메뉴$}'
set TH='{$CP936^=简易弹出菜单$}{$CP950^=簡易彈出選單$}'
powershell -c "(Get-Content SimpleMenu.xml -encoding utf8 ) -Replace %YB%,%TH%" > SimpleMenu测试.xml



pause>nul & exit

buyiyang

回复 11# 77七


    批处理可以这样产生bom头

>bom echo(77u/
certutil -decode -f bom 2.txt
复制代码

还可以这样，参考：http://www.bathome.net/viewthread.php?tid=12347&rpid=79254&ordertype=0&page=1#pid79254

@ECHO off&setlocal EnableDelayedExpansion
Set gbk=可去便
chcp 437>nul
for /f %%a in ('cmd/u/cecho !gbk!')do set utf=%%a
Set head=!utf:~0,1!!utf:~2,1!!utf:~4,1!
set/p=!head!<nul>2.txt
复制代码

hfstar

回复 15# 77七


    没事没事

77七

回复 12# hfstar


   
ps我不懂，bat也不太好替换等号。

hfstar

回复 13# qixiaobin0715


    好的

qixiaobin0715

如果需要保留的不同字段类型较多，这样要简洁些：

@echo off
chcp 65001
set var="{$CP936=" "{$CP950=" "{$CP0="
(for /f "tokens=1* delims=]" %%i in ('find /v /n "" License.txt') do (
    if defined n (
        echo,%%j
        if "%%j"=="$}" set n=
    ) else (
        for %%k in (%var%) do (
            if "%%j"==%%k (
                set n=0
                echo,%%j
            )
        )
    )
))>"License_精简.txt"
pause
复制代码

又修改了下，这样总的判断频次要少一些。

hfstar

回复 11# 77七


    学习了，
假如，我要用批处理调用 powershell 把 xml 文件中的 {$CP949=간단 팝업 메뉴$} 替换为 {$CP936=简易弹出菜单$}{$CP950=簡易彈出選單$} ，那该怎么做呢？

77七

找了个创建utf-8 带bom文件的ps代码，模仿大佬用混编写到一起

<# :
cls&echo off&cd /d "%~dp0"&chcp 65001 >nul&set "current=%cd%"
path %SYSTEMROOT%\System32\WindowsPowerShell\v1.0;%path%
powershell -NoProfile -ExecutionPolicy bypass "Get-Content -literal \"%~f0\"|Out-String|Invoke-Expression"
set "file=1.txt"
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%file%"') do (
	if "%%b" equ "{$CP936=" (
		set m=1
	) else if "%%b" equ "{$CP950=" (
		set m=1
	) else if "%%b" equ "{$CP0=" (
		set m=1
	) else if "%%b" equ "$}" (
		if defined m (
			echo %%b
		)
		set m=
	)
	if defined m (
		echo=%%b
	)
))>>2.txt
echo;done
pause
exit
#>
$filePath = "2.txt"

# 创建文件并写入BOM
$fileStream = [System.IO.File]::Create($filePath)
$bom = New-Object byte[] 3
$bom[0] = 0xEF
$bom[1] = 0xBB
$bom[2] = 0xBF
$fileStream.Write($bom, 0, 3)
$fileStream.Close()
复制代码

hfstar

刚刚测试了一下，各位大佬的脚本都能完美实现，多谢你们的帮忙

hfstar

回复 7# Batcher


    这个可以了，

77七

回复 6# qixiaobin0715


   谢谢大佬指点！我一直以为只有findstr可以打印行号，以后就首选find了。