[文本处理] 批处理echo输出的变量后面不可以加文字 显示错位

cc5511

echo输出的变量后面不可以加文字 显示错位 可能是有换行的原因 求解决方法

这个是正常的，可以在变量后面显示“你好”

@echo off
for /f "tokens=2 delims= " %%i in ('ver') do echo          %%i 你好
pause

这个是有问题的，你好显示在变量的前面，奇怪了。。

@echo off
for /f "tokens=2 delims==" %%i in ('wmic memphysical get MemoryDevices /value') do echo          %%i 你好
pause

cc5511

回复 5# Batcher


    谢谢Batcher管理员的指导，经过你分享的链接，学会了怎么处理了。


经过学习，可以通过for+call echo过滤一次，就能正常赋值到变量上了。
主要是这句：for /f "delims=" %%b in ('call echo !cpuxh!') do set cpuxh=%%b

@echo off
setlocal enabledelayedexpansion
for /f "tokens=2 delims==" %%a in ('wmic cpu get Name /value') do set cpuxh=%%a
for /f "delims=" %%b in ('call echo !cpuxh!') do set cpuxh=%%b
echo                               CPU型号为：变量前面!cpuxh!变量后面
pause
复制代码

Batcher

回复 4# cc5511


2楼链接里面有多种方法，例如：

@echo off
for /f "tokens=2 delims==" %%a in ('wmic memphysical get MemoryDevices /value ^| findstr "MemoryDevices"') do (
    for %%i in (%%a) do (
        set nctsl=%%i
    )
)
echo 内存条数量为：%nctsl%根
复制代码

cc5511

回复 2# Batcher


   大神 有时间帮我研究下不 我是想做个检测内存的批处理，看下怎么改一下好点，wmic提取出来的容量是字节为单位的，我本想再用“powershell -c”来除以1073741824（1073741824字节=1GB）来换算G数的，奈何提取出来的数字貌似最后有换行，连在"echo 变量"后面加个“字节”的文字都显示错位，更加不能运算了~

@echo off
setlocal enabledelayedexpansion

for /f "tokens=2 delims==" %%a in ('wmic memphysical get MemoryDevices /value') do set nctsl=%%a
echo 	内存条数量为：!nctsl!根

set sz=0
for /f "tokens=2 delims==" %%a in (
	'wmic memorychip get Capacity^,ConfiguredClockSpeed^,DeviceLocator^,Manufacturer^,PartNumber /value ^| find /i "Capacity"'
) do (

set /a sz=!sz!+1
if !sz! equ 1 set nc!sz!=%%a
if !sz! equ 2 set nc!sz!=%%a
if !sz! equ 3 set nc!sz!=%%a
if !sz! equ 4 set nc!sz!=%%a

)

for /l %%a in (1,1,!nctsl!) do echo 	第%%a根内存条容量：!nc%%a!字节


pause
复制代码

cc5511

回复 2# Batcher


    非常感谢你的帮助 我去研究下 谢谢

Batcher

回复 1# cc5511


参考：批处理调用WMIC时如何处理结果中的特殊字符？
http://bbs.bathome.net/thread-2862-1-1.html
http://bbs.bathome.net/thread-28534-1-1.html
http://bbs.bathome.net/thread-28535-1-1.html
http://bbs.bathome.net/thread-12033-1-1.html