[文本处理] 【挑战】将文本中指定位置的tab替换为普通字符

batman

本人原意是想用批处理将a.txt中各列的数值进行累加计算（计算本身是很容易
的），但问题是a.txt中各列中有的不是数值而是空（实际上是tab），必须要先将这些指
定位置的tab替换为0字符，才能正确计算出结果。如果是在excel表中操作这会是很容易
的，但就是想用批来完成，想破了头终于还是有了些头绪。同时，本人觉得这个问题还
是有拿出来讨论的价值，所以就发了出来，也请大家各显神通，来完成这个批处理对文
本的特殊替换吧。（因论坛无法处理tab，所以上传附件a.txt如下）


[ 本帖最后由 batman 于 2009-6-23 17:24 编辑 ]

zqz0012005

在表达式中的任何非数字字符串键作为环境变量
看来这个也是需要深入理解的。
把 set /a expression 简化成下面的形式，以便于分析：
set /a n=表达式
注意这里的表达式是预处理后的，比如set /a n=%var%，是先把变量var展开再处理。
而set /a n=var，是不需要预处理的（或者说该语句预处理后是它本身）。至于对字符串var的处理，是set自己的功能，而不是预处理的功劳。

1、如果表达式中出现了非数字、非运算符的字符串，则set将这些字符串作为变量名，遵循下面两点：
（1）如果这些字符串是跟在数字后面，则变量名识别会出现问题：set不把它作为变量名，而是试图解析为某种进制中的数字常数。
如，set /a n=12bat，“bat”这些字符不是10进制的常数0-9。
甚至，set /a n=0xbad，这种十六进制形式其实也可以这样理解：首先当然不把xbad作为变量名，而是作为八进制的数字常数，事实上八进制的数字常数只能是0-7，但碰巧第一个字母是x，set转而把它识别为十六进制。

（2）如果字符串后面有数字，这些数字将不再是“数字”，而是变量名的一部分。如果后面是运算符，仍然是运算符。
如，set /a n=bat12，不是%bat%12，而是%bat12%。
而set /a n=bat+12，就是%bat%+12。

2、如果变量未定义，或变量指向的值是非数字，直接替换为0。
如，set var=bathome&set /a m=var, n=undefined，m、n的值都是0。

3、如果变量指向的值包含数字，则从左边开始，如果是数字字符（0-9），则被保留，直到遇到非数字字符，非数字及以后的内容直接被舍弃。
如，set var=12+3&set /a n=var，n的值是12。

[ 本帖最后由 zqz0012005 于 2009-6-24 13:49 编辑 ]

zqz0012005

我是说set /a n=1,2是逗号运算符。

而你的例子再一次说明了变量名以数字开头的弊端。

tireless

17 楼不是因为“逗号是运算符”。换成这样也可以：

@echo off
set v=bathome1
set /a v=v
echo %v%
pause  变量 v 的值变为 0

set v=1bathome
set /a v=v
echo %v%
pause  变量 v 的值变为 1

set v=1bathome
set /a v=%v%
echo %v%
pause  而这样会出错
复制代码

[ 本帖最后由 tireless 于 2009-6-24 12:33 编辑 ]

zqz0012005

@echo off
set m=1,2
set /a n=%m%
echo %n%
set /a n=m
echo %n%
pause
复制代码

有点意思。
set /a n=%m%，即set /a n=1,2，其中,是逗号运算符。逗号表达式的值取最后一个子表达式的值。

set m=2+2
set /a n=m
set "2+2=1" 设置变量2+2
set /a n=m
pause
复制代码

batman

回楼上，没有问题啊，你再运行下看

Batcher

合计的结果有问题吧？

C:\Test>type test.bat @echo off&setlocal enabledelayedexpansion set "tab=   " rem请将#替换为tab键 for /f "delims=" %%a in (a.txt) do (      echo %%a&set /a m=0      set "str=%%a"&set "str=!str:%tab%=%tab%0!"      for %%b in (!str!) do (           set /a m+=1           set "var=%%b"&set "var=!var:~1!"           if not defined var set /a var=0           set /a _!m!+=!var!      ) ) set "_1=合计" for /l %%a in (1,1,%m%) do (      set /p=!_%%a!<nul      if %%a neq %m% set /p= <nul ) pause>nul C:\Test>test.bat 姓名    第一项作业      第二项作业      第三项作业      第四项作业 甲      30      63      83      86 乙      27      93      98      22 丙      94      45      77 丁      14              94      78 戊              81      25      57 己      62      58      75 庚      70      49      10      47 辛      98                      2 壬      95      10      81      12 癸      64      29      45      57 合计 35 46 44 24

tireless

set /? 中有说：

在表达式中的任何非数字字符串键作为环境变量
名称，这些环境变量名称的值已在使用前转换成数字。如果指定
了一个环境变量名称，但未在当前环境中定义，那么值将被定为
零。

这个很有意思：

@echo off
set v=,1
set /a v=v
echo %v%
pause  变量 v 的值变为 0

set v=1,
set /a v=v
echo %v%
pause  变量 v 的值变为 1
复制代码

batman

set /a居然能够兼容汉字符及其他非数值字符，才发现原来可以这样：
set /a a=汉字,b=z,c=#,d=_
只是都默认值为0。

tireless

@echo off&setlocal enabledelayedexpansion
set "Tab=#"   把 # 换成 Tab 键
for /f "skip=1 delims=" %%a in (a.txt) do (
  set var=%%a
  set n=0
  for %%a in ("!var:%tab%=" "!") do set /a n+=1 , _!n!+=%%~a 2>nul
)

more a.txt
for /l %%a in (1 1 %n%) do set end=!end!%tab%!_%%a!
echo 合计%end%
pause>nul
复制代码

batman

呵呵，各位都给出了精彩的解答，可能本人在楼顶没有描述清楚，其实最后应该是
要计算出各列的和的，本人代码如下：

@echo off&setlocal enabledelayedexpansion
set "tab=#" rem请将#替换为tab键
for /f "delims=" %%a in (a.txt) do (
     echo %%a&set /a m=0
     set "str=%%a"&set "str=!str:%tab%=%tab%0!"
     for %%b in (!str!) do (
          set /a m+=1
          set "var=%%b"&set "var=!var:~1!"
          if not defined var set /a var=0
          set /a _!m!+=!var!
     )
     
)
set "_1=合计"
for /l %%a in (1,1,%m%) do (
     set /p=!_%%a!<nul
     if %%a neq %m% set /p=%tab%<nul
)
pause>nul
复制代码

[ 本帖最后由 batman 于 2009-6-24 11:44 编辑 ]

tireless

正确吧？跟 7楼 的结果一样。

[ 本帖最后由 tireless 于 2009-6-24 09:13 编辑 ]

netbenton

楼上第一个代码可以减少一行，"号用得错实妙

第二个代码似乎结果不正确吧？
是不是想做成6楼的样子呢？


再来一个：

 
@echo off
set Tab= &rem 这个空白换为Tab键
for /f "delims=" %%a in (a.txt) do (
set var=%%a%Tab%
setlocal enabledelayedexpansion
set var=!var:%Tab%%tab%=%Tab%0%Tab%!
set var=!var:%Tab%%tab%=%Tab%0%Tab%!
echo !var:~,-1!
endlocal
)
pause
复制代码

[ 本帖最后由 netbenton 于 2009-6-24 07:50 编辑 ]

tireless

@echo off&setlocal enabledelayedexpansion
set "tab=        " 引号里的空格换成 Tab
for /f "delims=" %%a in (a.txt) do (
  set var=%%a
  set var="!var:%tab%="%tab%"!"
  set var=!var:""=0!
  echo !var:"=!
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
  set var=%%a
  set n=0
  for %%a in ("!var:【Tab】=" "!") do set /a n+=1 , _!n!+=%%~a 2>nul
)
set _
pause
复制代码

[ 本帖最后由 tireless 于 2009-6-24 09:12 编辑 ]

jackerloo2009

哎！man在群里让我做一下，呵呵，寻思半天还是来看答案了

喜欢8楼的思路

又掌握了一种思路技巧