[文件操作] 求个文件二进制比较命令

conolmova

比如，以目录A为标准， 通过批处理生成其他5个目录 1，2，3，4，5，每个目录上理论上都与A应该是相同的，都有10个相同的二进制文件。
现在想把  1，2，3，4，5 这5个目录里面的文件都与 目录A 下面的文件进行比较，结果只要标出是哪个目录与A目录不同就可以了。

请问该如何写呢？

PS2.0

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,5) do (
    set "flag=yes"
    for %%b in ("%%a\*") do (
        if not exist "A\%%~nxb" (
            set "flag=no"
        ) else (
            fc /b "%%b" "A\%%~nxb" > nul
            if errorlevel 1 (
                set "flag=no"
            )
        )
    )
    if "!flag!" equ "no" (
        echo %%a 不同
    )
)

for %%a in ("A\*") do (
    set "flag=yes"
    for /l %%b in (1,1,5) do (
        if not exist "%%b\%%~nxa" (
            set "flag=no"
            set "folder=%%b"
        )
    )
    if "!flag!" equ "no" (
        echo !folder! 不同
    )
)
pause
复制代码

老刘1号

或者

FC /B File1 File2 >NUL 2>NUL
If ERRORLEVEL 1 (echo 不同) else echo 相同
复制代码

老刘1号

这是比较单个文件的，目录比较自己写
FC /B File1 File2|Find "找不到相异处" >nul && Echo File1,File2的文件内容相同。||Echo File1,File2的文件内容不同。