[系统相关] 为何批处理给变量赋值后，变量值依然是空的？

microyip

为了方便日常系统安装工作，写了一个安装用的批处理，全部已经写好了，一运行，发现被闪退了，所以分块测试检查，发现居然存在明明已经赋值的变量是空的。
看看哪位大侠给点指教，下面贴出的代码是发现开始出错的地方。没贴全部，请见谅！

@echo off
for /f "tokens=2 delims=:" %%i in ('chcp') do set ChcpCode=%%i
echo %Chcpcode%

rem chcp 65001 >nul

:Menu
set ReturnMenu=1
cls
color 1E
echo =====================================
echo    ***** 安装软件*****
echo =====================================
echo 1、安装.Net Framework            [1]
echo 2、安装软件1                     [2]
echo 3、安装软件2                     [3]
echo 4、安装软件3                     [4]
echo 5、安装软件4                     [5]
echo 6、安装软件5                     [6]
echo 7、安装软件6                     [7]
echo 8、安装软件7                     [8]
echo 9、安装软件8                     [9]
echo 0、安装软件9                     [0]
echo A、安装软件10                    [A]
echo B、按顺序安装上面软件            [B]
echo C、安装软件11                    [C]
echo Q、退出安装                      [Q]
echo =====================================
echo PS:选择9时，默认安装.Net Framework 4.62
choice /c 1234567890abcq /n
if errorlevel 14 (
  exit
) else if errorlevel 13 (
  set SS=13
) else if errorlevel 12 (
  set ReturnMenu=0
) else if errorlevel 11 (
  set SS=11
) else if errorlevel 10 (
  set SS=10
) else if errorlevel 9 (
  set SS=9
) else if errorlevel 8 (
  set SS=8
) else if errorlevel 7 (
  set SS=7
) else if errorlevel 6 (
  set SS=6
) else if errorlevel 5 (
  set SS=5
) else if errorlevel 4 (
   set SS=4
) else if errorlevel 3 (
  set SS=3
) else if errorlevel 2 (
  set SS=2
) else (
  set SS=1
)

cls
color 2E

if %SS% == 1 (
  echo =====================================
  echo    ***** 安装.Net Framework*****
  echo =====================================
  echo 1、安装.Net Framework 4.62       [1]
  echo 2、安装.Net Framework 3.5SP1     [2]
  echo 3、安装.Net Framework 2.0        [3]
  echo Q、退出安装                      [Q]
  echo =====================================
  choice /c 123q /n
  if errorlevel 4 (
    goto Menu
  ) else if errorlevel 3 (
    set SS=1.3
  ) else if errorlevel 2 (
    set SS=1.2
  )
rem 下面这个aa变量赋值成功！
  set aa=1.3
  echo [%aa%]
) else if %SS% LSS 13 (
  echo =====================================
  echo    ***** 安装软件 *****
  echo =====================================
  echo 1、安装软件1                     [1]
  echo 2、安装软件2                     [2]
  echo 3、安装软件3                     [3]
  echo Q、退出安装                      [Q]
  echo =====================================
  choice /c 123q /n
  if errorlevel 4 (
    goto Menu
  ) else if errorlevel 3 (
    set SS=1.3
  ) else if errorlevel 2 (
    set SS=1.2
  )
rem 为什么下面这个aa变量赋值不成功？
  set aa=1.4
  echo [%aa%]
)
pause
复制代码

Batcher

回复 7# microyip


    如果6楼的教程看完之后仍然有疑问，欢迎随时联系我。

microyip

回复 6# Batcher 感谢推荐，多问个问题，那么加了setlocal enabledelayedexpansion之后，是否要把所有双%变量改成双！变量？

Batcher

回复 1# microyip


推荐阅读：批处理中的变量延迟扩展、变量嵌套
http://bbs.bathome.net/thread-2899-1-1.html

microyip

回复 4# 路过 多谢多谢耐心指导，有点懵逼，之前测试时候是可以的，你一说，发现还真的不可以。

路过

回复 3# microyip 你确定？在你给的出错的代码里第一个界面按1，变量SS=1
然后第二个界面也按1，执行第83行代码后的结果是"[]"，也就是变量aa"消失了"。

可能的原因是在执行64-104行代码之前变量aa的值已经是1.3了。

microyip

回复 2# 路过


    十分感激，测试成功！但有个问题想了解一下，为何第一个IF那里无需按你的方法处理都能成功呢？

路过

这是批处理的预处理机制导致的。
修改方法：在第六行添加

setlocal enabledelayedexpansion
复制代码

第103行改为

echo [!aa!]
复制代码