[其他] [已解决]求EXE程序批量创建快捷方式到指定文件夹并一一对应

大地

求EXE程序批量创建快捷方式到指定文件夹并一一对应

重新整理一下

源：                                                    →→→目标：
     工具目录包TOOLS1112222及内EXE →→→    ①PE桌面  工具目录包TOOLS1112222及内部快捷方式
      (任意位置，
      当然在分区根目录寻找很快)                           ②所有程序：工具目录包TOOLS1112222及内部快捷方式
                                               
                                                                       ③自定义某几个快捷方式至PE桌面
                                                                           例：DG.exe,nap.exe,QQ.exe

         源文件夹与目标新文件夹一一对应
         源文件夹下的EXE与目标新文件夹下的EXE的快捷方式所在位置一一对应


    经反复实践测试：无缝创建完美运行，再次感谢went的多次、耐心、无私奉献。

    完整代码至本贴末尾见went发布的。


(由于精简系统缺少组件等原因，运行本代码会遇到“设备不支持符号链接“时，需要补全DLL文件才行)

went

回复 24# 大地

这是第三方工具,具体没用过

大地

回复 23# went

大师：
这个版本很好，很实用，很方便，就是能不能用Shortcut.exe替换mklink，一个是mklink版本，一个是shortcut版本，多一个版本，多一个选择。相互取长补短，适应不同的环境，不同的系统。

went

ANSI保存,再不行我也没招了

@echo off
REM Admin
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
REM search drivers
set "drivers=C D E F G H I J K L M N O P Q R S T U V W X Y Z"
REM exe foldername
set "exeFolderName=TOOLS1112222"
REM main foldername
set "linkFolderName1=C:\Users\lenovo\Desktop\1"
set "linkFolderName2=C:\Users\lenovo\Desktop\2"
REM esp exe
set "espExe=\分区工具\DG.exe?\截图工具\nap.exe?\其它\QQ.exe"
REM start
for %%i in (%drivers%) do if exist "%%i:\" ( 
	set /p="check:%%i:\%exeFolderName%   "<nul 
	if exist "%%i:\%exeFolderName%" (
		echo OK!
		set "folder=%%i:\%exeFolderName%" 
		goto :done
	) else echo not found!
)
echo -------------
for %%i in (%drivers%) do (
	cd /d "%%i:\" 2>nul && (
		echo search %%i: please wait...
		for /r /d %%a in ("*") do (
			if "%%~na" equ "%exeFolderName%" (
				set "folder=%%~a"
				goto :done
			)
		)
	)
)
:done
if "%folder%"=="" echo %exeFolderName% not found! & pause&exit
echo -------------
echo "folder=%folder%"
echo -------------
for /r "%folder%" %%i in ("*.exe") do (
	echo mklink: %%~i
	call set "exe=%%~i"
	call echo %espExe% | call findstr /i /C:"%%exe:%folder%\=%%" >nul 2>nul && (
		call echo add %userprofile%\desktop
		mklink "%userprofile%\desktop\%%~ni" "%%~i" >nul
	)
	for /f "tokens=2 delims==" %%a in ('set linkFolderName') do (
		call set "link=%%a\%exeFolderName%\%%exe:%folder%\=%%"
		call mkdir "%%link:%%~nxi=%%" >nul 2>nul
		call mklink "%%link:~0,-4%%" "%%~i" >nul
	)
)
pause&exit
复制代码

大地

回复 21# went



按ANSI保存不能运行无反应
按UTF-8保存，能运行，但显示在C盘根目录找不到，但实际在C盘根目录上有该文件夹
按BOM的UTF-8保存，运行一直滚动不停止
上述操作在完整版的WIN10中试也不行

went

回复 20# 大地


    ANSI编码

大地

回复 19# went


老师  加入上面的两个代码 运行闪屏不反应，  没有加入上面两个代码时仍运行正常

went

回复 18# 大地
16楼代码
10行下面加上以下代码,这是特殊exe的相对路径,?分隔

REM esp exe
set "espExe=\分区工具\DG.exe?\截图工具\nap.exe?\其它\QQ.exe?\新建文件夹\handle64.exe?\新建文件夹\CPU-V.exe"
复制代码

39行下面加上以下代码

call echo %espExe% | call findstr /i /C:"%%exe:%folder%\=%%" >nul 2>nul && (
		call echo add %userprofile%\desktop
		mklink "%userprofile%\desktop\%%~ni" "%%~i" >nul
	)
复制代码

ANSI保存

大地

回复 16# went


  从搜索到的TOOLS1112222的文件夹的EXE发送快捷方式至 "桌面" 和 "所有程序" 后，我还想
  从TOOLS1112222这个总文件夹中 挑选 其中三个特定的文件的快捷方式到桌面上

  TOOLS1112222\分区工具\DG.exe
                         \截图工具\nap.exe
                               \其它\QQ.exe
                                 ................

该如何添加？

大神再帮我解决一下吧  再次感谢!!

大地

回复 16# went

大神  ：

  从搜索到的TOOLS1112222的文件夹的EXE发送快捷方式至 "桌面" 和 "所有程序" 后，我还想
  从TOOLS1112222这个总文件夹中 挑选 其中三个特定的文件的快捷方式到桌面上

  TOOLS1112222\分区工具\DG.exe
                         \截图工具\nap.exe
                               \其它\QQ.exe
                                 ................

该如何添加？

went

文件夹按照9-10行的格式添加
set "linkFolderName序号=路径"

@echo off
REM Admin
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
REM search drivers
set "drivers=C D E F G H I J K L M N O P Q R S T U V W X Y Z"
REM exe foldername
set "exeFolderName=TOOLS1112222"
REM main foldername
set "linkFolderName1=C:\Users\lenovo\Desktop\1"
set "linkFolderName2=C:\Users\lenovo\Desktop\2"
REM start
for %%i in (%drivers%) do if exist "%%i:\" ( 
	set /p="check:%%i:\%exeFolderName%   "<nul 
	if exist "%%i:\%exeFolderName%" (
		echo OK!
		set "folder=%%i:\%exeFolderName%" 
		goto :done
	) else echo not found!
)
echo -------------
for %%i in (%drivers%) do (
	cd /d "%%i:\" 2>nul && (
		echo search %%i: please wait...
		for /r /d %%a in ("*") do (
			if "%%~na" equ "%exeFolderName%" (
				set "folder=%%~a"
				goto :done
			)
		)
	)
)
:done
if "%folder%"=="" echo %exeFolderName% not found! & pause&exit
echo -------------
echo "folder=%folder%"
echo -------------
for /r "%folder%" %%i in ("*.exe") do (
	echo mklink: %%~i
	call set "exe=%%~i"
	for /f "tokens=2 delims==" %%a in ('set linkFolderName') do (
		call set "link=%%a\%exeFolderName%\%%exe:%folder%\=%%"
		call mkdir "%%link:%%~nxi=%%" >nul 2>nul
		call mklink "%%link:~0,-4%%" "%%~i" >nul
	)
)
pause&exit
复制代码

大地

回复 13# went


大师  再次让你见笑了 没完没了 哈哈

在多个实体硬盘、U盘上的目录间任意传送，完美运行，但在实体盘上目录传送到内存系统(PE或ramos)的目录上，显示不支付该设备连接，无法创建。
经反复检查 最后搞清楚是系统问题，与大神代码无关， 大神代码可以完美运行，再次表示感谢。

1、我想一次两用，传送到桌面的同时，也同时发送到所有程序里面。当然可以运行两次，但我想简洁一点。如何修改？

大神 谢谢了。

大地

回复 13# went

大师  再次让你见笑了 没完没了 哈哈

在多个实体硬盘、U盘上的目录间任意传送，完美运行，但在实体盘上目录传送到内存系统(PE或ramos)的目录上，显示不支付该设备连接，无法创建。
经反复检查 最后搞清楚是系统问题，与大神代码无关， 大神代码可以完美运行，再次表示感谢。

1、我想一次两用，传送到桌面的同时，也同时发送到所有程序里面。当然可以运行两次，但我想简洁一点。如何修改？

大神 谢谢了。

went

权限问题

@echo off
REM Admin
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
REM search drivers
set "drivers=C D E F G H I J K L M N O P Q R S T U V W X Y Z"
REM exe foldername
set "exeFolderName=TOOLS1112222"
REM main foldername
set "linkFolderName=C:\ProgramData"
REM start
for %%i in (%drivers%) do if exist "%%i:\" ( 
	set /p="check:%%i:\%exeFolderName%   "<nul 
	if exist "%%i:\%exeFolderName%" (
		echo OK!
		set "folder=%%i:\%exeFolderName%" 
		goto :done
	) else echo not found!
)
echo -------------
for %%i in (%drivers%) do (
	cd /d "%%i:\" 2>nul && (
		echo search %%i: please wait...
		for /r /d %%a in ("*") do (
			if "%%~na" equ "%exeFolderName%" (
				set "folder=%%~a"
				goto :done
			)
		)
	)
)
:done
if "%folder%"=="" echo %exeFolderName% not found! & pause&exit
echo -------------
echo "folder=%folder%"
echo -------------
for /r "%folder%" %%i in ("*.exe") do (
	echo mklink: %%~i
	call set "exe=%%~i"
	call set "link=%linkFolderName%\%exeFolderName%\%%exe:%folder%\=%%"
	call mkdir "%%link:%%~nxi=%%" >nul 2>nul
	call mklink "%%link:~0,-4%%" "%%~i" >nul
)
pause&exit
复制代码

大地

回复 11# went


大师 让你见笑了 还是有两个问题要向你请教：

1、上面代码运行时  出现个别目录无法创建快捷方式，不知是权限问题还是其它问题
      后我用  xcopy **** /e/t 先复制空目录  再用上面的代码 就完整创建所有的快捷方式，
     我自个想加个xcopy  可不知道放哪个位置 一直没搞定

2、  第26行后加入    call set "tag=X:\ProgramData\Microsoft\Windows\Start Menu\Programs\%folderName%%%exe:%folder%=%%"
     显示运行错误  该如何修改加入？

     再次麻烦大师