[文本处理] 批处理如何根据最后1列修改数值？

娜美

大家好 文件夹内有多个 *.txt文件  需要批量将里面内容修改,   最好可以直接对源文件里面内容数值修改会更好,   因为不用产生另一个输出新文件名,   如不可  则需要输出的文件名称 和 输入的文件名称相同

*.txt
下面    如果最后1列的最后一个数字是2,  测需要将第2列修改为 01 数值,  如果是其他数字, 则不做任何处理   
W*02*8ee*bb*c038*f86bdb6e*010fac020000*02
W*02*8ee*bb*c038*f86bdb6e*010fac020000*90
W*02*8ee*bb*c038*f86bdb6e*010fac020000*95
W*01*Y5333*T5D54D*DR4ER45W32***
W*01*Y5333*T5D54D*DR4ER45W3


改动后  
W*01*8ee*bb*c038*f86bdb6e*010fac020000*02
W*02*8ee*bb*c038*f86bdb6e*010fac020000*90
W*02*8ee*bb*c038*f86bdb6e*010fac020000*95
W*01*Y5333*T5D54D*DR4ER45W32***
W*01*Y5333*T5D54D*DR4ER45W3


谢谢 Thanks.....

hfxiang

@echo off
setlocal EnableDelayedExpansion
(for /f %%i in (1.txt) do (
    set "str=%%i"
    if [!str:~-1!]==[2] (
                set "str1=!str:**=!"
                set "str2=!str1!"
                call set "str1=%%str:!str1!=%%"
                set "str2=!str2:**=!"
                echo;!str1!01*!str2!
        ) else (
                echo;%%i
        )
)
)>temp_1.txt
move /y temp_1.txt 1.txt
endlocal

娜美

可以了  多谢各位哥哥了

aloha20200628

@echo off &setlocal enabledelayedexpansion
dir/b/a-d *.txt>tmpF.lst
for /f "delims=" %%F in (tmpF.lst) do (
        for /f "usebackq delims=" %%s in ("%%F") do (
                set "s=%%s"
                if !s:~-1! neq 2 (echo,%%s) else (
                        for /f "tokens=1-2* delims=*" %%1 in ("%%s") do (echo,%%1*01*%%3)
                )
        )>>tmpF
        move /y tmpF "%%~nxF">nul
)
endlocal&(del/q tmpF.lst)&exit/b

qixiaobin0715

这样可能更精确一些，如果文件中不存在最后一个字符是2的行，则不处理：

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%I in ('findstr /r /m "2$" *.txt') do (
    (for /f "delims=" %%a in ('type "%%I"') do (
        set "str=%%a"
        if "!str:~-1!"=="2" (
            for /f "tokens=1,2* delims=*" %%i in ("%%a") do set "str=%%i*01*%%k"
        )
        echo,!str!
    ))>$
    move "$" "%%I"
)
pause
复制代码

qixiaobin0715

未测试：

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%I in ('dir /b /a-d *.txt') do (
    (for /f "delims=" %%a in ('type "%%I"') do (
        set "str=%%a"
        if "!str:~-1!"=="2" (
            for /f "tokens=1,2* delims=*" %%i in ("%%a") do set "str=%%i*01*%%k"
        )
        echo,!str!
    ))>$
    move "$" "%%I"
)
pause
复制代码

娜美

回复 5# qixiaobin0715


我改成这样后为什么不能批量对所有文件修改呢

@echo off
setlocal enabledelayedexpansion
(
for /f "delims=" %%a in (*.txt) do (
    set "str=%%a"
    if "!str:~-1!"=="2" (
        for /f "tokens=1,2* delims=*" %%i in ("%%a") do set "str=%%i*01*%%k"
    )
    echo,!str!
)
)>%%a.txt
endlocal
pause
复制代码

flashercs

@echo off
setlocal enabledelayedexpansion
(
for /f "delims=" %%a in (1.txt) do (
    set "str=%%a"
    if "!str:~-1!"=="2" (
        for /f "tokens=1,2* delims=*" %%i in ("%%a") do set "str=%%i*01*%%k"
    )
    echo,!str!
)
)>"%temp%\abc.txt"
move /y "%temp%\abc.txt" 1.txt
endlocal
pause
复制代码

娜美

回复 5# qixiaobin0715


   很好  如果可以直接在源文件里面修改会更好,   因为不用产生另一个新文件名   谢谢了

qixiaobin0715

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in (1.txt) do (
    set "str=%%a"
    if "!str:~-1!"=="2" (
        for /f "tokens=1,2* delims=*" %%i in ("%%a") do set "str=%%i*01*%%k"
    )
    echo,!str!
)
pause
复制代码

娜美

回复 2# hfxiang


   测了一下如果前面多了几个字母会有错误
WGJ*02*8ee*bb*c038*f86bdb6e*010fac020000*02

WGGJ6*02*8ee*bb*c038*f86bdb6e*010fac020000*02

娜美

回复 2# hfxiang


    似乎可以, 谢谢hfxiang哥哥,     但是可以直接对源文件进行修改吗(即直接修改源文件) ,   不想再产生新输出文件了

hfxiang

@echo off
setlocal EnableDelayedExpansion
for /f %%i in (1.txt) do (
        set "str=%%i"
        if [!str:~-1!]==[2] (
                echo !str:~0,2!01!str:~4!
        ) else (
                echo %%i
        )
)
endlocal