[文件操作] [已解决]批处理如何提取最底层文件夹名称到文本？

a6236130

比如A是主文件夹，批处理在A里面，则提取当前目录下所有子文件夹里最底层文件夹的名称到文本txt中
       A/A1/BBB/CCC、
      A/A2/BBB/CCC/DDD，
      A/A3/BBB
谢谢！

a6236130

感谢各位大哥！！

aloha20200628

@echo off
(for /f "delims=" %%d in ('dir /b/s/ad') do (
	cd /d "%%~d"
	dir /b/ad|findstr ".*">nul||echo,%%d
))>"末级目录列表.txt"
复制代码

WHY

PowerShell "dir -Literal '%~dp0' -Recurse -Dir | ?{!$_.GetDirectories().Count} | forEach{$_.FullName}"
复制代码

WHY

@echo off
for /d /r "%~dp0" %%i in (*) do (
    set "flag="
    for /d %%j in ("%%~i\*") do set "flag=1"
    if not defined flag echo;%%i
)
pause
复制代码

terse

@echo off
>new_txt.txt (for /f "delims=" %%i in ('dir /b /ad') do (
        call :getfolder "%%~i" "d"
        call echo %%d%%
))
pause&exit
:getfolder
(for /f "delims=" %%a in ('dir /ad/b "%~1\"') do call :getfolder "%~1\%%a" %2)||set "%~2=%~1"&exit /b
复制代码

qixiaobin0715

@echo off
for /f "delims=" %%a in ('dir /s /b /ad') do (
    dir /b /ad "%%a"|findstr .>nul 2>nul
    if errorlevel 1 echo,%%a
)
pause
复制代码

hfxiang

回复 1# a6236130

@echo off
rem 保存为ANSI编码格式
setlocal enableDelayedExpansion
cd /d "%~dp0"
set A=%~f0
(
	for /f "delims=" %%a in ('dir /b/s/ad^|sort/r') do (
		if "!A!" NEQ "%%~fa\" echo;%%~na
		set A=%%~dpa
	)
)>dir_name.txt
endlocal
复制代码

77七

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
        pushd "%%i"
        set n=
        for /f "delims=" %%a in ('dir /b /s /ad ^| sort /r') do (
                if not defined n (
                        echo %%~na
                        set n=1
                )
        )
        popd
)>>名称.txt
pause
复制代码

这样可以吗？