[文件操作] [已解决]以数字命名的文件夹批量重命名，如何在不足指定位数的名称前补0/加0

akb4888

求助：文件夹批量重命名
前言，本人无基础
现有一批用数字命名的文件夹，在不同的目录中：基本结构如下：
X:备份\AA-115\1
X:备份\AA-126\3
.
.
.
X:备份\AA-116\2333
以及
X:存储\AA-115\1
X:存储\AA-126\3
.
.
.
X:存储\AA-116\2333
我想做个批处理，判断文件夹名字，不足4位数的文件夹重命名在前面用0补齐4位数
自己在网上参考后写的代码如下：

@echo off&color 3a&set c=0123456789abcdefghijklmnopqrstuvwxyz
setlocal enabledelayedexpansion
for /f "tokens=*" %%i in ('dir /a:d /s /b') do (
set n=%%i
if !n! lss 10 (if !n! geq 0 ren "!n!" "000!n:~-1!")
if !n! lss 100 (if !n! geq 10 ren "!n!" "00!n:~-2!")
if !n! lss 1000 (if !n! geq 100 ren "!n!" "0!n:~-3!")
)
echo 正在处理...
echo.
echo 处理完毕
pause
复制代码

只对前目录里的文件夹生效，子目录里的文件夹没有被重命名，求前辈大佬们指点，万分感谢！

akb4888

回复 2# yhcfsr
谢谢前辈指点！
原来sort 这个是排序命令，/r 这个参数就是倒序吧？
有点明白了，虽然您的代码有一句用到了很多不认识的命令够我学一阵了，hhh
您写的代码方案测试没问题，总之非常感谢！！

yhcfsr

@echo off
for /f "delims=" %%a in ('dir /ad/s/b^|sort /r') do (
	set "$=%%~na#"&set len=0
	setlocal enabledelayedexpansion
	for %%b in (4 2 1)do if !$:~%%b^,1!. NEQ . set/a len+=%%b&set $=!$:~%%b!
	if !len! equ 1 ren "%%a" "000%%~na"
	if !len! equ 2 ren "%%a" "00%%~na"
	if !len! equ 3 ren "%%a" "0%%~na"
	endlocal
)

pause
复制代码

关键是sort /r
dir打印目录列表后，这张表就被保存了。你的代码先命名前级目录，这时子目录的实际路径已变。
而dir之前保存的目录列表还是原来的，CMD还是按原来的路径去命名子目录，这里就会提示找不到路径，重命名失败。
解决方法是逆序排列，让子目录排在前面。先重命名子目录，再命名母目录，就没问题了。