[系统相关] 批处理如何实现禁用/启用无线网卡

erjnasrtnws

求助批处理打开禁用的无线网卡，只要启用硬件就行了，会自动连接家里的wifi，谢谢了
就是把硬件管理器无线网卡启用，具体见图 谢谢指点 谢谢关注！！

pcl_test大侠已经完美搞定 答案在3楼

窄口牛

devcon disable 设备id
devcon enable 设备id
devcon find pci\*可以找到设备ID，或者设备管理器里看看

@echo off
for /f "delims=^& tokens=1,2,3" %%a in ('devcon find pci\* ^| findstr /i "wireless"') do set "dev=%%a^&%%b"
echo %dev%
devcon disable %dev%
devcon enable %dev%
pause
复制代码

@echo off
for /f "delims=^& tokens=1,2,3" %%a in ('devcon find usb\* ^| findstr /i "wireless"') do set "dev=%%a^&%%b"
echo %dev%
devcon disable %dev%
devcon enable %dev%
pause
复制代码

wgip192

这个脚本核心就是用的是。
netsh interface set interface name="本地联接" admin= disabled

netsh interface set interface name="本地联接" admin= enabled

erjnasrtnws

回复 3# pcl_test


   真的蛮好用 再次谢谢！！！

pcl_test

无效则使用第三方devcon
http://www.bathome.net/s/tool/index.html?key=devcon

@echo off
set "网络连接名称=本地连接"
::启用为1，禁用为0
set "模式=0"
ver|findstr "\<5\.[12]">nul||goto :2
:1
(
    echo;Set objshell = CreateObject("Shell.Application"^)
    echo;Set objnet = objshell.NameSpace("::{7007ACC7-3202-11D1-AAD2-00805FC1270E}"^).Items(^)
    echo;For i = 0 To objnet.Count - 1
    echo;    If objnet.Item(i^).Name = "%网络连接名称%" Then
    echo;        objnet.Item(i^).Verbs(^).Item(0^).DoIt
    echo;    End If
    echo;Next
    echo;CreateObject("WScript.Shell"^).popup "Done",2,"提示",64
)>"%tmp%\tmp.vbs"
wscript -e:vbscript "%tmp%\tmp.vbs"
goto :end

:2
for /f "delims=" %%a in ('wmic nic where "NetConnectionID='%网络连接名称%'" get DeviceID /value 2^>nul^|find "="') do set %%a
if "%模式%" equ "0" (
    netsh interface set interface "%网络连接名称%" disabled >nul
    wmic path win32_networkadapter where DeviceID=%DeviceID% call disable
) else (
    netsh interface set interface "%网络连接名称%" enabled >nul
    wmic path win32_networkadapter where DeviceID=%DeviceID% call enable
)
:end
pause
复制代码

erjnasrtnws

回复 1# erjnasrtnws


希望桌面建个批处理，运行批处理就启用设备管理器里的就是截图的无线网卡   求解各位大大