[文件操作] 批处理如何给文件名最后的数字改成3位数，不足三位用0补上？

mofangti

我有多个文件夹，每个文件夹有多个文件，如何给每个文件名最后的数字改成3位数，不足三位用0补上

Batcher

回复 17# mofangti


    把-WhatIf去掉

mofangti

回复 16# WHY


怎么文件没有变化？

WHY

回复 15# mofangti


    powershell 2.0版本中 rename-Item 不支持 -literalPath 参数，你可以改成 -Path，或者更新 PowerShell 版本。

mofangti

回复 11# WHY

mofangti

回复 10# xczxczxcz


    有效，谢谢

mofangti

回复 12# WHY

有效，谢谢

WHY

@echo off & setlocal enabledelayedexpansion
for /L %%i in (0 1 9) do set _%%i=1
for /f "delims=" %%i in ('dir /b /a-d /s E:\Test\*') do (
    set "Name=##%%~ni"
    for /f "tokens=1-3 delims=/" %%n in ("!Name:~-3,1!/!Name:~-2,1!/!Name:~-1!") do (
        if "!_%%n!.!_%%o!.!_%%p!" == ".1.1" (
            echo;ren "%%i" "!Name:~2,-2!0!Name:~-2!%%~xi"
        ) else if "!_%%o!.!_%%p!" == ".1" (
            echo;ren "%%i" "!Name:~2,-1!00!Name:~-1!%%~xi"
        )
    )
)
pause
复制代码

不考虑特殊字符，不考虑重名问题。

WHY

test.ps1

dir e:\Test\ -Include *[0-9].* -Recurse | ForEach{
    $name = [regex]::Replace($_.BaseName, '\d{1,3}$', {param($a); $a.Value.PadLeft(3, '0')});
    $name += $_.Extension;
    ren -Literal $_.FullName -NewName $name -WhatIf;
}
复制代码

Microsoft Windows [版本 10.0.17134.345]
(c) 2018 Microsoft Corporation。保留所有权利。

C:\Users\WHY>dir /b /s /a-d E:\Test\
E:\Test\a\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low08.doc
E:\Test\a\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low2.7z
E:\Test\a\1.LOG
E:\Test\a\a.txt
E:\Test\a\ccc1.jpg
E:\Test\b\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low08.doc
E:\Test\b\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low2.7z

C:\Users\WHY>PowerShell -ExecutionPolicy ByPass -f Desktop\Test.ps1
WhatIf: 正在目标“项: E:\Test\a\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low08.doc 目标: E:\Test\a\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low008.doc”上执行操作“重命名文件”。
WhatIf: 正在目标“项: E:\Test\a\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low2.7z 目标: E:\Test\a\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low002.7z”上执行操作“重命名文件”。
WhatIf: 正在目标“项: E:\Test\a\1.LOG 目标: E:\Test\a\001.LOG”上执行操作“重命名文件”。
WhatIf: 正在目标“项: E:\Test\a\ccc1.jpg 目标: E:\Test\a\ccc001.jpg”上执行操作“重命名文件”。
WhatIf: 正在目标“项: E:\Test\b\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low08.doc 目标: E:\Test\b\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low008.doc”上执行操作“重命名文件”。
WhatIf: 正在目标“项: E:\Test\b\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low2.7z 目标: E:\Test\b\0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low002.7z”上执行操作“重命名文件”。

C:\Users\WHY>

xczxczxcz

回复 9# mofangti

没有后缀的文件不修改，文件名末尾没有数字的不修改。不重新排序。只对后面的数字补全3位数。

@echo off & cd /d "%~dp0" & setlocal EnableDelayedExpansion
for /f "delims=" %%a in ('dir/a-d/b/s *.*') do (
	if "%%~xa" neq "" (
		call :AAA "%%~na"
		if "!ext!" neq "" (
			set "ext=0000!ext!"
			echo ren "%%a" "!str!!ext:~-3!%%~xa"
		)
	)
)
pause & exit
:AAA
set "ext="
set "str=%~1"
:LOOP
echo %str:~-1%|findstr "^[0-9]$">nul&&(set "ext=%str:~-1%%ext%" &set "str=%str:~0,-1%"&goto LOOP)|| goto :eof
复制代码

=========================================
上面为演示。实际操作把第7 行 "echo ren" 改为"ren" 即可。

mofangti

回复 2# Batcher

mofangti

回复 7# lifei259


    你这个不对，没考虑顺序，1后面没接上2，而成了10

lifei259

没考滤文件的排序，这是DOS的一个短板。

mofangti

回复 2# Batcher


    文件夹都是按数字依次排列的，如1（1），1（2）,...2 (1),2 (2),...，文件名英文与数字都有，但是最后几位是数字，从0，1，2，往下排。
例如0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low0
0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low1
0b3d9c8b-5a69-49c9-9f8d-a57f5ef0f883_mobile_low2
.每个文件夹下的文件数不超过1000
我希望每个文件夹下的文件按000,001，002， 排列即可

mofangti

回复 4# zuodx


    不管用