[文件操作] [已解决]批处理如何把多个文件夹下的ts分别合成mp4文件？

lvwenjun11

@

@echo off 
set "p=%cd%"??& cd .. 
call set "p=%%p:%cd%\=%%" 
call set "p=%%p:%cd%=%%" 
cd "%~dp0" 
(for %%a in (*.ts) do @echo file %%a) > Video.txt
ffmpeg -f concat -i "Video.txt" -c copy "%p%.mp4"
del Video.txt
pause
复制代码

如上代码 分别是获取文件夹名 合成ts文件
A文件夹下有 1.ts 2.ts 3.ts
B文件夹下有4.ts 5.ts 6.ts
假设所有ts文件按顺序排列
如何生成A.mp4  B.mp4 不再枚举
其中ffmpeg已配置

附上几个很小的ts文件，大佬们可以练练手！谢谢！https://www.aliyundrive.com/s/NBw67uLXZVc
版主大大的第二段代码可以使用！谢谢！

lvwenjun11

回复 26# hlzj88


    谢谢 但是我还需要一个合并操作

hlzj88

在我的有限的实践中，发现 ts 文件可以直接重命名 为 mp4
例如：1  ren *.ts *.mp4
         2  type *.ts>>new.mp4  这里没有考虑先后顺序

xp3000

回复 23# lvwenjun11

就是把ffmpeg放入C:\Windows\System32文件夹就可以了

77七

回复 22# lvwenjun11


   你可以直接在命令行输入

ffmpeg -h
rem 或者
ffmpeg -help
复制代码

试试看呢？

lvwenjun11

回复 21# xp3000


    谢谢 这个是不是要重新设置环境变量 提示里这么说 我明明设置过了

lvwenjun11

回复 20# 77七


    也是不行 我添加环境变量了 用九楼的代码跑成功了，您的这个代码我又试了 有反应 但是不合成 最后清空了ts

xp3000

回复  xp3000
    谢谢大佬！但是不行
lvwenjun11 发表于 2023-2-4 16:20

原帖上面增加了一个处理整个分区的

77七

回复 19# lvwenjun11


  

@echo off
cd /d "%~dp0"
rem 先设置路径ffmpeg的路径，需要引号，例如 set ffmpegexe="C:\Program Files\ffmpeg\ffmpeg.exe"
set ffmpegexe=


for /f "delims=" %%i in ('dir /b /s /ad') do (
	pushd "%%i"
	for /f "delims=" %%a in ('dir /b /a-d *.ts') do (
		echo file '%%~fa'
	)>>temp.txt
	if exist temp.txt (
		%ffmpegexe% -f concat -safe 0 -i temp.txt -c copy "%%~ni.mp4"
		for /f "tokens=2 delims='" %%b in ('type "temp.txt"') do (
			del "%%b"
		)
		del temp.txt
	)
	popd
)
pause
复制代码

你的ffmpeg应该没有添加到环境变量吧？
试一下这样呢？

lvwenjun11

回复 18# 77七


    没有这种情况，用九楼大大的代码重新试了一下，可以了！也非常谢谢你！

77七

回复 17# lvwenjun11

看来是ffmpeg合并失败了
   你的文件名或者路径名是不是含有特殊符号？目录下不要存在与文件夹名同名的MP4文件

lvwenjun11

回复 15# 77七


    看了下确实有动静。。。就是把原来的ts全删了

lvwenjun11

回复 14# xp3000


    谢谢大佬！但是不行

77七

回复 13# lvwenjun11

把代码以ansi编码格式保存为bat文件，放到需要处理的目录里面，如果目录下没有ts文件，肯定没有动静

xp3000

这个问题在于有人不知道下载的ffmpeg放哪里
ffmpeg放入C:\Windows\System32文件夹就可以了
下面这个只处理目录下一级的文件夹的ts视频

@echo off&setlocal enabledelayedexpansion
@REM 保存为ANSI编码，文件名排序后合并视频

set s=^^^^^^^^^^^^^^^^^^^^^^^^^^
for /d %%a in (*) do (echo.进入文件夹：%%a
    pushd %~dp0%%a&type nul>"%%a.txt"
setlocal
for /f "delims=" %%i in ('dir /b/a-d/on "*.ts"') do (
    set "ss=!s!!s!!s!!s!!s!%%i"&set "^^=!ss:~-64!"&set _!^^!=!^^!
    )
for /f "delims==_^^" %%j in ('set _^|sort /+1') do (
    echo;file %%j>>"%%a.txt"&echo; 即将合并文件 %%j
    )
popd
endlocal
ffmpeg -f concat -i "%~dp0%%a\%%a.txt" -vcodec copy -acodec copy "%~dp0%%a.mp4" -y
del /f /s /q "%~dp0%%a\%%a.txt" >nul 2>nul
)
pause
复制代码

ffmpeg后面有个-y，不需要覆盖就删除
这一个处理根目录内所有文件夹的ts视频

@echo off&setlocal enabledelayedexpansion
@REM 保存为ANSI编码，文件名排序后合并视频
cd \
set s=^^^^^^^^^^^^^^^^^^^^^^^^^^
for /f "delims=" %%a in ('dir /a:d /b/s *') do (
    pushd "%%a"&echo.进入"%%a"
if exist *.ts (type nul>"%%a\%%~na.txt"
echo.
setlocal
for /f "delims=" %%i in ('dir /b/a-d/on "*.ts"') do (
    set "ss=!s!!s!!s!!s!!s!%%i"&set "^^=!ss:~-64!"&set _!^^!=!^^!
    )
for /f "delims==_^^" %%j in ('set _^|sort /+1') do (
    echo;file %%j>>"%%a\%%~na.txt"&echo; 即将合并文件 %%j
    )
popd
endlocal
ffmpeg -f concat -i "%%a\%%~na.txt" -vcodec copy -acodec copy "%~dp0%%~na.mp4" -y

del /f /s /q "%%a\%%~na.txt" >nul 2>nul
) else (echo %%a不存在ts视频)
)
pause
复制代码