[系统相关] 批处理如何把移动硬盘名或者指定U盘名的文件复制到指定目录？

besunny

想说实现一个功能，用作封装系统后继更新软件
运行1.bat
实现功能如下：
1、找到机器上所有盘符里含有sysadmin的（包含本地硬盘，移动硬盘，U盘，存储卡之类的）分区名
2、匹配到后，在名为sysadmin分区下找到soft目录
3、将soft目录复制到本地硬盘，如有D盘
4、复制完后，执行D:\soft\start.bat

besunny

膜拜大神@Bathcer

Batcher

回复 1# besunny


test-2.bat

@echo off
for /f "tokens=2 delims==" %%a in ('wmic LogicalDisk where "VolumeName like '%%SYSADMIN%%'" get DeviceID /value') do (
    for %%b in (%%a) do (
        if exist "%%b\soft" (
            xcopy /e /y "%%b\soft" "D:\soft\"
            start "" "D:\soft\start.bat"
        )
        goto :eof
    )
)
复制代码

Batcher

回复 1# besunny


test-1.bat

@echo off
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        vol %%a: | findstr /i "sysadmin" >nul
        if not errorlevel 1 (
            if exist "%%a:\soft" (
                xcopy /e /y "%%a:\soft" "D:\soft\"
                start "" "D:\soft\start.bat"
            )
            goto :eof
        )
    )
)
复制代码

besunny

回复 2# Batcher


    取第一个就行

Batcher

回复 1# besunny


    如果有多个盘符里含有sysadmin如何处理？