[文件操作] BAT脚本FOR遍历，删除文件，怎样排除目录和文件？

7758234

排除C盘下指定目录下所有的PDF DOC XLS文件，进行遍历C盘、D盘、E盘所有PDF、DOC、XLS文件，进行删除处理

Batcher

回复 22# 7758234


    请参考19楼：恢复.bat

7758234

回复 25# 77七

是的，我就是按照这个格式去修改。

    call :1 "e:\1\"
重命名BAT，就有e盘1目录下的文件包括子目录文件
ren "e:\新建 Microsoft Excel 工作表.xls" "新建 Microsoft Excel 工作表.tttt"
ren "e:\1\新建 Microsoft Word 文档.doc" "新建 Microsoft Word 文档.tttt"
ren "e:\1\2\新建 Microsoft Word 文档.doc" "新建 Microsoft Word 文档.tttt"

77七

回复 24# 7758234


  

rem 批处理保存为ansi编码格式。路径末尾以 \ 结束
call :1 "c:\指定目录1\"

请按这两行的要求、格式修改。

7758234

回复 23# 77七


    我添加了排除e:\1 文件夹，命名还是显示有e盘1文件夹下的文件。

77七

@echo off
rem 批处理保存为ansi编码格式。路径末尾以 \ 结束
call :1 "c:\指定目录1\"
call :1 "c:\指定目录2\"
call :1 "c:\指定目录3\"

for %%a in (c d e) do call :2 "%%a:\"
pause & exit

	:1
	set _"%~1"=1
	rem 如果不需要排除子目录删除下一行
	for /r "%~1" /d %%d in (*) do set _"%%d\"=1
	exit /b

	:2
	for /r "%~1" %%i in (*.pdf *.doc *.xls) do (
		if not defined _"%%~dpi" (
			>>"重命名.bat" echo ren "%%i" "%%~ni.tttt"
			>>"恢复.bat" echo ren "%%~dpni.tttt" "%%~nxi"
		)
	)
	exit /b
复制代码

执行后生成两个bat，重命名和恢复

7758234

回复 21# Batcher


    我看了19楼代码了，有点没看懂恢复的处理步骤，改了新命名后，这个批处理怎么去读oldname去恢复

Batcher

回复 20# 7758234


19楼代码已经更新，可以处理同一个文件夹下包含：
测试.doc
测试.pdf
测试.xls
这种情况

恢复的时候，就是要读取csv文件的NewName和OldName进行重命名。直接搜索.ttttt是不好的方法。

7758234

回复 19# Batcher


    站长，但是恢复上就有个问题，文件中存在doc、pdf、xls等文件，批量已命令后缀tttt，恢复应该要读备份CSV进行文件命名才行。单纯通过现有BAT搜索*.tttt命名会有问题。

Batcher

回复 18# 7758234


备份.bat

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder1=C:\Users\Administrator\Desktop\"
set "ExFolder2=C:\Program Files\"
REM 导出的文件列表
set "OutFile=%~dp0备份.csv"
REM 设置新的临时后缀名
set "NewExt=ttttt"
>"%OutFile%" echo OldName,NewName
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder1%" ^| find /v /i "%ExFolder2%" ') do (
            echo 正在查找 %%b
            >>"%OutFile%" echo "%%b","%%b.%NewExt%"
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可重命名文件
            echo ren "%%b","%%~nxb.%NewExt%"
        )
        popd
    )
)
pause
复制代码

恢复.bat

@echo off
set "InFile=%~dp0备份.csv"
for /f skip^=1^ tokens^=3^ delims^=^" %%a in ('type "%InFile%"') do (
    REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可重命名文件
    echo ren "%%a" "%%~na"
)
pause
复制代码

7758234

回复 14# Batcher


    站长其实我们是有个检查，也不想删除这些文件。我有个想法，批量查找出这些文件，把他们命名和后缀输出到xls文件，批处理将他们后缀删除，后续检查过后，恢复他们的后缀格式名，这样也不影响后面的使用。

qixiaobin0715

若指定目录不存在子目录，这样也可。慎用，只是提供一种思路：

@echo off
set "ExFolder1=指定目录1"（完整路径）
set "ExFolder2=指定目录2"（完整路径）
...

ren "%ExFolder1%\*.*" "*.*.1"
ren "%ExFolder1%\*.*" "*.*.1"
...

for %%i in (C D F) do (
if exist %%i:\
for %%j in (pdf doc xls) do (
del /s %%i:\*.%%j
)
)

ren "%ExFolder1%\*.*" "*."
ren "%ExFolder2%\*.*" "*."
...
复制代码

77七

@echo off
rem 批处理保存为ansi编码格式。路径末尾以 \ 结束
call :1 "c:\指定目录1\"
call :1 "c:\指定目录2\"
call :1 "c:\指定目录3\"

for %%a in (c d e) do call :2 "%%a:\"
pause & exit

	:1
	set _"%~1"=1
	rem 如果不需要排除子目录删除下一行
	for /r "%~1" /d %%d in (*) do set _"%%d\"=1
	exit /b

	:2
	for /r "%~1" %%i in (*.pdf *.doc *.xls) do (
		if not defined _"%%~dpi" (
			echo del "%%i"
		)
	)
	exit /b
复制代码

改进下2楼代码。如果子目录数量过多，还是会存在变量个数超限问题。

单个环境的最大变量大小为 8192 字节。所有变量（包括变量名称和等号）的最大环境变量总大小为 65，536KB。

http://bbs.bathome.net/redirect.php?goto=findpost&ptid=29022&pid=145079
windows路径长度限制260字符。
粗略估算，一般应该不会超限，但是如果子目录数量过万，变量过万，批处理存在效率降低问题。

7758234

回复 14# Batcher


    谢谢

Batcher

回复 10# 7758234


方法1.bat

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder1=C:\Users\Administrator\Desktop\"
set "ExFolder2=C:\Program Files\"
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder1%" ^| find /v /i "%ExFolder2%" ') do (
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可删除文件
            echo del /f /q "%%b"
        )
        popd
    )
)
pause
复制代码