[文本处理] 批处理从第一个文件读取每行内容，输出到第二个文件指定字符串后面怎么实现？求救

clayxin

第一个文本内容为用户名文本
a.txt（内容）
zhangsan
lisi
wanger
cuihua
读取a.txt的每行内容输出到另一个文本（b.txt）的文本中input的后面
b.txt(内容)
sdaadw
zxcz
input
sfwa

sdas
dasdas
geww
input
asdasdqqq

asda
rhhre
xoxhn
input
wegwg



我的大概思路是新建一个c.bat,读取a文件的每行并设为变量，再用finstr 找到b文件的input字符串 在后面加a生成的变量名。但今天才学bat不太会代码，求救！！！

clayxin

谢谢大佬们，已经解决了。！！

Nsqs

powershell -noprofile -executionpolicy bypass "(gc b.txt) -replace '(?<=^input)',\"`r`n$(gc a.txt -raw)\"" >c.txt
复制代码

读a.txt与b.txt 最后输出 c.txt

qixiaobin0715

我想楼主的需求应当是这样的：

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
    set /a n+=1
    set _!n!=%%i
)
(for /f "tokens=1* delims=:" %%i in ('findstr /n .* b.txt') do (
    echo,%%j
    if "%%j"=="input" (
        set /a m+=1
        for %%k in (_!m!) do echo,!%%k!
    )
))>c.txt
pause
复制代码

Batcher

回复 1# clayxin


请参考Q-04和Q-05把bat文件和txt文件都保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
cd /d "%~dp0"
set "KeyStr=input"
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "b.txt"') do (
    set "ThisStr=%%b"
    setlocal enabledelayedexpansion
    echo,!ThisStr!
    if "!ThisStr!" equ "%KeyStr%" (
        type "a.txt"
    )
    endlocal
))>"c.txt"
复制代码