[文件操作] [分享]批处理查找指定日期修改过的文件

Batcher

【问题描述】

求教 怎么查找 指定日期修改过的文件
这样可以：

dir /a /s /tw |find "2021/11/08"
复制代码

有没有参数能显示这个文件的路径？

Batcher

回复 8# ww0000

@echo off
cd /d "%~dp0"
(for /f "delims=" %%i in ('dir /b /s /a-d *.txt') do (
    for /f %%j in ("%%~ti") do (
        if "%%j" gtr "2023/03/11" (
            if "%%j" lss "2023/03/19" (
                echo %%j %%i
            )
        )
    )
))>"Out.txt"
复制代码

ww0000

回复 7# Batcher


    谢谢老师！
if "%%j" gtr "2023/03/11" lss "2023/03/19"  两个日期之间的代码要怎么写？  加上文件类型判断又如何写呢？

Batcher

回复 5# ww0000


2.bat

@echo off
cd /d "%~dp0"
type nul >"Out.txt"
for /f "delims=" %%i in ('dir /b /s /a-d') do (
    for /f %%j in ("%%~ti") do (
        if "%%j" equ "2021/11/08" (
            >>"Out.txt" echo %%j %%i
        )
    )
)
复制代码

Batcher

回复 5# ww0000


1.bat

@echo off
cd /d "%~dp0"
(for /f "delims=" %%i in ('dir /b /s /a-d') do (
    for /f %%j in ("%%~ti") do (
        if "%%j" equ "2021/11/08" (
            echo %%j %%i
        )
    )
))>"Out.txt"
复制代码

ww0000

回复 2# Batcher


    路径能输出到TXT吗？

Batcher

回复 3# qixiaobin0715


    看起来第3行的 /a 是多余的，只保留 /a-d 就行了。

qixiaobin0715

dir一些参数还是未搞明白。
这里/a /a-d是表示：只显示文件不显示目录，隐藏文件也显示。
是吗？

Batcher

【解决方案】

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /a /a-d') do (
    for /f %%j in ("%%~ti") do (
        if "%%j" equ "2021/11/08" (
            echo %%j %%i
        )
    )
)
pause
复制代码