【练习-037】批处理去除文本行前后的空格

batman

　　因为论坛练习题系列中确实缺少37题（这是本人的过失），所以就
以本题来做为37题吧。有文本a.txt如下：

 amd cx qu      
    k of woo is qmom                 
      jm ko    ppp     oe    mie    tnnn           
  sis              jb  
复制代码

　　要求通过批处理去除文本行的前后空格（空格数是随机和末知的
，且都为半角空格），输出如下（行的前后请加上引号）：

"amd cx qu"
"k of woo is qmom"
"jm ko    ppp     oe    mie    tnnn"
"sis              jb"
复制代码

　　本题满分10分，原则上以思路为重，视情况加分。
       参考答案如下：

@echo off
for /f "delims=" %%a in (a.txt) do set "a="&call :lp "$%%a$"
pause>nul&goto :eof
:lp
for /f "tokens=1* delims= " %%a in ("%a%%~1") do set "str=%%b"&set "var="
for %%a in (%str: = # %) do call,set "var=%%a%%var%%"
if "%~1" neq "" (set "a=%var:#= %"&call :lp) else echo "%var:#= %"
复制代码

[ 本帖最后由 batman 于 2009-8-15 18:44 编辑 ]

Batcher

@echo off
(for /f "tokens=*" %%i in ('type "C:\1.txt"') do (
    echo,%%~nxi
))>"D:\2.txt"
复制代码

踏沙行

wxcute 发表于 2009-8-15 21:04

原贴代码：

@echo off
for /f "tokens=* delims= " %%s in (a.txt) do call :str %%s
pause
:str
echo "%*"
复制代码

这个方法也很好，但是有个困惑：怎么取得返回值？
如果我想把每行首尾的空格去掉后，再将结果返回给主程序中的某个变量，该怎么实现？

踏沙行

回复 2# netbenton
旧贴重提，不知道论坛是否有禁止性规定？
使用扩展变量%~nx，固定速度快，但是假如，文本中包含有路径符号 \ 的话，就悲剧了。
比如：1.txt内容如下：
   A11 !b11 H\c11 ^E
      A13 B13\22\123 #C13 E

yashuer

发个sed的
#!/bin/bash
# Fri Jun 22 15:43:42 CST 2012 
# Sun Jul  1 19:52:32 CST 2012
# The code is listed as follows
echo >uu.txt
sed 's/^\s*\(.*[a-z]\)\s*$/\1/g' temp > uu.txt 
exit
复制代码

civen

&&修改下我顶楼的代码，顶楼原来是想通用一系列的技巧来简化代码，
结果是付出了效率上的代价，现提高代码 ...
batman 发表于 2009-8-15 21:07

有点不完美. 空行带空格的还得输出一个空格

zaixinxiangnian

回复 5# keen


    你这个还好理解些，但到这里就想不通了。  为什么有个#号？如果有时间每句给解释下就有富了

for %%h in (!str1!) do (

        for %%m in (!str1!#) do set hh=!str:%%h=%%m!

        for /f "delims=#" %%x in ("!hh!") do echo "%%x"

Seder

有分加那么好？？

sed -e "s/^[ ]*//;s/[ ]*$//;s/\(.*\)/\"\1\"/" test.txt
复制代码

Hello123World

参照2楼的算法，但不知道原理。

@echo off
For /f "Tokens=*" %%i in (a.txt) do (For /f "tokens=*" %%a in ("%%i") do Echo "%%~nxa")
pause
复制代码

leap

@echo on&setlocal enabledelayedexpansion
for /f "tokens=*" %%i in (a.txt) do (
	md "d:\2\%%i")
for /f "delims=" %%i in ('dir /b "d:\2\"') do echo "%%i">>2.txt
rd/s/q d:\2\
pause
复制代码

terse

不考虑特殊字符的话 call出来 echo %* 效率可以
利用%%~nxi扩展的话 路径的处理上也有问题
我再用替换法  发现效率比不上echo %*
文本中有一个引号的话也出错 两引号之间没空格可以处理

@echo off&setlocal enabledelayedexpansion
for /f "tokens=*" %%i in (a.txt) do (
    set var=%%i&set str=&set "k= "
    set "var=!var: =" "!"
    for %%a in ("!var!") do if %%a neq "" (
        set "str=!str!!k!%%~a"&set "k= "
      ) else set "k= !k!"
        echo "!str:~1!"
   )
pause
复制代码

Lumiere

原帖由 wxcute 于 2009-8-15 21:04 发表
@echo off
for /f "tokens=* delims= " %%s in (a.txt) do call :str %%s
pause
:str
echo "%*"

你的delims= 似乎是多余的吧？tokens=*不是不会分节字符串的么？
还有啊，%*我现在还不是太明白，能给讲解一下么

Lumiere

@echo off&setlocal enabledelayedexpansion
for /f "tokens=*" %%a in (a.txt) do set "var=%%a"&call :loop&echo "!var!">>b.txt
goto :eof
:loop
set "check=!var:~-1!"&if "!check!"==" " set "var=!var:~0,-1!"&goto loop
复制代码

[ 本帖最后由 Lumiere 于 2009-8-16 00:36 编辑 ]

shqf

综合一下，还可如下
@echo off
for /f "tokens=* delims= " %%s in (a.txt) do echo "%%~nxs"
pause

batman

&&修改下我顶楼的代码，顶楼原来是想通用一系列的技巧来简化代码，
结果是付出了效率上的代价，现提高代码运行效率如下：

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
    for /f "tokens=*" %%a in ("%%a") do set "str=%%a"&set "str=!str: = # !"&set "var="
    for %%a in (!str!) do set "var=%%a!var!"
    set "var=!var:#= !"
    for /f "tokens=*" %%a in ("!var!") do set "str=%%a"&set "str=!str: = # !"&set "var="
    for %%a in (!str!) do set "var=%%a!var!"
    echo "!var:#= !"
)
pause>nul
复制代码