批处理获得所有的磁盘

novaa

最好用两种方法作答。
一种也可以

青青草

回复 29# 77七
谢谢！
Windows 11 24H2 已经没有了wmic。无法运行。
个人还是比较喜欢用diskpart

77七

回复 28# 青青草


  

@echo off
for /f "delims=:" %%i in ('wmic logicaldisk get name ^| find ":"') do (
	call set str=%%i %%str%%
)
echo %str%
pause
复制代码

试试这个

青青草

回复 24# 77七
另外，虚拟磁盘盘符似乎不能显示出来。

青青草

回复 25# aloha20200628

谢谢！

青青草

回复 24# 77七
谢谢！
再次请教：
     隐藏分区出现的是卷标，不是盘符。如何去掉它？（只显示可见分区盘符）
如，我的系统共有5个分区，C  D  E  F 还有隐藏的ESP分区。结果批处理中 str=F E ESP C D
我需要的是str=F E C D
应如何处理？谢谢！

aloha20200628

回复 23# 青青草

方法一》计入光驱

@echo off
for /f "tokens=1* delims=: " %%1 in (' fsutil.exe fsinfo drives^|find ":" ') do set "dl=%%2"
set "dl=%dl::\=%"
echo,%dl%
pause&exit/b
复制代码

方法二》不计入光驱

@echo off &setlocal enabledelayedexpansion &set "dl="
for %%d in (c d e f g h i j k l m n o p q r s t u v w x y z) do if exist %%d: set "dl=!dl!%%d "
echo,!dl!
endlocal&pause&exit/b
复制代码

77七

回复 23# 青青草


  

@echo off
for /f "skip=9 tokens=3" %%i in ('echo list volume ^| diskpart ') do (
	call set str=%%i %%str%%
)
pause>nul
复制代码

青青草

回复 21# Taurus
请教一下大神：
如何将盘符赋值给变量str?(如str=c d e f g)

唯尘

@echo off
for %%i in (c d e f g h i j k l m n o p q r s t u v w x y z) do if exist %%i: echo %%i:
pause

Taurus

再来一个未有的
用 diskpart 命令

@echo off
for /f "skip=9 tokens=3" %%i in ('echo list volume ^| diskpart ') do echo %%i:
pause>nul

[ 本帖最后由 Taurus 于 2009-5-20 20:47 编辑 ]

keen

你的方法，能得到多余的盘符，例如，我在机子上用过U盘，盘符为H，我把U盘拔掉。
你的方法仍然可以检测到U盘的盘符H的存在。

dtyunong

@echo off
setlocal enabledelayedexpansion
for /f "skip=1 tokens=1 delims=\" %%a in ('fsutil fsinfo drives^|find /v ""') do (
    set aa=%%a
    set aa=!aa:~-2!
    for %%i in (!aa!) do fsutil fsinfo drivetype  %%i
)
pause

Taurus

想到的楼上都答了,原本想答wmic...
相同的思方再答就不好了;
那就绕圈子,从regedit析辨
那样用for可不可算是第四种方法呢... ...?

@echo off
@for /f  "tokens=3 delims=\:" %%i in ('reg query "HKEY_LOCAL_MACHINE\SYSTEM\MountedDevices\" ^| findstr  /r "DosDevices"') do (
echo %%i:
)
pause

[ 本帖最后由 Taurus 于 2009-5-14 10:57 编辑 ]

sjzong

应该认真学习了！！！