[文件操作] 50元跪求批量删除压缩包的密码

manjaro

请问诸位大神，如何批量删除压缩包的密码，有成千上万个压缩包，主要是zip格式，也有少量是RAR格式。
有的压缩包有密码，有的没有密码。
有密码的压缩包密码都不同，但密码只有以下几个：12345678，qwer1234,雪山飞狐，神雕侠侣。
非常感谢，50元茶水费

manjaro

非常感谢，zip文件可以，但是rar文件不行啊

zaqmlp

密码一行一个输入到password.txt，将bat、txt和压缩包放一起运行，注意备份源文件

@echo off
mode con lines=3000
set info=互助互利,支付宝扫码头像,感谢赞助
rem 有问题,可加QQ956535081及时沟通
title %info%
cd /d "%~dp0"
set "pw=password.txt"
set "rarpath=C:\Program Files\WinRAR\WinRAR.exe"
if not exist "%rarpath%" (echo;指定WinRAR的安装路径不正确或没有安装&pause&exit)
if not exist "%pw%" (echo;密码文件不存在&pause&exit)
for /f "delims=" %%a in ('dir /a-d/b *.rar *.zip') do (
    call :check "%%a"
    rd /s /q "%%~dpna\" 2>nul
)
echo;%info%
pause&exit
:check
if not exist "%~dpn1\" md "%~dpn1\"
set "f="
"%rarpath%" x -p"" -ibck -y "%~1" "%~dpn1\"
for /f "delims=" %%c in ('dir /a-d/b/s "%~dpn1\" 2^>nul') do set f=true
if defined f (
    echo;["无密码"]"%~1"
    exit /b
)
for /f "delims=" %%b in ('type "%pw%"') do (
    "%rarpath%" x -p"%%b" -ibck -y "%~1" "%~dpn1\"
    for /f "delims=" %%c in ('dir /a-d/b/s "%~dpn1\" 2^>nul') do set f=true
    if defined f (
        echo;["%%b"]"%~1"
        del /a /f /q "%~1"
        "%rarpath%" a -r -ep1 -ibck "%~1" "%~dpn1\"
        exit /b
    )
)
echo;["找不到密码"]"%~1"
exit /b
复制代码