[文件操作] bat自动解压更新chrome浏览器的遇到一个低级问题 !!

zhqiao

高手帮忙!

国内使用chrome需要手动下载, 再解压得到chrome全部文件做绿色版.

我写了一个bat,
但有一个小问题是, chrome解压后会得到一个版本号文件夹, 纯数字无规律,带点号,  像69.3723.23.9这样的. 目前需要手动改为目标名称.
怎么自动改这个无规律的文件夹名呢?

::      更新chrome浏览器. 
::      过程:  用bandizip解压下载的exe, 删除部分语言文件, 复制必需文件到D盘固定目录.

cd      Z:\A\
:: 临时工作目录A
ren     Z:\A\*chrome_installer.exe      Chrome.zip
start /wait      C:\"Program Files"\Bandizip\Bandizip.exe bx -y    Z:\A\Chrome.zip  /S
del  /s/f/q     Z:\A\Chrome.zip
start /wait      C:\"Program Files"\Bandizip\Bandizip.exe bx -y    Z:\A\Chrome.7z  /S
:: 此时解压完毕会得到一个版本号文件夹, 纯数字无规律,带点号,  像69.3723.23.9这样的

@echo 此时需手动改名Z:\A\Chrome-bin\下的无规律版本号数字文件夹为111
pause

move /y       Z:\A\Chrome-bin\chrome.exe      Z:\A\Chrome-bin\111\

:: 下面删除多余文件
rd /s/q      Z:\A\Chrome-bin\111\default_apps\
for /f "tokens=* delims=" %%a in ('"dir /s /b Z:\A\Chrome-bin\111\Locales|findstr /i /v "en-US.pak zh-CN.pak""') do del %%a

:: 清空旧chrome文件夹
rd /s/q      D:\PROGRAM\Net\Chrome
xcopy  /i/e/y       Z:\A\Chrome-bin\111\      D:\PROGRAM\Net\Chrome\
rd /s/q      Z:\A\
复制代码

每一版chrome的版本号都不同 . 怎么自动改这个无规律的带点文件夹名 ,一气呵成 ,  免去手动改名 ?

zhqiao

回复 6# 窄口牛


    非常感谢 !
不会干掉用户数据. 都在. 自己解压的方式自由度高 . 不必被强制安装在C盘.

zhqiao

回复 4# Batcher


    非常感谢 !

窄口牛

你这更新把收藏夹也干掉了吧？？

窄口牛

@echo off
Setlocal enabledelayedexpansion
cd /d %~dp0
set pt=D:\PROGRAM\Net\Chrome
set te=%temp%\Chrome-bin
set te111=%temp%\Chrome-bin\111
"D:\Program Files\7-Zip\7z.exe" x chrome.7z -o%temp%
::del chrome.7z /q
for /f "delims=" %%a in ('dir %te% /ad /b 2^>nul') do ren %te%\%%a 111
pause
rd /s/q %te111%\default_apps\
for /f "tokens=* delims=" %%a in ('"dir /s /b %te111%\Locales|findstr /i /v "en-US.pak zh-CN.pak""') do del %%a
rd %pt% /s /q>nul 2>nul
md %pt%
move %te%\Chrome.exe %pt%\Chrome.exe
xcopy /s /e /y /i %te111% %pt%
rd %te% /s /q>nul 2>nul
复制代码

Batcher

回复 3# zhqiao


1.bat

@echo off
for /f "delims=" %%i in ('dir /b /ad "Z:\A\Chrome-bin\"') do (
    set "folder=%%~nxi"
)
echo,%folder%
pause
复制代码

2.bat

@echo off
for /d %%i in ("Z:\A\Chrome-bin\*") do (
    set "folder=%%~nxi"
)
echo,%folder%
pause
复制代码

zhqiao

回复 2# Batcher


   只有一个文件夹, 文件夹名就是版本号 .  还有一个chrome.exe文件. 没有其它内容了 !

Batcher

解压之后 Z:\A\Chrome-bin\ 下只有一个文件夹吗？
如果有多个文件夹的话，其它文件夹分别是什么？需要总结一下规律才好写代码