[文本处理] [已解决]批处理如何实现将txt文本每一行指定字符前后的1位数字前面加0/补零/补0？

ygqiang

[已解决]批处理，如何将txt文件每行-前后的1位数，前面自动加上0？

rq.txt文件格式：
8-9
10-6
5-21
11-25


如何转换成：
08-09
10-06
05-21
11-25

Nsqs

回复 4# ygqiang


    8进制问题,解决了

hlzj88

虽然解决了，还是来一发

@echo off&&setlocal enabledelayedexpansion
for /f "delims=- tokens=1,2," %%i in (rq.txt) do (
   set aa=0%%i
   set aa=!aa:~-2,2!
   set bb=0%%j
   set bb=!bb:~-2,2!
   echo !aa!-!bb!>>rq1.txt
)
pause
复制代码

WHY

@if (0)==(0) echo off
cscript //nologo //e:jscript "%~f0" <a.txt
pause & exit @end

var s = WSH.StdIn.ReadAll();
s = s.replace(/^(\d{1,2})-(\d{1,2})\r?$/gm,
        function(s0, s1, s2){
                return (s1*1 + 100 + '').substr(1) + '-' + (s2*1 + 100 + '').substr(1);
        }
)

WSH.Echo(s)
复制代码

ygqiang

回复 3# Nsqs


    你好，你的代码有点问题。

如果a.txt文件内容是：
08-09
5-6
08-09
8-9

生成的new.txt文件为：
-
05-06
05-06
08-09

Nsqs

@echo off
(for /f "tokens=1,2 delims=-" %%a in (a.txt)do (
set /a n=%%a*1,n0=n/10,n1=n%%10,n=%%b*1,n2=n/10,n3=n%%10
call set s=%%n0%%%%n1%%-%%n2%%%%n3%%
call echo %%s%%
))>new.txt
复制代码

ygqiang

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=-" %%a in (rq.txt) do (
echo 源串:%%a-%%b
pause

if 1%%a lss 100 (set var1=0%%a) else set var1=%%a
if 1%%b lss 100 (set var2=0%%b) else set var2=%%b

echo !var1!-!var2!>>test.txt

)

del /q rq.txt
ren test.txt rq.txt

1pause
复制代码