[文本处理] [已解决]批处理获取文件路径删除被拖放的文件夹部分

2013koko

请教各位坛友：
@echo off
setlocal enableDelayedExpansion
if "%~1"=="" echo,请拖放文件夹到本文件上&pause&exit /b
dir /a-d /b /s /og "%~1" >"%~dp0file.txt"
dir /ad /b /s /og "%~1" >"%~dp0folder.txt"
copy folder.txt + file.txt folderfile.txt
这个批处理是拖放文件夹获取文件列表和目录列表
但这个生成的文件列表是带绝对路径的，如：D:\TEST\被拖放的文件夹\...，现在想去除其中的“D:\TEST\被拖放的文件夹\”部分，请问该如何做？感谢！

2013koko

回复 21# went

这个也能达到目的，可惜不知为何不能评分，谢谢！

2013koko

回复 20# cutebe


这个完美！批处理多大？比三方小多了，并且一个文件就ok!

2013koko

回复 19# newswan


    这个批处理运行后得到的是文件列表+目录列表。能否文件列表一个输出，文件目录一个输出？谢谢！

went

回复 21# went


    要生成到bat文件夹就把第一行@echo off改为

@echo off & cd /d "%~dp0"
复制代码

went

支持一次性拖动多个文件夹到bat上,ansi保存

@echo off
if "%~1"=="" echo,请拖放文件夹到本文件上 &pause&exit 
:loop
echo %~1
(
	for /r "%~1" %%i in (*) do (
		call set "p=%%~i"
		call set "p=%%p:%~1\=%%"
		call echo %%p%%
	)
)>"%~nx1.txt"
echo %~nx1.txt
echo done.
echo ---------------
shift /1
if not "%~1"=="" goto :loop
pause&exit
复制代码

cutebe

不用三方会稍微复杂点。

@echo off
setlocal enableDelayedExpansion
set "str=%~1"
set dn=1
:snlp
if "!str:*\=!" neq "" (
	set/a dn+=1
	set "str=!str:*\=!"
	if "!str:*\=!" neq "!str!" goto :snlp
)
setlocal disableDelayedExpansion
(for /f "tokens=%dn%* delims=\" %%q in ('dir/a-d/b/s/og "%~1"')do echo %%r)>"%~dp0%~nx1_filelist.txt"
复制代码

newswan

@echo off
setlocal enableDelayedExpansion

for %%a in (%*) do (
    call :f1 %%a
)
goto :END


:f1
for /f "usebackq" %%a in (`Powershell -c "'%1'.Length"`) do (
    set /a n=%%a+1
)
for /f "usebackq delims=" %%a in (` dir /a/s/b/on %1 `) do (
    set str=%%~a
    set str=!str:~%n%!
    echo !str!
)
goto :eof

:END
pause
复制代码

支持多个文件夹

2013koko

回复 17# cutebe


用三方工具确实可以了，谢谢！
请教不用工具，批处理删除文本中的字符串能够实现吗？

cutebe

回复 15# 2013koko

我试了已经可以了。
sed.exe放在批处理同目录，搜索下载：http://www.bathome.net/s/tool/index.html

2013koko

回复 12# newswan

这个似乎不对，试了多个文件夹 都只显示一行：smart-art\quickstyle\simple5.xml

2013koko

回复 14# cutebe

还是差一线，请再看一下，谢谢！

以下是输出的部分内容，现在想删除每行中的“D:\Software\Office 2010\”这一段，其余均保留

D:\Software\Office 2010\+)激活备份还原.cmd
D:\Software\Office 2010\-)卸载.cmd
D:\Software\Office 2010\!)安装.cmd
D:\Software\Office 2010\icons\GRAPH.ICO
D:\Software\Office 2010\icons\misc.exe
D:\Software\Office 2010\icons\MSOICONS.EXE
D:\Software\Office 2010\icons\PPTICO.EXE
D:\Software\Office 2010\icons\WORDICON.EXE
D:\Software\Office 2010\icons\XLICONS.EXE
D:\Software\Office 2010\icons\ACCICONS.EXE
D:\Software\Office 2010\Office14\ACCDDS.DLL
D:\Software\Office 2010\Office14\ACCDDSF.DLL
D:\Software\Office 2010\Office14\ACCDDSLM.DLL
D:\Software\Office 2010\Office14\ACCVDT.DLL
D:\Software\Office 2010\Office14\ACCWIZ.DLL
D:\Software\Office 2010\Office14\ACEDAO.DLL
D:\Software\Office 2010\Office14\AUTHZAX.DLL

cutebe

回复 10# 2013koko三方工具可从论坛下载：sed.exe

开始会错意，现在搞清了！

dir/a-d/b/s/og "%~1">"%~dp0%~n1_filelist.txt"
set "dirstr=%~1\"
sed -i "s/^%dirstr:\=\\%//" "%~dp0%~n1_filelist.txt"
复制代码

newswan

过滤子目录，要或不要，用白名单或者黑名单

newswan

@echo off
setlocal enableDelayedExpansion

for /f "usebackq" %%a in (`Powershell -c "'%1'.Length"`) do (
    set /a n=%%a+1
)
for /f "usebackq delims=" %%a in (` dir /a/s/b/on %1 ^| findstr /v "EBWebView" `) do (
    set str=%%~a
    set str=!str:~%n%!
    echo !str!
) > list.txt
复制代码