[文件操作] [已解决]批处理修改文件名删除特定两个字符之间字符

Alandx

删除第一个_与倒数第二个_之间的字符，最好将最后一个_后的字符也删除。
例：
abc_xyz_a-a_654321_01_123.jpg
删除后得：
abc_01_123.jpg
最好：
abc_01.jpg

qixiaobin0715

回复 16# Alandx
变量延迟转换，假借而已，实际上并没有循环。

Alandx

回复 14# qixiaobin0715

最后一句还需要通过循环来吗？能不能直接改名？

Alandx

回复 11# Batcher

感谢~~

qixiaobin0715

回复 13# newswan

画蛇添足是我经常出现的问题，谢谢提醒。应修改为：

@echo off
setlocal enabledelayedexpansion
for %%a in (*.jpg) do (
    set n=0
    set str=%%a
    set str=!str:_= !
    for %%b in (!str!) do (
        set /a n+=1
        set str!n!=%%b
    )
    set /a n-=1
    for %%c in (str!n!) do ren "%%a" "!str1!_!%%c!.jpg"
)
pause
复制代码

newswan

回复 12# qixiaobin0715

每个字段分别保存到一个变量，通过for语句进行2次变量扩展。

for %%a in (*.jpg) do (
    set str=%%~na
    set str=!str:_= !
    set n=0
    for %%a in (!str!) do (
        set /a n+=1
        set str!n!=%%a
    )
    set /a m=n-1
    set str
    for %%a in (str!m!) do echo !%%a!
)
复制代码

qixiaobin0715

也可以这样：
通过set /a m-=？，来控制文件名是要保留倒数第几段字符。

@echo off
setlocal enabledelayedexpansion
for %%a in (*.jpg) do (
    set n=0
    set str=%%a
    set str=!str:_= !
    for %%b in (!str!) do (
        set /a n+=1
        set /a m=!n!%%10
        set str!m!=%%b
    )
    set /a m-=1
    for %%c in (str!m!) do ren "%%a" "!str1!_!%%c!.jpg"
)
pause
复制代码

Batcher

回复 9# Alandx


sed和awk(gawk)是Linux系统里面两个非常强大的文本处理命令
Windows能用的版本可以在这里下载：
http://bcn.bathome.net/s/tool/index.html?key=sed
http://bcn.bathome.net/s/tool/index.html?key=gawk

qixiaobin0715

什么sed、awk之类的都属于第三方命令，需要下载所属代码，处理字符串较为方便，个人偏爱纯批，不受限制。

Alandx

回复 6# newswan

我是新手 问一下awk是什么？

newswan

回复 7# netdzb


忘记 扩展名了。。

netdzb

回复 6# newswan

你的代码有问题，正确的应该如下：

dir /b *.jpg |awk -F '[_.]' '{print $1"_"$(NF-2)"."$(NF)}'

newswan

段落数量可变，有 awk 方便多了，用shift 遍历参数麻烦些。

dir /b *.jpg | awk -F '[_.]' '{print $1"_"$(NF-2)}'
复制代码

newswan

固定段落数量

for /f "usebackq tokens=1,5,7 delims=_." %%i in (`dir /b *.jpg`) do (
    echo %%i %%j %%k
)
复制代码

qixiaobin0715

回复 3# newswan
_数量不固定可以这样。

@echo off
setlocal enabledelayedexpansion
for %%a in (*.jpg) do (
    set n=1
    set str=%%a
    set str=!str:_= !
    for %%b in (!str!) do (
        if !n!==1 (
            set str1=%%b&set n=0
        ) else if "%%b"=="%%~nb" (
            set str2=%%b
        )
    )
ren "%%a" "!str1!_!str2!.jpg"
)
pause
复制代码